エクセルのことで質問です

うまく説明ができないかもしれないのですがよろしくお願いします<(_ _)>

シート１
会社名　　氏名　　　携帯番号
○○会社　山田太郎　090-****-****
○○会社　佐藤次郎　090-****-****
○○会社　田中三郎　090-****-****
××会社　松尾四郎　090-****-****
××会社　小泉五郎　090-****-****
　　　　　　　　・
　　　　　　　　・
　　　　　　　　・
シート２
会社名　　氏名　　　携帯番号
××会社　松尾四郎

というデータがあって、シート２で××会社の松尾さんの携帯番号を抽出したい時は何の関数を使えば良いでしょう？

No.7 ベストアンサー 回答者： stones 回答日時： 2003/06/27 02:08

作業セルを作ってよいのであれば、シート１（Sheet1）の会社名の

左横に＝B1&C1として、ひとつのセルに会社名と氏名を合体させて表示します。

次に、シート２の携帯番号のセルに
=VLOOKUP(A2&B2,Sheet1!A:D,4,FALSE)とすると良いと思います。

この回答へのお礼

ありがとうございました<(_ _)>
この方法が簡単でしたので使わせていただきます。

お礼日時：2003/06/27 09:30

No.8 回答者： maruru01 回答日時： 2003/06/27 09:32

こんにちは。

maruru01です。

配列数式を使う方法です。

Sheet2のC2を選択して、数式バーに、

=IF(SUMPRODUCT((Sheet1!$A$2:$A$6=A2)*(Sheet1!$B$2:$B$6=B2))=0,"",VLOOKUP(A2,IF(Sheet1!$B$2:$B$6=B2,Sheet1!$A$2:$C$6,""),3,FALSE))

と入力して、まだ数式バーにカーソルがある状態で、[Ctrl]と[Shift]を押しながら[Enter]を押して決定します。
（数式の両端に「{}」が付きます。）
一応、エラー処理はしてあります。

No.6 回答者： shigechama 回答日時： 2003/06/27 00:18

＃２です。

初心者なのでむずかしいことはわかりませんので、
聞き流していただいていいです"^_^"

同姓同名の方だけ、
山田太郎Ａ
山田太郎Ｂ
などとされてはいかがでしょうか。

氏名で、１度並び替えをしてみれば同姓同名は一目瞭然ですもんね。
１００件ほどでしたら、そんなにはないのでは？

失礼いたしました。

この回答へのお礼

ありがとうございました<(_ _)>

お礼日時：2003/06/27 09:30

No.5 回答者： Hageoyadi 回答日時： 2003/06/27 00:17

#4です。

アタシの方法では携帯番号が文字列として入力されているとエラーが出ます。数値として入力し、なおかつ「-」などはセルの書式設定で自動表示するようにしないと使いにくいですね。

あまりお役に立てず申し訳ありません。

この回答へのお礼

ありがとうございました<(_ _)>

お礼日時：2003/06/27 09:31

No.4 回答者： Hageoyadi 回答日時： 2003/06/27 00:06

配列関数を使う式のはずですが、うまく動作しませんでした。

で、代替案
シート２のC2=SUMPRODUCT((一覧!A3:A29=抽出!A2)*(一覧!B3:B29=B2)*(一覧!C3:C29))

シート１の名前が「一覧」でシート２は「抽出」って名前です。
抽出シートの1行目に項目名を入力し、A２に抽出したい会社名、B2に氏名を入力してください。

この回答へのお礼

ありがとうございました<(_ _)>

お礼日時：2003/06/27 09:31

No.3 回答者： taisuke555 回答日時： 2003/06/26 23:56

=INDEX(Sheet1!C2:C6,SUMPRODUCT((Sheet1!A2:A6=A2)*(Sheet1!B2:B6=B2)*ROW(Sheet1!C2:C6))-1,0)

でどうですか？

ちょっと式が長いですし、エラー処理してませんが・・・

この回答へのお礼

ありがとうございました<(_ _)>

お礼日時：2003/06/27 09:31

No.2 回答者： shigechama 回答日時： 2003/06/26 23:41

ＶＬＯＯＫＵＰ関数でできます。

シート２のＣ２をアクティブにしてＶＬＯＯＫＵＰ関数、
検索値はシート２のＢ２、
範囲はシート１のデータすべてを選択し絶対参照、
列番号は選択したデータの何列目に携帯番号が入っているか、
検索のかたちは“０”でできます。

同姓同名に対応するには、番号の列を作り、
検索値を氏名ではなく番号にするといいと思います。
わかりにくい説明ですみません。

この回答へのお礼

やっぱり番号を入力した方が良いんですね。
番号にすると抽出する人の番号を覚えないと、入力に時間がかかるという難点から避けてました。
件数が１００件以上はあるので会社名と名前で抽出する方法はないのかと思い質問しました。
ありがとうございました<(_ _)>

お礼日時：2003/06/26 23:50

No.1 回答者： happypoint 回答日時： 2003/06/26 23:29

こんばんわ。

VLOOKUP関数ですね。
同姓同名があると混乱の原因になります。

この回答への補足

すいません。説明が足りなかったみたいですね<(_ _)>
「会社名」と「氏名」の両方で電話番号を抽出したいのです。
VLOOKUP関数だと、違う会社に同姓同名があったら抽出できませんから・・・<(_ _)>

補足日時：2003/06/26 23:34