ピボットテーブル最終行から２行目に項目を入れて３行目から新しいピボットテーブルを貼り付けたい。

Question

エクセルのマクロで、ピボットテーブルを２つ作成しています。
それを集計表シートに貼り付けています。

「A1」に「ピボットテーブル１」の名前を入れて
１つ目のピボットテーブルの範囲が「A2:G10」の場合

11行目は空欄
「A12」に「ピボットテーブル２」の名前
「A13（:D20など）」ピボットテーブル２
というようにピボットテーブルを貼り付けていきたいのですが、
良い方法はありませんか？

現在は２つ目のピボットテーブルを「A25」に貼り付けるように
設定していますが、１つ目のピボットテーブルの大きさが毎回
変化するので、見た目がきれいではありません。

２つ目のピボットテーブルを貼り付ける部分のＶＢＡを記入しておきます。
「貼り付け」シートのデータを元にピボットテーブルを作成しています。
ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:= _
        "貼り付け!R2C15:R300C19", Version:=xlPivotTableVersion12).CreatePivotTable _
        TableDestination:="集計表!R25C1", TableName:="ピボットテーブル13", DefaultVersion _
        :=xlPivotTableVersion12
    Sheets("集計表").Select
    Cells(25, 1).Select

end-u · Accepted Answer

ピボットテーブルの貼り付け先として、
変動するデータ範囲の取得方法を知りたいという事ですね。
ピボットテーブル１作成後、最終行を取りたいなら、
Endプロパティを使うのが最もオーソドックスかと思います。
（作成前に集計表シートをクリアしておく事が前提）

こちらのページが解かり易いので参考にしてください。
http://www.niji.or.jp/home/toru/notes/8.html

実際のサンプルは以下。ピボット作成はテキトーです。

Sub test()
　　Dim r As Range

　　With ActiveWorkbook

　　　　Set r = Sheets("集計表").Range("A1")
　　　　r.Value = "ピボットテーブル１"

　　　　With .PivotCaches.Create(SourceType:=xlDatabase, _
　　　　　　　　　　　　　　　　 SourceData:="貼り付け!R2C15:R300C19") _
　　　　　　　　　　　　　　　　 .CreatePivotTable(TableDestination:=r.Offset(1), _
　　　　　　　　　　　　　　　　　　　　　　　　　 TableName:=r.Value)
　　　　　　.AddFields RowFields:="Field1", _
　　　　　　　　　　　 ColumnFields:="Field2"
　　　　　　.AddDataField .PivotFields("Field3"), "Field3計", xlSum
　　　　End With

　　　　'２コ目のピボットテーブル
　　　　With Sheets("集計表")
　　　　　　'シート最大行から[Ctrl]+[↑]で上に跳んで、止まったセルの２コ下。
　　　　　　Set r = .Cells(.Rows.Count, 1).End(xlUp).Offset(2)
　　　　End With
　　　　r.Value = "ピボットテーブル２"

　　　　With .PivotCaches.Create(SourceType:=xlDatabase, _
　　　　　　　　　　　　　　　　 SourceData:="貼り付け!R2C15:R300C19") _
　　　　　　　　　　　　　　　　 .CreatePivotTable(TableDestination:=r.Offset(1), _
　　　　　　　　　　　　　　　　　　　　　　　　　 TableName:=r.Value)
　　　　　　.AddFields RowFields:="Field1", _
　　　　　　　　　　　 ColumnFields:="Field2"
　　　　　　.AddDataField .PivotFields("Field3"), "Field3計", xlSum
　　　　End With
　　
　　End With

　　Set r = Nothing
End Sub

ピボットテーブル最終行から２行目に項目を入れて３行目から新しいピボットテーブルを貼り付けたい。

ピボットテーブルの貼り付け先として、

似たような質問が見つかりました

このQ&Aを見た人はこんなQ&Aも見ています

関連するカテゴリからQ&Aを探す

このQ&Aを見た人がよく見るQ&A

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング