Excel Slope関数 繰返し処理の簡略化

ExcelのSlope関数をVBAで繰返し処理させたいのですが、自分が作製したプログラムですと、処理に時間がかかってしまう事がわかりました（正常動作はするのですが、Excelの動きが鈍い）。
動きが遅くなってしまう部分はおそらくここだろうと部分をピックアップしたので、処理が軽くなる方法がわかる方いらっしゃいましたら、教えて下さい。宜しくお願い致します。



i = 1
n = 55
Do While i < 3
i = Sheets("Sheet2").Cells(n, 2)
n = n + 1
Loop
n = n - 2

Worksheets("Sheet3").Range("Q16").Formula = "=Slope(Sheet2! C55:C" & n & ",Sheet2!B55:B" & n & "）"
Worksheets("Sheet3").Range("Q17").Formula = "=Slope(Sheet2! E55:E" & n & ",Sheet2!D55:D" & n & "）"
Worksheets("Sheet3").Range("Q18").Formula = "=Slope(Sheet2! G55:G" & n & ",Sheet2!F55:F" & n & "）"
・
・
・
・
・

Worksheets("Sheet3").Range("Q28").Formula = "=Slope(Sheet2! AA55:AA" & n & ",Sheet2!Z55:Z" & n & "）"

No.2 ベストアンサー 回答者： cj_mover 回答日時： 2013/11/12 14:42

こんにちは。

数式を出力するもの、
値を出力するもの、
２例、挙げておきます。

１）遅くなる原因を十分に（未然に）（場合によっては必要以上に）排除しておく。
２）オブジェクトへの参照は必要最小限にして、繰り返さない。
３）計算を実行するタイミングを一度に纏める。

３）については、本来は配列変数を使って数式を一気に出力するのが有力ですが、
ここでは、数式の先頭に全角空白を付加した文字列を一旦出力して、
置換機能で全角空白を削除するタイミングで計算させます。

「数式を出力するもの」
現状問題の遅さ、についての手当てとしては、主に３）の効果が大きいと思いますが、
１）２）については、ExcelyaExcel VBAを扱う上では、一応基本的な手法ですので、
書き加えています。

「値を出力するもの」
出力する数式の参照先のデータが変動値ではなく、固定であるならば、
ＶＢＡで計算したものを値で出力することで、実行を軽くできますし、
ファイルそのものを軽くできます。

１）の記述は、元に戻す処理と対になっています。
他の処理を書き加える時は、エラーに備えて、確実に元に戻すように
エラーを制御するよう検討してください。


この手のテーマは、方法を伝えるよりサンプルを示した方が
解り易いんじゃないかな、と思ったので、例示として以下を提示します。


' ' 「数式を出力するもの

Sub Re8344147f()
　　Dim rRef As Range
　　Dim n As Long
　　Dim i As Long

　　With Sheets("Sheet2")　　'　　２）
　　　　For i = 55 To .Cells(Rows.Count, 2).End(xlUp).Row
　　　　　　If .Cells(i, 2) >= 3 Then Exit For
　　　　Next i
　　End With
　　n = i - 2

　　With Application　　'　　１）
　　　　.Calculation = xlCalculationManual
　　　　.EnableEvents = False
　　　　.ScreenUpdating = False
　　End With
　　Set rRef = Range("A55:A" & n)　　'　　２）
　　With Worksheets("Sheet3").Range("Q16:Q28")　　'　　２）
　　　　For i = 1 To 13　　'　　３）↓
　　　　　　.Cells(i).Value = "　=Slope(Sheet2!" & rRef.Offset(, i * 2).Address(0, 0) & ",Sheet2!" & rRef.Offset(, i * 2 - 1).Address(0, 0) & "）"
　　　　Next i
　　　　.Replace "　", ""　　'　　３）
　　End With
　　Set rRef = Nothing
　　With Application　　'　　１）
　　　　.Calculation = xlCalculationAutomatic
　　　　.EnableEvents = True
　　　　.ScreenUpdating = True
　　End With
End Sub



' ' 「値を出力するもの」

Sub Re8344147v()
　　Dim rRef As Range
　　Dim n As Long
　　Dim i As Long

　　With Sheets("Sheet2")　　'　　２）
　　　　For i = 55 To .Cells(Rows.Count, 2).End(xlUp).Row
　　　　　　If .Cells(i, 2) >= 3 Then Exit For
　　　　Next i
　　End With
　　n = i - 2

　　With Application　　'　　１）
　　　　.Calculation = xlCalculationManual
　　　　.EnableEvents = False
　　　　.ScreenUpdating = False
　　End With
　　Set rRef = Sheets("Sheet2").Range("A55:A" & n)　　'　　２）
　　With Worksheets("Sheet3").Range("Q16:Q28")　　'　　２）
　　　　For i = 1 To 13
　　　　　　.Cells(i).Value = Application.Slope(rRef.Offset(, i * 2), rRef.Offset(, i * 2 - 1))
　　　　Next i
　　End With
　　Set rRef = Nothing
　　With Application　　'　　１）
　　　　.Calculation = xlCalculationAutomatic
　　　　.EnableEvents = True
　　　　.ScreenUpdating = True
　　End With
End Sub

この回答へのお礼

ご回答ありがとうございました。
サンプル構文の提示もありがとうございました。

' ' 「数式を出力するもの

で記載して頂いたマクロを自分のExcelファイルに貼り付けて、一部変更して使用したところ今までのマクロの3倍くらい速い速度で処理できました。

しかし、まだマクロ入門したばかりなので、この構文ですともし使用現場で何か不具合があった際に対応ができない懸念点が残ってしまいます。

ですので、せっかく教えて頂いたのですが、今までのマクロで職場の先輩に教えて頂いた内容を少し取り入れたもので運用したいと思います。

お忙しいところご回答いただきましてありがとうございました。

お礼日時：2013/11/12 17:13

No.1 回答者： play_with_you 回答日時： 2013/11/12 10:56

「どれくらい」遅くなるかがかかれてないけど、とりあえずブックの自動再計算がオンなら、関数を挿入するたびに再計算されるので多少は遅くなるでしょうね。

一時的に自動再計算をオフにするか、もしくは「そもそもそのセルにSLOPE関数が必要なのか」を考え直すかです。

念のため説明。
「そもそもそのセルにSLOPE関数が必要なのか」というのは「そのセルに“関数が入っている必要”はあるのか」ということです。
もし結果がそのセルに入ればいいならわざわざSLOPE関数を入れるのではなくVBA内で計算してしまえばいいのですから。
関数をどうVBAで使うか知らないなら↓
https://www.google.co.jp/search?q=vba+worksheetf …