VBからExcelに書き込む方法

こんにちは。VB6.0(SP5),Excel2000,Win2000でVBの勉強をしています。
VBでコマンドボタンを押した時に、テキストボックスのデータを、Excelに書き込みたいと思っています。
特定のExcelに書き込むことは「GetObject」で出来たのですが、名前がわからない場合はどうしたらよいのでしょうか？

※ExcelはVBから起動したものではなく、人が任意のファイルを起動しています。Excelの名前はわかっていません(任意なので、何かわかりません）

このような場合に、VBから書き込むのは可能なのでしょうか？
よろしくお願いします。

No.2 ベストアンサー 回答者： aki_aero 回答日時： 2004/11/12 17:41

'Microsoft Excel への参照を格納する変数を宣言します。

Dim xlApp As Excel.Application
Dim xlBook As Excel.Workbook
Dim xlSheet As Excel.Worksheet


'Microsoft Excel が既に起動されているかどうかを調べます。
'第 1 引数を指定せずに GetObject 関数を呼び出すと、
'アプリケーションのインスタンスへの参照が返されます。
'Microsoft Excel が起動されていないと、エラーが発生します。
Set xlApp = GetObject(, "Excel.Application")

If Err.Number Then
MsgBox "Excel が起動されていません。"
' エラーが発生した場合は Err オブジェクトをクリアします。
Err.Clear
Else
' MsgBox "Excel はすでに起動中です。"
Set xlBook = xlApp.Workbooks.Item(1)
Set xlSheet = xlBook.Worksheets.Item(1)

xlSheet.Cells(3, 5) = Me.Text1.Text
End If

上記のプログラムで開いてるエクセルの１つめのブックの１つめのシートにテキストボックスのデータが書き込まれます。
いかがでしょうか？

この回答へのお礼

回答ありがとうございます。
GetObjectは引数なしで使えるのですね。大変参考になりました。ありがとうございます。

お礼日時：2004/11/13 01:10

No.4 回答者： imogasi 回答日時： 2004/11/12 19:38

ActiveBook、ActiveSheetが使えるかテストしてみました。

名前を使っていません。エクセルが起動されているか・アクチブブックが存在するかどうかはチェックなし。
Private Sub Text1_KeyDown(KeyCode As Integer, Shift As Integer)
If KeyCode = 13 Then
MsgBox Form1.Text1.Text
Set xlapp = GetObject(, "Excel.Application")
'Set xlbk = xlapp.workbooks("Book1")
Set xlbk = xlapp.activeworkbook
'Set xlsh = xlbk.Sheets("sheet1")
Set xlsh = xlbk.activesheet
xlsh.cells(1, "C") = Form1.Text1.Text
End If
End Sub
上手く行くようです。
今開かれてアクチブになっているブック・シートにテキストボックスの値を（C1セルに）セットしました。
コメント化した行でも上手く行きます。
Msgboxは確認用。

この回答へのお礼

回答ありがとうございます。参考になりました。

お礼日時：2004/11/13 01:12

No.3 回答者： sam_inoue 回答日時： 2004/11/12 18:53

>特定のExcelに書き込むことは「GetObject」で出来た

>のですが、名前がわからない場合はどうしたらよいの
>でしょうか？
>※ExcelはVBから起動したものではなく、人が任意の
>ファイルを起動しています。Excelの名前はわかって
>いません(任意なので、何かわかりません）
GetObjectで開いているExcelは掴めたが、
何のブックが開いているか解らないということですね。
Set xlApp = GetObject(, "Excel.Application")
の後、
For Each objWbk In xlApp.Workbooks
If objWbk.Name = "HOGE.xls" Then
' 目的のブックへの処理
End If
Next
とすれば開いている中で所望するブックに対して
処理ができます。
開いていなければ未処理で終わらせるとか、
その時点で開くとか、
後は方法を考えて下さい。

この回答へのお礼

回答ありがとうございます。参考になりました。

お礼日時：2004/11/13 01:12

No.1 回答者： 2ch 回答日時： 2004/11/12 13:28

私だけでしょうか、質問の意味がわからないのは・・・(だいたひかる風)

GetObject(, "Excel.Application")
を知りたいのでしょうか？

>特定のExcelに書き込むことは「GetObject」で出来たのですが、
というのであれば、その部分の抜粋を記さないと、既存が読めません。

現在はGetObjectのパラメータをどのように利用しているのでしょうか？

この回答へのお礼

返答ありがとうございます。
特定のexcelというのは、名前がわかっている場合という意味で書きました。

お礼日時：2004/11/13 01:08