EXCEL VBAについて、ワークシート上に置いたTextBoxに値を入れる方法について

すいませんEXCEL VBAについて質問があります。
エクセルのワークシート上にコントロールツールボックスから
テキストボックスを２つ、コマンドボタンを１つ設置する。
アクティブになっているテキストボックスに”goo”という値を入れる。
これをVBAで処理するにはどうしたらよろしいのでしょうか。
ユーザーフォームのテキストボックスであれば
Private Sub CommandButton1_Click()
Dim i As Object
Set i = ActiveControl
If TypeOf i Is MSForms.TextBox Then
i.Text = i.Text & "goo"
End If
Set i = Nothing
End Sub
これでできるはずですが、シート上に置くテキストボックスだと
うまくいきません。
よろしくお願いいたします。

No.3 ベストアンサー 回答者： lark_0925 回答日時： 2009/03/27 07:08

Getfocusイベントで対応しては　いかがですか？

例　当該シートに　Textbox1　Textbox2　Commandbutton1
が配置されていた場合で考えます。

シートモジュールに

Option Explicit
Private atobj As Object
Private Sub CommandButton1_Click()
　　If TypeName(atobj) = "TextBox" Then
　　atobj.Text = atobj.Text & "goo"
　　End If
End Sub
Private Sub TextBox1_GotFocus()
　　Set atobj = TextBox1
End Sub
Private Sub TextBox2_GotFocus()
　　Set atobj = TextBox2
End Sub
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
　　Set atobj = Nothing
End Sub

この回答へのお礼

お返事が遅くなり大変申し訳ございません。
やりたかった処理が出来ました。ありがとうございます。
Getfocusイベントを知らなかったので勉強になりました。
またよろしくお願いいたします。

お礼日時：2009/04/11 08:14

No.2 回答者： xls88 回答日時： 2009/03/27 03:18

ActiveSheet.TextBox1.Value = "あいうえお"

ActiveSheet.TextBox1.Select
Selection.Object.Value = "あいうえお"

No.1 回答者： xls88 回答日時： 2009/03/27 00:43

ActiveSheet.OLEObjects("TextBox1").Object.Value = "あいうえお"