エクセルで三行ごとのデータを１行ごとに表示させたい

下のように三行ごとにあるセルを参照し、他のセルに一行ごとに表示する方法（関数、もしくはマクロなど）

　　Ａ　Ｂ　Ｃ　Ｄ
１　あ　　　　　あ
２　　　　　　　い
３　　　　　　　
４　い
５
６
７　う
８

あるいはあるセルに入力されている数値を数式内の行、または列として指定する方法を探しています。

（たとえばA1に４、A2に３と入力されていたとき、B2でその数値を取得しC3の内容を表示する、といった感じです）

簡単そうなきがするのですが私の検索が悪いのか、見つけることが出来ませんでした。ご存知の方お願いします

No.4 ベストアンサー 回答者： spnlight 回答日時： 2008/08/07 19:45

　　Ａ　Ｂ　Ｃ　Ｄ

１　あ　１　　　=INDIRECT("A" & B1,1)
２　　　４　　　=INDIRECT("A" & B2,1)
３　　　７　　　=INDIRECT("A" & B3,1)
４　い
５
６
７　う
８
こういう事かな？

この回答へのお礼

まさにこれです！やっぱりエクセルの関数でありましたね。
ありがとうございました！

お礼日時：2008/08/08 09:22

No.3 回答者： mike_g 回答日時： 2008/08/07 18:48

D1: =IF(OFFSET(A$1,(ROW(A1)-1)*3,,)=0,"",OFFSET(A$1,(ROW(A1)-1)*3,,))

》 A1に４、A2に３と入力されていたとき、B2でその数値を取得しC3の内容を表示

C3 は D3 の間違いでは？
間違いでなければ、「その数値」と C3 の関係を説明ください。

この回答への補足

Ｄ３の間違いでしたすみません

補足日時：2008/08/08 09:25

No.2 回答者： hallo-2007 回答日時： 2008/08/07 18:30

>他のセルに一行ごとに表示する方法

１行目、4行目、7行目・・・と表示する方法ですが
　=INDEX(A:A,(ROW(A1)*3)-2,1)
>あるいはあるセルに入力されている数値を数式内の行、または列として指定する方法
　一例ですが
　A1に4　A2に3　とあって　4行目の3列目を表示する方法
　=OFFSET(A1,A1-1,A2-1)
>B2でその数値を取得しC3の内容を表示する
の内容がよくわかりませんが？

この回答へのお礼

INDEXでもできるのですね。
なかなか沢山方法があったんですね…
ありがとうございました！

お礼日時：2008/08/08 09:30

No.1 回答者： mshr1962 回答日時： 2008/08/07 18:21

D1==OFFSET($A$1,ROW()*3-3,0)

または
D1=INDIRECT("A"&(ROW()*3-2))
※注意．参照するA列のセルが未入力の場合は0が表示されます。
それを避ける場合は
D1=IF(OFFSET($A$1,ROW()*3-3,0)="","",OFFSET($A$1,ROW()*3-3,0))
のようにIF文で制御する必要があります。

この回答へのお礼

OFFSETとROWだけでできたんですね。
かんがえてもわかりませんでした…
INDIRECTという関数は今後も使えそうなのでしっかりと覚えたいです。
ありがとうございました！

お礼日時：2008/08/08 09:28