ExcelのToggleButtonを排他的に。。

Question

師も走りまわる１２月。。皆様（師）も走りまわっていることでしょう。
私は。。。走りません、はい。

本題です。
ExcelのVBAでToggleButtonを排他的に使いたいのです。
調べるとオプションボタンになさいと書かれてはいるのですが・・・。

ワークシート上にToggleButton1～3があります。
１を押す（凹）と“処理A”，もう一度押す（凸）と“処理Ｚ”
2　　同上　　　 “処理Ｂ”，　　同上
3　　同上　　　 “処理Ｃ”，　　同上

以下のコードでなんとなく動くのですが，排他的動作の際には，TrueなToggleButton#の動作をおこなってしまいます。
Excel2007,Windows7です。
師の皆様の良い御提案が御座いましたら御教示下さい。

----ボタンがあるシートモジュールに記載----------------------------------------
Option Explicit
Dim strCode As Variant

Private Sub ToggleButton1_Click()
If ToggleButton1.Value = False Then
   strCode = "処理中Ｚ"
'   Debug.Print "ＡからＺに戻します。"
Else
   strCode = "処理中Ａ"
'   Debug.Print "Ａを押しました。"
   ToggleButton2.Value = False
   ToggleButton3.Value = False
End If
'Debug.Print "Ａでの処理をします。"
Call 処理(strCode)
'Debug.Print "Ａから処理をしました。"
End Sub

Private Sub ToggleButton2_Click()
If ToggleButton2.Value = False Then
   strCode = "処理中Ｚ"
'   Debug.Print "ＢからＺに戻します。"
Else
   strCode = "処理中Ｂ"
'   Debug.Print "Ｂを押しました。"
   ToggleButton1.Value = False
   ToggleButton3.Value = False
End If
'Debug.Print "Ｂでの処理をします。"
Call 処理(strCode)
'Debug.Print "Ｂから処理をしました。"
End Sub

Private Sub ToggleButton3_Click()
If ToggleButton3.Value = False Then
   strCode = "処理中Ｚ"
Else
   strCode = "処理中Ｃ"
   ToggleButton1.Value = False
   ToggleButton2.Value = False
End If
Call 処理(strCode)
End Sub

Sub 処理(strCode)
Dim i As Long
Dim Start As Single
Dim Finish As Single
Start = timer
i = 0
'Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
For i = 1 To 1000
    i = i + 1
    Cells(2, 1).Value = strCode & i
Next i
Application.Calculation = xlCalculationAutomatic
'Application.ScreenUpdating = True
Cells(1, 1).Value = strCode
Finish = timer
Cells(3, 1).Value = Format$(Int((Finish - Start) * 10 ^ 4 + 0.5) / 10 ^ 4)
End Sub
---------------------------------------------------------------------------
おまけ：
　上記サンプルを作ってみましたが，ToggleButton1だけ相対的に処理速度が速いです・・・。
なぜなんでしょう？？

redfox63 · Accepted Answer

Application.EnableEventsで 制御できないんじゃないかな …

わたしなら
モジュールレベルの変数として
dim toggle, bFlag
を定義

ボタンの制御プロシージャを定義
Sub ClickProc(ctl as Object)
　　' フラグが Trueなら そのまま戻る
　　if bFlag then Exit Sub
　　if IsEmpty(toggle) then
　　　　toggle = Array(ToggleButton1, ToggleButton2, ToggleButton3)
　　end if
　　Dim ss as String
　　bFlag = True
　　ss = "処理Z"
　　select case ctl.Name
　　　　case "ToggleButton1"
　　　　　　if ctl.Value then ss = "処理A"
　　　　　　toggle(1).Value = False
　　　　　　toggle(2).Value = False
　　　　case "ToggleButton2"
　　　　　　if ctl.Value then ss = "処理B"
　　　　　　toggle(0).Value = False
　　　　　　toggle(2).Value = False
　　　　case "ToggleButton3"
　　　　　　if ctl.Value then ss = "処理C"
　　　　　　toggle(0).Value = False
　　　　　　toggle(1).Value = False
　　End Select
　　処理 ss
　　' 処理終了のためフラグをFalseに
　　bFlag = False
End Sub

各トグルボタンのクリックを

Sub ToggleButton1_Click()
　　ClickProc ToggleButton1
End Sub

Sub ToggleButton2_Click()
　　ClickProc ToggleButton2
End Sub

Sub ToggleButton3_Click()
　　ClickProc ToggleButton3
End Sub

といったぐあいで …

noname157639 · Answer

EnableEventsはOn,Offの操作でするのがよさそうですね。noname#157639

WindFaller · Answer

こんにちは。

>Application.EnableEventsで 制御できないんじゃないかな …

「排他的動作の際には，TrueなToggleButton#の動作をおこなってしまいます。」
というコメントから発想を考えたわけです。他の方法もありますが、一般的には、再帰的なイベントをEnableEventsはOn・Offで操作するのが定番のはずです。

#2さんのテクニック的には、面白いのですが、結果的には、再帰的に、別のActiveX Control オブジェクトに戻ってきてしまいますね。ActiveX Control オブジェクトが大量のある場合に、それでも同じだと言えるのかどうか、試してみないので、これは、答えようがありません。ただ、私は、それを嫌って解除しようとしたわけです。元のご質問をどのように解釈しているのかもよりますが……。

WindFaller · Answer

こんにちは。

>ToggleButton1だけ相対的に処理速度が速いです
これ自体は、私の環境では実現できません。ほぼ同じでしたから、実際は、もっと数が多いのではないでしょうか。もしくは、バッファに入っていることぐらいでしょうか。

今のスタイルで、ActiveX コントロールで使う分には、しょうがないという所だと思います。
ご質問は、関係のない所のトグルボタンは、Call 処理(strCode)に飛ばないようにするということと同じ意味ではありませんか？

他にも方法としては、数が多い場合に、コードを全部インスタンスに換えて、クラスで設定すれば、イベントの発生した部分を特定化できるはずです。

とりあえず、これで、イベントのオンオフをしてやればどうでしょうか。
　Application.EnableEvents = False
　Application.EnableEvents = True

'//
Private Sub ToggleButton1_Click()
Application.EnableEvents = False　'全てのトグルボタンのコードに、これを入れて、
If ToggleButton1.Value = False Then
　 strCode = "処理中Ｚ"
'　 Debug.Print "ＡからＺに戻します。"
Else
　 strCode = "処理中Ａ"
'　 Debug.Print "Ａを押しました。"
　 ToggleButton2.Value = False　'←ここにイベント発生源
　 ToggleButton3.Value = False　'←　　　〃
End If
'Debug.Print "Ａでの処理をします。"
Call 処理(strCode)
'Debug.Print "Ａから処理をしました。"
End Sub

Sub 処理(strCode)
Dim i As Long
Dim Start As Single
Dim Finish As Single
Start = timer
　'中略
Cells(3, 1).Value = Format$(Int((Finish - Start) * 10 ^ 4 + 0.5) / 10 ^ 4)
　Application.EnableEvents = True 'ここで戻す
End Sub
'//

ExcelのToggleButtonを排他的に。。

Application.EnableEventsで 制御できないんじゃないかな …

この回答への補足

EnableEventsはOn,Offの操作でするのがよさそうですね。

こんにちは。

こんにちは。

この回答への補足

似たような質問が見つかりました

このQ&Aを見た人はこんなQ&Aも見ています

関連するカテゴリからQ&Aを探す

このQ&Aを見た人がよく見るQ&A

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング

Application.EnableEventsで制御できないんじゃないかな …