入力された文字数をカウントする方法

毎々おせわになっております。
サウナマンです。

会社内で秀丸エディタ3.10を愛用しています。
よくあるなーと最近気がついて質問させて頂きたいのですが、
秀丸には入力された文字の数をカウントする機能が
あるのでしょうか？
半角で何文字入力されているのか、全角文字は？
といった情報を優秀（？）な秀丸エディタが
できないわけないと思いHELPを調べたのですが、、、、
調べたいときにワードに持っていって調べているのが
疲れてしまったサウナマンです。

なにとぞ、よろしくお願いいたします！

No.2 ベストアンサー 回答者： route156 回答日時： 2002/01/30 18:25

　機能が無くてもマクロで実現できます…というかそれが普通だと思います。

携帯にメールする際に使っているものがありますので、一部手を入れて貼り付けておきます。試してみてください。
　～キチンとしたものは検索すればいくつか見つかるはずです。

　以下をメモ帳（または秀丸）に貼り付けて count.mac のファイル名で秀丸のフォルダ（C:\Program Files\Hidemaru ?）に保存してください。[マクロ] メニューの [マクロ実行] で count.mac をダブルクリックすると文字数を数えて表示します。半角全角共に空白を除いた数です。

// --- count.mac ---
gofiletop;
selectall;
copy;
beginclipboardread;
#count_han = 0;
#count_zen = 0;
$line = getclipboard;
while ($line != "") {
#len = strlen($line);
#pos = 0;
while (#pos < #len) {
#c = ascii(midstr($line, #pos, 1));
if (#c >= 0x100) {
#c = ascii(midstr($line, #pos, 2));
if (#c != 0x8140) // この行を削除すると全角空白もカウント
#count_zen = #count_zen + 1;
#pos = #pos + 2;
} else {
if (#c >= 0x21) // 0x20 に書き換えると半角空白もカウント
#count_han = #count_han + 1;
#pos = #pos + 1;
}
}
$line = getclipboard;
}
message "半角 : " + str(#count_han) + "\n全角 : " + str(#count_zen);
// --- end ---

参考URL：http://hidemaru.xaxon.co.jp/lib/macro/

この回答へのお礼

あああーすばらしい。うっとりです。
本当にありがとうございます。
参考ＵＲＬも大変グッドでした。
これからもよろしくお願いいたします。

お礼日時：2002/02/03 16:23

No.1 回答者： Zz_zZ 回答日時： 2002/01/30 04:25

　お調べの通り、有りません。

　作者にリクエストしてみましょう。