画像を削除したい（ＶＢＡ）

指定したセルにある画像を削除する様にしたいのですが、
マクロで記録すると、どうしても（Picture 32）のど写真に番号が付いてしまいます。
写真は、その都度変わるので、指定の場所にある例えば、C5セルにある画像だけを消すＶＢＡを教えて下さい。
宜しくお願いします。

No.3 ベストアンサー 回答者： KenKen_SP 回答日時： 2007/02/05 13:00

こんにちは。

２つほどサンプルを。ご参考までに。

' // C5セル内に画像左上角がある場合は削除
' // 画像右下がC5セルからはみ出しているかどうかを問わない
Sub SampleProc1()

　　Dim Pic As Picture
　　For Each Pic In ActiveSheet.Pictures
　　　　If Pic.TopLeftCell.Address = "$C$5" Then
　　　　　　Pic.Delete
　　　　End If
　　Next

End Sub


' // セルの選択範囲内に完全に含まれる画像を削除
Sub SampleProc2()

　　Dim Pic As Picture
　　Dim r　 As Range
　　
　　If UCase$(TypeName(Selection)) <> "RANGE" Then Exit Sub
　　For Each Pic In ActiveSheet.Pictures
　　　　Set r = Range(Pic.TopLeftCell, Pic.BottomRightCell)
　　　　If Selection.Address = Union(Selection, r).Address Then
　　　　　 Pic.Delete
　　　　End If
　　　　Set r = Nothing
　　Next

End Sub

この回答へのお礼

大変助かりました。
ありがとうございました

お礼日時：2007/02/05 13:29

No.2 回答者： zap35 回答日時： 2007/02/05 12:58

こんな感じでしょうか。

ただし画像左上がC5にないと削除されません。
セルを覆い隠すように配置されているなら補足してください

Sub Macro()
Dim shp As Shape
　For Each shp In ActiveSheet.Shapes
　　If shp.TopLeftCell.Address = "$C$5" Then
　　　shp.Delete
　　End If
　Next shp
End Sub

この回答へのお礼

大変助かります。
ありがとうございました

お礼日時：2007/02/05 13:30

No.1 回答者： marbin 回答日時： 2007/02/05 09:20

TopLeftCell

で判断してはいかがでしょう？

この回答へのお礼

TopLeftCellでも判断できました。
ありがとうございました。

お礼日時：2007/02/05 13:31