抽出後の行の最上段と最下段を参照したいのですが・・・

ある行をオートフィルで抽出したとして
その一番上の数字（または文字列）と一番下の数字を参照する方法、または関数があればお願いしたいのですが、ご存知の方よろしくお願いします。

No.1 ベストアンサー 回答者： LOSSIGNOR 回答日時： 2008/03/08 01:06

作業列が要りますが、私なら以下のようにやります。

形は以下のようなものを前提。
データは説明の都合上、100行目まであるとします。

・Ａ２に、=SUBTOTAL(3,$B$2:B2)　と入力。そして、一番下（Ａ100）まで引っ張る。

・Ｂ１は、「県名」とでもしましょうか。Ｂ２～Ｂ１００までいろいろな県名が入っています。

・Ｃ１は、「数量」としましょう。Ｃ２～Ｃ１００までデータが入っています。

・Ｅ１に　=VLOOKUP(1,$A$2:$C$100,3,0)　と入力
・Ｆ１に　=VLOOKUP(MAX($A$2:$A$100),$A$2:$C$100,3,0)　と入力。

・Ｂ１とＣ１を選択し、フィルタを設定。

このうえで、Ｂ列の県名で抽出した場合に、Ｅ１に一番上の数字、Ｆ１に一番下の数字が出ると思います。

この回答へのお礼

LOSSIGNOR様、ご回答ありがとうございました＾＾

いただきました式を試しましたところ、仰るとおりの結果がでました。
また、説明もわかりやすく助かりました。

私のシートにそのまま使えそうですので、ありがたく頂戴いたします＾＾

お礼日時：2008/03/08 22:47

No.2 回答者： maron--5 回答日時： 2008/03/08 01:44

　　　　A　　　　　B　　　　　C　　　　D

1　　　県名　　　数量　　　88　　　12
2　　　京都　　　88
3　　　大阪　　　14
4　　　奈良　　　25
5　　　大阪　　　63
6　　　京都　　　1
7　　　大阪　　　6
8　　　兵庫　　　12

◆上のような場合で
C1：B列の最上段、D1：B列の最下段　のデータ
C1=INDEX(B2:B10,MATCH(1,INDEX(SUBTOTAL(3,INDIRECT("B"&ROW(B2:B10))),),0))
D1=LOOKUP(1,1/SUBTOTAL(3,INDIRECT("B"&ROW(B2:B10))),B2:B10)

★フィルタで県名を「大阪」なら、C1＝14　、D1＝6　になります

この回答へのお礼

maron--5様、ご回答ありがとうございます＾＾

関数が複雑ですので、自力では思いつかない内容です＾＾；
私のシートにも応用できそうですので、使用させていただきます。

お礼日時：2008/03/08 22:31