VBA　セル内改行禁止

Question

H列の全てのセルで、セル内改行（Alt+Enter）したら、
"セル内改行禁止"というメッセージボックスを表示させたいのですが、
どのような構文になりますか。

    Dim inputdata As Integer
    On Error GoTo MSG
    inputdata = Worksheets("sheet1").Column("H:H")
    if inputdata

ここまで書いてみたのですが、全然自信がありません。
ご存知の方、ご教授お願い致します。

marbin · Accepted Answer

"H列”を見落としてました。
↓でお試しください。

Private Sub Worksheet_Change(ByVal Target As Range)
 If Target.Value Like "*" & vbLf & "*" And Target.Column = 8 Then
    MsgBox "H列かつセル内改行あり"
 End If
End Sub

marbin · Answer

セル内改行の有無をチェックします。

Private Sub Worksheet_Change(ByVal Target As Range)
 If Target.Value Like "*" & vbLf & "*" Then
    MsgBox "セル内改行あり"
 End If
End Sub

cafe_au_lait · Answer

シートモジュールに貼り付けてください。

Private Sub Worksheet_Change(ByVal Target As Range)

Dim myrng As Range

For Each myrng In Target
    If myrng.Column = 8 Then
        If InStr(myrng.Value, Chr(10)) > 0 Then
            MsgBox "セル内改行禁止"
        End If
    End If
Next myrng

End Sub

lark_0925 · Answer

ちょっと仕様が変更して、
改行コード　Vblfが
当該シートの　Ｈ列に入力されると　エラーメッセージを表示した後に、
改行コードを削除します。

ぐらいの使用にした方が簡単だと思いますが、いかがですか？

これでよいなら、
当該シートのモジュールに
'=======================================================
Private Sub Worksheet_Change(ByVal Target As Range)
　　Dim trng As Range
　　Dim crng As Range
　　Set trng = Application.Intersect(Target, Range("h:h"))
　　If Not trng Is Nothing Then
　　　Application.EnableEvents = False
　　　For Each crng In trng
　　　　　If InStr(crng, vbLf) Then
　　　　　　MsgBox "改行はできません"
　　　　　　With crng
　　　　　　　.Value = Replace(crng.Value, vbLf, "")
　　　　　　　End With
　　　　　　End If
　　　　　crng.WrapText = False
　　　　　Next
　　　Application.EnableEvents = True
　　　End If
End Sub

として、Ｈ列に入力して試してみて下さい。

mshr1962 · Answer

入力時（コピー＆ペースト）ということなら下記で強制的に改行を解除できます。
Private Sub Worksheet_Change(ByVal Target As Range)
    For Each RG In Target
    If RG.Column = 8 Then
        If InStr(1, RG.Value, Chr(10)) > 0 Then
         MsgBox "セル" & RG.Address & "に改行を取り消します。", , "改行禁止"
         RG.Value = Replace(RG.Value, Chr(10), "")
        End If
    End If
    Next RG
End Sub

lark_0925 · Answer

訂正です。

>ぐらいの使用にした方が簡単だと思いますが、いかがですか？
ぐらいの仕様にした方が簡単だと思いますが、いかがですか？

imogasi · Answer

これはVBAでなくても、データー入力規則ーユーザー設定ー　=ISERROR(FIND(CHAR(10),A1)) でできることです。ですから
それをマクロの記録をとったものを下記に挙げておきます。
Sub Macro1()
    With Range("A:A").Validation
        .Delete
        .Add Type:=xlValidateCustom, AlertStyle:=xlValidAlertStop, Operator:= _
        xlBetween, Formula1:="=ISERROR(FIND(CHAR(10),A1))"
        .IgnoreBlank = True
        .InCellDropdown = True
        .InputTitle = ""
        .ErrorTitle = ""
        .InputMessage = ""
        .ErrorMessage = "セル内改行禁止"
        .IMEMode = xlIMEModeNoControl
        .ShowInput = True
        .ShowError = True
    End With
End Sub
A列の例ですから、H列なら With Range("H:H").Validation
と変えます。

VBA セル内改行禁止

セル内改行の有無をチェックします。

"H列”を見落としてました。

シートモジュールに貼り付けてください。

ちょっと仕様が変更して、

入力時（コピー＆ペースト）ということなら下記で強制的に改行を解除できます。

訂正です。

これはVBAでなくても、データー入力規則ーユーザー設定ー =ISERROR(FIND(CHAR(10),A1)) でできることです。

似たような質問が見つかりました

このQ&Aを見た人はこんなQ&Aも見ています

関連するカテゴリからQ&Aを探す

このQ&Aを見た人がよく見るQ&A

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング

VBA　セル内改行禁止

これはVBAでなくても、データー入力規則ーユーザー設定ー　=ISERROR(FIND(CHAR(10),A1)) でできることです。