エクセル連続した月表示

お世話になります。

セルA1に5月と入力したら
F2に5月
E2に4月
D2に3月
C2に2月
B2に1月
A2に12月

と返る計算式をご教授下さい。
A1には12月と入力する場合もありまして
その際も遡って半年分返るようにお願いします。

言葉足らずなら補足させて頂きます。
宜しくお願い致します。

No.5 ベストアンサー 回答者： MackyNo1 回答日時： 2014/05/30 00:56

単純にセルに過去6か月分の月を表示するだけなら、A2セルに以下の式がを入力し右方向にオートフィルコピーするのが何の設定も必要ないので簡単かもしれません。

=MOD(SUBSTITUTE($A$1,"月","")+COLUMN(A:A)+5,12)+1&"月"

No.6 回答者： mshr1962 回答日時： 2014/05/30 12:20

A1セルの内容で式が変わります。

■A1=5　で表示形式が　0"月"
A2=IF(COUNT($A$1),TEXT(DATE(2000,$A$1+COLUMN()-6,1),"M月"),"")
でF2までコピー

■A1=2014/5/1　で表示形式が　M"月"
A2=IF(COUNT($A$1),TEXT(EDATE($A$1,COLUMN()-6),"M月"),"")
でF2までコピー

■A1="5月"
A2=IF(COUNTIF($A$1,"*月"),TEXT(EDATE(DATEVALUE("2000年"&$A$1&"1日"),COLUMN()-6),"M月"),"")
でF2までコピー

No.4 回答者： bunjii 回答日時： 2014/05/29 19:45

>その際も遡って半年分返るようにお願いします。

A1は文字列で入力されているものとします。
質問のようにA1セルが5月で検証してみました。

F2=MONTH(DATE(1,SUBSTITUTE($A$1,"月","")-COLUMNS($F2:F2)+1,1))&"月"
SUBSTITUTE関数でA1セルの文字を数字のみに置き換えてCOLUMNS関数でセル位置による減算値を決めます。
DATE関数では年数を今年にする必要はありませんが、1以上にしないと日付のシリアル値が負数になるときがありますので注意が必要です。
DATE関数で月の値を0になると12月に、-1になると11月になります。
F2セルをオートフィルで左へA2セルまでコピーすれば目的通りになります。
オートフィルは一般的に右と下へコピーしますが左や上へもコピーできます。

No.3 回答者： mike_g 回答日時： 2014/05/29 17:54

範囲 A2:A2 を“ユーザー定義”で

G/標準"月"
に書式設定しておく。
セル A1 に 1～12 の正整数を入力
セル A2 に次式を入力して、此れを右方にドラッグ＆ペースト
=MONTH(DATE(YEAR(TODAY()),$A1-6+COLUMN(),1))

No.2 回答者： tom04 回答日時： 2014/05/29 17:53

こんにちは！

単に表示だけで良いのですね？

A1セルの表示形式は　ユーザー定義　から
0月
としておき、A1セルには　1～12　の数値だけを入力します。

そして、A2セルに
=TEXT(DATE(2014,$A1+COLUMN(G1),1),"m月")
という数式を入れF2セルまでフィルハンドルでコピーしてみてください。m(_ _)m

No.1 回答者： keithin 回答日時： 2014/05/29 17:14

Ａ１セルには「5月」と言葉で記入する

Ａ２セルには
=IF($A$1="","",TEXT(DATE(YEAR(TODAY()),SUBSTITUTE($A$1,"月","")-6+COLUMN(A2),1),"m月"))
と記入、右にコピーする。






＃参考
「言葉」で何月とかやるんじゃなくて、年/月/日で記入或いは計算、必要に応じて表示形式で見せ方を工夫することで、続きの計算にも利用しやすく（＝応用しやすく）なります。
具体的な計算例は上述した通りです。