空白セルのカウント方法

どなたかご存じでしたら回答をお願いします。
【質問】
各列毎に●や★が任意の数がある８行のセルがあります。
各列毎に８行目から上に遡り、●までの間の空白のセルを数える方法が知りたいです。
但し、★も”空白の１つ”として数えます。

【入力】
　　A　　B　　C　　D　　E　　Ｆ　　Ｇ　・・・・
1　●　　　　　　　　★
2　　　　　　　●　　●　
3　　　　　　　★　　　　　　　 ●
4　　　　　　　　　　　　　★
5　　　　　　　　　　　　　
6
7　　　　　　　　　　　　　　　　●
8　　　　　　　　　　　　　　　　　　　●

【結果】
　Ａ　Ｂ　Ｃ　　Ｄ　Ｅ　　Ｆ　Ｇ　・・・
　７　8　　6　　6　　8　　1　0

※結果の説明
Ａ：●の下には空白が７個。
Ｂ：●が無く空白が８個。
Ｃ：●の下に★があるが空白とみなして６個。
Ｄ：●の下に空白が６個。
Ｅ：★があるが空白とみなして８個。
Ｆ：●の下には空白が1個
Ｇ：●の下には空白が0個

使用するエクセルは２０１０です。

以上、よろしくお願いします。

No.1 ベストアンサー 回答者： tom04 回答日時： 2012/10/12 21:42

こんばんは！

一例です。

表示したいセルに
=8-MAX(IF(A1:A8="●",ROW(A1:A8)))
これは配列数式になってしまいますので、
Shift＋Ctrl＋Enterで確定！

この画面からコピー＆ペーストする場合は
あるセルに貼り付け後、数式バー内で一度クリック！
編集可能になりますので、Shift＋Ctrlキーを押しながらEnterキーで確定！
数式の前後に｛　｝マークが入り配列数式になります。

これを列方向にデータ分だけオートフィルでコピー！

これで何とかご希望通りにならないでしょうか？m(_ _)m

この回答へのお礼

早速の丁寧なご回答いただきありがとうございます！
早速教えて頂いた通りに入力して希望通りの結果になりました。

お礼日時：2012/10/12 23:35

No.4 回答者： mike_g 回答日時： 2012/10/12 22:00

添付図参照

A9: {=ROWS(A1:A8)-MAX((A1:A8="●")*ROW(A1:A8))}
　　(配列数式)

この回答へのお礼

ご回答いただきありがとうございます。
やってみたところ、希望どおりの結果になりました。

お礼日時：2012/10/12 23:46

No.3 回答者： kagakusuki 回答日時： 2012/10/12 21:56

　「A列の値を表示させるセル」に次の関数を入力してから、そのセルを右方向にドラッグして下さい。

（セルに入力するデータは文字列でも、数値でも有効です）

=ROW(A$8)-MAX(IF(COUNTIF(A$1:A$8,"*?"),MATCH("*?",A$1:A$8,-1),0),IF(COUNT(A$1:A$8),MATCH(9E+307,A$1:A$8),0))

この回答へのお礼

ご回答いただきありがとうございます。
教えていただいたとおりに入力しましたが、
Ｅ列が思う結果にならなかったのが残念です。

お礼日時：2012/10/12 23:45

No.2 回答者： keithin 回答日時： 2012/10/12 21:44

Ａ９に

=IFERROR(8-MATCH("●●",A1:A8,1),8)
と記入、右向けにコピーしておきます。



＃後出しで「実は違いましたこうでした」が無きゃいいんですが。

この回答へのお礼

いつもご回答いただきありがとうございます。
教えていただいたとおりに入力して得たい結果がでてきました。
ですので、「実は違いましたこうでした」とは言いません！
またよろしくお願いします。

お礼日時：2012/10/12 23:36