WORD VBAでテキストファイルを指定して...

WORD２００２を使っています。
WORD　VBAでダイアログボックスを表示させ、オープンするファイルを指定しようとしています。

Documents.Open FileName:=dlg.Name, ReadOnly:=True

でオープンするファイルがテキストファイルだけなので、ダイアログボックスに表示するファイルをテキストファイルだけにしたいと思っています。
どのように変更すればいいのでしょうか？

No.2 ベストアンサー 回答者： enunokokoro 回答日時： 2012/01/07 00:17

単純なものなら、こちら↓みたいなものとか。

Sub TextFileOpen()
'
'既定の保存先であるファイルの場所を開く
'テキストファイルのみを指定
'
　With Dialogs(wdDialogFileOpen)
　　.Name = "*.txt"
　　.Show
　End With

End Sub

既定のコマンド" FileOpen "と基本的に同じものです。
組み込みの [ファイルを開く]ダイアログにて表示される
[ファイルの種類]が[テキストファイル]のみになるもの。
[ Dialogs プロパティ]のヘルプにも同じようなものが
あります。

この回答へのお礼

回答ありがとうございます。
うまくいきました。

お礼日時：2012/01/07 17:13

No.1 回答者： nicotinism 回答日時： 2012/01/06 22:28

色々方法はあるかと思いますが・・

Sub OpenTxt()
'要参照設定 Microsoft Office 10.0 Object Library
　　With Application.FileDialog(msoFileDialogFilePicker)
　　　　.InitialFileName = "C:\"　　　　　　　　'初期検索先指定
　　　　.Title = "ファイル選択 (複数選択不可)"
　　　　.AllowMultiSelect = False　　　　　　　　'複数ファイル選択の許可
　　　　.Filters.Clear　　　　　　　　　　　　 'ファイルフィルタの設定
　　　　.Filters.Add "すべてのファイル", "*.*"
　　　　.Filters.Add "Wordドキュメント", "*.doc"
　　　　.Filters.Add "テキストファイル", "*.txt;*.log"　　'下の[3]はここの事
　　　　.FilterIndex = 3　　　　　　　　　　　　'初期選択フィルタの設定
　　　　.ButtonName = "決定"　　　　　　　　　　'ボタンの表示文字列の設定
　　　　'キャンセル時にはShowメソッドは0(Long型)を返す
　　　　If CBool(.Show) Then
　　　　　　Documents.Open FileName:=.SelectedItems(1), ReadOnly:=True
　　　　End If
　　End With
End Sub

この回答へのお礼

回答ありがとうございます。
今回は、No.2の方が簡単なので、そちらでやってみます。

お礼日時：2012/01/07 17:15