[VBA]改行入りのセルの値を配列に格納したい

EXCELのA列に下記のような値が入っています。

-----------
"aaa
bb
cccc"
-----------
"ddd"
-----------
""
-----------
"eee
fff
ggg
hhh"
-----------

といったようにセルの中の値に改行があったり、
なかったり、値すらなかったりといった感じです。

これを改行区切りで配列に入れたいんですが、いい方法ありませんか？

上の内容を下記のような配列にしたいんです。
arrValue=Array("aaa","bb","cccc")
arrValue=Array("ddd")
arrValue=Array("")
arrValue=Array("eee","fff","ggg","hhh")

よろしくお願いします。

No.1 回答者： nofx35 回答日時： 2013/10/17 22:24

以下のFunctionを標準モジュールに設定

Public Function GetArray(ByVal Target As Range) As Variant
　　If Target.Count > 1 Then Exit Function '複数のセルが渡されたらExit
　　GetArray = Split(Target.Value, vbLf) 'Splitを使い vbLfで分割し配列生成
End Function

使用例

Public Sub Try()
　　Dim Area As Range,rng As Range
　　Dim v() As Variant
　　Dim i As Long
　　'範囲指定
　　Set Area = Range("A1:A4")
　　'セルの数だけ配列を確保
　　ReDim v(Area.Count - 1) As Variant 'この場合v(0)からv(3)までの４つ確保
　　'指定範囲のセルを列挙
　　For Each rng In Area
　　　　'自作関数にrngを渡し配列を得る
　　　　v(i) = GetArray(rng)
　　　　i = i + 1
　　Next
　　Stop 'ここで止まるのでローカルウィンドでvの中身を確認
End Sub

No.2 ベストアンサー 回答者： h_tana_0530 回答日時： 2013/10/17 22:40

こんばんは。

ターゲットとなるセルをCells(y,x)とすれば
arrValue=Split( Cells(y,x).Value , vbLf )
でできそうです。　EXCEL 2010 で確認しました。
ただし、セル値に入力されていない場合（上の例では３行目）はエラーになるので、例外処理しておいた方がよいですね。

この回答へのお礼

お返事遅くなりました。

SPLIT関数っていうのがあったんですね。
区切り文字もchr(10)で判断しようとしてましたが、vblfは分かりやすくていいですね。
とてもシンプルな式でこんなのを望んでいました。
ありがとうございましたm(_ _)m

お礼日時：2013/10/18 20:18

No.3 回答者： kmetu 回答日時： 2013/10/17 22:54

とりあえずA列にデータがあるとして　B列から横方向1個の配列ごとにデータを入力していきます。

Sub Sample1()

Dim myArray() As String
Dim i As Long, j As Long
Dim c As Range

j = 2
For Each c In Range("A1:A" & Range("A" & Rows.Count).End(xlUp).Row)
myArray() = Split(c.Value, vbLf)
For i = 0 To UBound(myArray)
Cells(i + 1, j).Value = myArray(i)
Next i
j = j + 1
Next

End Sub

No.4 回答者： YON56 回答日時： 2013/10/18 10:06

配列としてデータを読み取りたいという要望ですが、

取扱可能なデータとして取り込む方法を書きます。
その方が実状に合っている気がしますので。

処理対象データがA1-A4セルにあるとして、

Dim A,B,C
Dim AA
Dim AAA()

ReDim AAA(4,10)
'4:処理対象データの数,10:処理対象データの中に存在する改行文字(Cahr(10))の想定最大値+1
For A=1 To 4
'処理対象データ:AAを取得
AA=Cells(A,1).Valu
'処理対象データの中に存在する改行文字数:Bを算定
B=Len(AA)-Len(Replace(AA,Chr(10),""))
If B>0 Then　
For C= 1 To B
'処理対象データのうち、左方より1番目の改行文字から左方の値を取得
AAA(A,C)=Left(AA,Instr(AA,Chr(10)-1)
'処理対象データのうち、左方より1番目の改行文字から右方の値を取得
AA=Right(AA,Len(AA)-Instr(AA,Chr(10))
Next C
'処理対象データのうち、最右方の改行文字から右方の値を取得
AA(A,C+1)=AA
Else
AAA(A,1)=AA
End If
Next A

AAA(A,B+1)から要求されるデータを引き出せます。
ちなみに　AAA(4,2)="fff" です。

No.5 回答者： watabe007 回答日時： 2013/10/18 11:04

こんにちは、参考に

Sub Test()
　　Dim arrValue(), v As Variant
　　Dim c As Range, i As Long, j As Long

　　i = -1
　　For Each c In Range("A1", Cells(Rows.Count, "A").End(xlUp))
　　　　If c.Value = "" Then
　　　　　　i = i + 1
　　　　　　ReDim Preserve arrValue(i)
　　　　　　arrValue(i) = ""
　　　　Else
　　　　　　v = Split(c.Value, vbLf)
　　　　　　For j = 0 To UBound(v)
　　　　　　　　i = i + 1
　　　　　　　　ReDim Preserve arrValue(i)
　　　　　　　　arrValue(i) = v(j)
　　　　　　Next
　　　　End If
　　Next
　　'<<< 配列確認 >>>
　　For i = 0 To UBound(arrValue)
　　　　MsgBox arrValue(i)
　　Next
End Sub