ACCESSでストップウォッチの作成

ＡＣＣＥＥＳＳ２０１３を利用しています。

ＶＢＡでストップウォッチを作成したいのです。

自作では、簡単なのはできたのですが、

スータト⇒ストップ⇒スタート　⇒このとき0秒の戻ってしまいます。

スタート　ストップ　一時停止がほしいのですが、
一時停止の作成ができません。

ネットで調べても、見つけることができませんでした。
ほぼ、丸投げ状態ですが、ご教唆お願いします

No.1 ベストアンサー 回答者： nicotinism 回答日時： 2016/04/24 23:10

教唆はいけません。

『人にいろいろ暗示を与えて、悪事・犯罪などを犯すように仕向けること』ですから「教示」ですね。

さて、本題。
フォームにコマンドボタンを二個（名前をそれぞれ BtnStart と BtnReset にします）
テキストボックスを一個（名前を TxtTime にします）
フォームのモジュールに

Option Compare Database
Option Explicit
'下記二行は宣言部
Private FormTime As Single
Private PassedTime As Single

Private Sub BtnReset_Click()
　　Me.TimerInterval = 0
　　FormTime = 0
　　PassedTime = 0
　　Me!TxtTime = 0
　　Me!BtnStart.Caption = "Start"
End Sub

Private Sub BtnStart_Click()
　　If Me.TimerInterval = 0 Then
　　　　FormTime = Timer - FormTime
　　　　Me!BtnStart.Caption = "Stop"
　　　　Me.TimerInterval = 100
　　Else
　　　　Me!BtnStart.Caption = "Start"
　　　　Me.TimerInterval = 0
　　　　FormTime = PassedTime
　　End If
End Sub

Private Sub Form_Timer()
　　Dim sMod As Long
　　PassedTime = Timer - FormTime
　　sMod = Int((PassedTime - Int(PassedTime)) * 100)
　　Me!TxtTime = CDate(PassedTime / 60 / 60 / 24) & Format(sMod, "\.00")
　　'Me.Repaint
End Sub

※なお、Timer関数を使用している都合上、日付をまたがって使用していると誤表記されます。
投稿用にタブインデントの代わりに全角スペースを使用しています。
Access2010での動作確認です。

この回答へのお礼

完璧です。ありがとうございました。
日本語のご指摘も感謝しております。
本当にありがとうございました。

お礼日時：2016/04/25 10:23