テーブルへのデータ追加の元となるクエリの探し方

Ａｃｃｅｓｓのあるテーブルがあります。
そのテーブルには、クエリによりレコードが追加されていると思われるのですが、どのクエリを元にレコードが追加されているのか不明です。
どのクエリを元にレコードが追加されているのかを探り当てるには、どのようにしたらよいか、ご教授願います。

※ Ｗｉｎ ＸＰ、Ａｃｃｅｓｓ2002で作業しています。

No.2 ベストアンサー 回答者： DexMachina 回答日時： 2011/03/06 11:44

こちらの環境はWinXP＆Access2003ですが、多分2002とはそれほど

違わないと思いますので・・・

> どのクエリを元にレコードが追加されているのかを探り当てる

【Accessの機能を利用する方法】
追加クエリの場合、データベースウィンドウ(クエリ等が一覧表示される
画面)で、アイコン上にマウスポインタをその上に置くと、ヒントテキストの
形で追加先のテーブル名が表示されます。
(テーブル作成クエリも同じ方法で確認可。削除・更新クエリは不可)

ですので、追加クエリの数がそれほど多くないようでしたら、この方法で
1件ずつ確認していけるかと思います。


【ユーザー定義関数を使用する方法】
クエリの数が多いようでしたら、下記コードを『標準モジュール』に保存
して、実行してください。

実行方法としては、イミディエイトウィンドウ(→Ctrl+Gキーで表示される
画面)で「?WhereFrom("テーブル名")」と入力し、Enterキーで次行に
移ります。
これで、その下に、引数で指定したテーブルに対して追加を行うクエリの
名前が列挙されます。
※追加先にテーブルではなくクエリを指定している場合には非対応(汗)

Public Function WhereFrom(TblName As String) As String
On Error GoTo エラー処理

　　Dim Rsl As String, sTemp As String, nLen As Long, sMsg As String
　　Dim Dbs As DAO.Database, Tdf As DAO.TableDef, Qdf As DAO.QueryDef

　　'テーブルの確認(存在しない場合はエラー処理に飛ぶ)
　　Set Dbs = CurrentDb
　　Set Tdf = Dbs.TableDefs(TblName)

　　'「指定テーブルへの追加クエリ」を判定する条件の確認
　　sTemp = "Insert Into " & TblName & " "
　　nLen = Len(sTemp)

　　'全クエリのSQL文を確認
　　For Each Qdf In Dbs.QueryDefs
　　　　'当該テーブルへの追加クエリなら、名前を「Rsl」に記録
　　　　If Left(Qdf.SQL, nLen) = sTemp Then Rsl = Rsl & Qdf.Name & vbCrLf
　　Next

　　If Rsl = "" Then Rsl = "<該当する追加クエリはありません>"

終了処理:
　　WhereFrom = Rsl
　　Set Tdf = Nothing
　　Set Qdf = Nothing
　　Set Dbs = Nothing
　　Exit Function

エラー処理:
　　If Err.Number = 3265 Then
　　　　Rsl = "<指定した名前のテーブルはありません>"
　　Else
　　　　Rsl = "【Error】" & Err.Number & "：" & Err.Description
　　End If
　　Resume 終了処理

End Function


<注意>
上記のコードでは「DAO」というものを使用していますので、以下のサイト
を参考に、参照設定を行って下さい：
http://www.accessclub.jp/actips/tips_20.htm
(なお、上記コードでは「DAOコンポーネントの利用」を宣言しているので、
　「ADO」よりも上位に位置させる必要はありません：
　「Access2000、Access2002でDAOを用いる場合」の「6」を参照))

※優先順位は、特にいじらないことをお勧めします。
　(既存のコードがADOを使用していて、かつ、「ADOの利用」を宣言して
　 いない場合、優先順位の変更はエラーの原因となる危険性があります)

この回答へのお礼

回答ありがとうございました。
細かく書き込みしていただき、痛み入ります。
大変勉強になりました。
本当にありがとうございました。

お礼日時：2011/03/08 08:23

No.3 回答者： 30246kiku 回答日時： 2011/03/07 22:29

解決されていたでしょうか。

であればスルーということに。

フリーのツールを使うっていうのはどうでしょう。
相関図等、Excelに出力してくれるようです。
（どこまでの結果を求めるかによるとは思いますが）

AccessMDB解析ツール
http://www.vector.co.jp/soft/dl/win95/business/s …


なお、＃１さんが言われている UPDATE についても調べられるとよいと思います。
（UPDATE でも追加できますので）


UPDATEでの追加の一例を以下に

テーブル「TA」「TB」が同じフィールド構成であるとします。

テーブル「TA」の内容

ID　　　内容
1　　　AAAAAA
3　　　CCCCCC
5　　　EEEEEE

テーブル「TB」の内容

ID　　　内容
2　　　BBBBBB
5　　　abcdef
6　　　FFFFFF

テーブル「TA」を元に、テーブル「TB」に追加されている ID を「TA」に追加して

テーブル「TA」の内容

ID　　　内容
1　　　AAAAAA
2　　　BBBBBB
3　　　CCCCCC
5　　　EEEEEE
6　　　FFFFFF

としたい場合、以下のSQLを書く時があります。


UPDATE TA RIGHT JOIN TB ON TA.ID=TB.ID
SET TA.ID = TB.ID, TA.内容 = TB.内容
WHERE (TA.ID Is Null);

この回答へのお礼

回答ありがとうございました。
なるほど！フリーのツールを探せば良かったんですね。
また、ご丁寧に書き込みいただき、ありがとうございました。

お礼日時：2011/03/08 08:25

No.1 回答者： nicotinism 回答日時： 2011/03/03 16:28

追加クエリはクエリ名のアイコンにプラス記号が

更新クエリは鉛筆記号が付いています。
これを頼りにクエリをデザインビューで開いて
さらに右クリックでSQLビューに切り替えます。
追加クエリなら INSERT INTO ○○
更新クエリなら UPDATE ○○
になっていますので、○○ がテーブル名です。
http://www.geocities.jp/allmemo11/access01_2.html

※クエリを右クリックでプロパティ画面を出して、説明欄に
簡単な説明を入力。
メニューバーから、表示→詳細 切り替えれば先ほどの説明が出るので
宜しかったらどうぞ。

この回答へのお礼

回答ありがとうございました。
勉強になりました。

お礼日時：2011/03/08 08:22