IF OR関数で

C1のセルに次のように式を入力しました。

=IF(OR(A1<B1),"●",IF(OR(A1>B1),"○",IF(OR(A1=B1),"△")))

これは試合結果を表示させるために作ったのですが、これだとまだ試合
をしてないところは△で表示されてしまいます。

そこで上記の式の最後に　A1が空白のときは　未　と表示されるように
式を追加したいのですが、どのようにしたらいいでしょうか？

IF(OR（A1=""）,"未"とつけたしてみたんですがうまくいきませんでした。
どなたかご教授ください。お願いします。

No.1 ベストアンサー 回答者： grumpy_the_dwarf 回答日時： 2009/09/19 17:51

or関数は、複数の判定式をカンマで区切って並べ、どれか一つでも

TRUEならTRUEを返す関数です。中身が一つでは、or関数を使う意味
がありませんね。

> IF(OR（A1=""）,"未"
これを最後に追加したんじゃないですか。A1とB1がどちらも空っぽ
なら、A1=B1がTRUEになります。空っぽの判定は、最初にやりま
しょう。というわけで、

=if(A1="","未",if(A1<B1,"●",if(A1>B1,"○","△")))
みたいな感じ。"△"の前にifがないのは、A1<B1でもA1>B1でもない
状態はたいていA1=B1だから、判定する必要がないのです。

No.4 回答者： maron--5 回答日時： 2009/09/19 18:58

◆こんな方法はいかがでしょう

=IF(COUNT(A1:B1)<2,"",TEXT(A1-B1,"○;●;△"))

No.3 回答者： imogasi 回答日時： 2009/09/19 18:34

OR関数の理解が、根本的に誤解してますよ。

ＯＲ関数は（）内に条件式をカンマで区切って書き並べます。
その結論はＴＲＵＲかＦＡＬＳＥで、その各々（２通り）についてしか、セットしたい式や結果をかけません。
質問のようにＯＲの（）内に相反するA1<B1、A1>B1、A1=B1など並べません。
ＷＥＢででも照会して、学習してください。
多分質問の場合は、ＩＦ関数のネストを使う場合でしょう。
エクセルには、＝ＳＷＩＴＣＨ（A1<B1、A1>B1、A1=B1,"●",
"○","△")のようなのはありません（これは架空例です）。
多分質問の場合は、ＩＦ関数のネストを使う場合でしょう。
Ｇｏｏｇｌｅででも、｛エクセル　ＩＦ　ネスト」で照会して学ぶこと。
http://kokoro.kir.jp/excel/if-and.html
ＯＲ、ＡＮＤ関数利用でネストの深さを少なく出来ますが。
ネストの制限は２００３までは最大７までの制約がある。２００７では６４です。
ーー
現状の課題にＩＦ関数のネストでうまく式を作れたら、、
＞A1が空白のときは　未　と表示されるように・・
を追加するのは、ネストを外側に１つ増やすだけです。

No.2 回答者： KURUMITO 回答日時： 2009/09/19 18:13

Ａ１セルまたはＢ1セルが空のときに未とするように式の最後で行うような式をどうしてもするとしたら次のようになります。

=IF(A1<B1,"●",IF(A1>B1,"○",IF(AND(A1<>"",B1<>"",A1=B1),"△",IF(OR(A1="",B1=""),"未",""))))
ここでAND(A1<>"",B1<>"",A1=B1)はＡ1，B1の両セルが空白以外でＡ1とＢ1が同じの場合にはとなります。
OR(A1="",B1="")はＡ1またはＢ1が空ならばの意味になります。
通常はAND(A1<>"",B1<>""・・・のような式をなくするためには最後の式を最初に付けるようにします。
=IF(OR(A1="",B1=""),"未",IF(A1<B1,"●",IF(A1>B1,"○",IF(A1=B1,"△",""))))