エクセル関数を教えてください.続き２

以前教えていただいた数式について再度質問させていただきます。
エクセルで作成した表から２つの条件の事柄を他のシートに抽出する方法を教えてください。
例えば
グループ　名前　　作成月
A 　　　　浅井　　１
A 　　　　伊藤　　３
Ａ　　　　小林　　１
Ｂ　　　　久野　　３
Ｂ　　　　酒井　　１
Ｃ　　　　服部　　３
Ｃ　　　　林　　　１
　グループＡかつ作成月１を抽出
浅井
小林
で=IFERROR(INDEX(Sheet1!B$1:B$1000,SMALL(IF((Sheet1!A$1:A$1000="A")*(Sheet1!C$1:C$1000=1),ROW(A$1:A$1000)),ROW(A1))),"")の数式を入力したところ抽出することができましたが応用してグループＡかつ作成月３を抽出したい場合
=IFERROR(INDEX(Sheet1!B$1:B$1000,SMALL(IF((Sheet1!A$1:A$1000="A")*(Sheet1!C$1:C$1000=３),ROW(A$1:A$1000)),ROW(A1))),"")の数式にしたところ抽出できませんでした。
数式が今一つ理解できないのでお手数ですが詳しく教えていただけますと助かります。
もし可能でしたらグループと作成月の２つを同時に抽出できる方法があれば教えてください。

質問者からの補足コメント

• 補足で質問させていただきます。
  グループのセルにＡ＝赤、Ｂ＝青、Ｃ＝黄色　と色をつけた場合エクセル関数を利用して抽出と同時に色も反映することができますか？

    補足日時：2017/09/24 21:44

No.1 回答者： tom04 回答日時： 2017/09/24 00:37

こんばんは！

＞グループＡかつ作成月３を抽出したい場合・・・

質問文通りの配置だとお示しの数式でちゃんと「浅井」が表示されました。
もしかして配列数式になっていないのでは？
もう一度数式が入っているセルを選択し
①　数式バー内で一度クリック
②　F2キーを押下
③　数式が入っているセルをダブルクリック

上記①～③の中のどれでも良いので、操作してください
編集可能になりますので、Ctrl＋Shift＋Enterで確定！
これで数式の前後に{ }マークが入り配列数式になります。

＞もし可能でしたらグループと作成月の２つを同時に抽出できる方法・・・
とは仮にA列が「A」でC列が「1」または「3」といった具合でしょうか？

その場合は
=IFERROR(INDEX(Sheet1!B$1:B$1000,SMALL(IF((Sheet1!A$1:A$1000="A")*((Sheet1!C$1:C$1000=1)+(Sheet1!C$1:C$1000=3)),ROW(A$1:A$1000)),ROW(A1))),"")

前回同様、配列数式なのでCtrl＋Shift＋Enterで確定！　→　下へオートフィル！

これで　浅井・伊藤・小林　の3セルが表示されます。

※　汎用性を持たせようと思えば、
どこかに「A列」の条件、「C列」の条件を入力するセルを設けておけば
そのセルを参照するだけでわざわざ数式に手を加える必要はなくなります。m(_ _)m

この回答へのお礼

ありがとうございます。
抽出することができました。
※汎用性を持たせる～の説明をもう少し詳しく教えてください。

お礼日時：2017/09/24 21:36

No.2 回答者： tom04 回答日時： 2017/09/24 00:42

No.1です。

たびたびごめんなさい。
前回の投稿の中の
＞「浅井」が表示されました。
は間違いで
「伊藤」が正解です。

どうも失礼しました。m(_ _)m

この回答へのお礼

ありがとうございます。

お礼日時：2017/09/24 21:33

No.3 回答者： chonami 回答日時： 2017/09/24 10:10

>抽出できませんでした

というのはどうなったんでしょうか？
数が出るけど正確でない？エラーになる？0になる？空白になる？

また、例示のA列は全角と半角が混じってますが、実際のデータはどうですか？

この回答へのお礼

ありがとうございます。
配列数式の理解ができていなかったのが原因でした。

お礼日時：2017/09/24 21:33

No.4 回答者： mike_g 回答日時： 2017/09/24 11:23

前回の私の回答では、「グループＡかつ作成月３を抽出した」データもありますね。

ついでに、前回の「エラーが出てしまいました」原因が

【お断り】上式は必ず配列数式として入力のこと

を貴方が「今一つ理解できない」からと勝手読みして、下にその意味を記しておきます。

此処では式を例えば =SUM((A1:A10)*(B1:B10)) としておく
１．該当式をコピーして指定のセルに入力(でも、まだ
￣￣Enterキーを叩かない！)
２．Ctrl+Shift+Enter を「エイヤッ！」と叩き付け
３．[数式バー]を眺めて、下記のように、入力した式が ｛ ｝で
￣￣囲まれていることを確認
￣￣ {=SUM((A1:A10)*(B1:B10))} ←此れが配列数式！

この回答へのお礼

たびたびありがとうございました。
配列数式が理解できていませんでした。
再度やってみたところ抽出することができました！

お礼日時：2017/09/24 21:32

No.5 ベストアンサー 回答者： tom04 回答日時： 2017/09/24 21:55

No.1です。

＞※汎用性を持たせる～の説明をもう少し詳しく教えてください。

とりあえず質問通りでA列が「A」、C列が「1」または「3」としました。
（もちろんAをBやCに、1、3は他のデータに入れ替えても構いません）

↓の画像のようにSheet2のC2セルにA列データ、D2・D3にC列データを入力するとします。
A2セルに
=IFERROR(INDEX(Sheet1!B$1:B$1000,SMALL(IF((Sheet1!A$1:A$1000=C$2)*((Sheet1!C$1:C$1000=D$2)+(Sheet1!C$1:C$1000=D$3)),ROW(A$1:A$1000)),ROW(A1))),"")

配列数式の操作をし、フィルハンドルで下へコピー！

これでC2・D2・D3のデータを色々変えてみてください。

※　C列は2条件限定としています。
もちろんもっと条件を増やしても構いませんが仮にC列の条件を4個とか5個などにしたい場合、
数式がやたらと長くなるだけで、メンテナンス（数式の修正など）が大変になりますので、
VBAの方がよいかもしれません。m(_ _)m

この回答へのお礼

ありがとうございます。
色々な方法があるんですね。とても参考になりました。

お礼日時：2017/09/24 22:04

No.6 回答者： tom04 回答日時： 2017/09/24 22:00

No.1・5です。

投稿後補足を拝見しました。
セルの書式は数式で反映することはできません。
どうしても！という場合はVBAになるかと思います。

ただ、補足の文だけで判断すると
A列がきまれば表示されるのは同じ色のセルになるのでは？
あえて色まで指定する必要はないように思われます。

これもSheet2に色を付けたいのであれば
Sheet2の方に条件付き書式を設定してみたらどうでしょうか？m(_ _)m

この回答へのお礼

回答ありがとうございます。
条件付き書式の設定方法を教えていただけないでしょうか？
教えていただけますと助かります。

お礼日時：2017/09/24 22:17

No.7 回答者： tom04 回答日時： 2017/09/24 23:08

続けてお邪魔します。

A列が塗りつぶされればよいのですかね？
No.5で書いたように、仮に↓の画像のようにC2セルが「C」の場合
表示されるのはSheet1のA列が「C」のデータだけのはずですので敢えてセルを塗りつぶす必要はないように思われますが・・・
どうしても！というコトであれば、

A2セルを選択　→　条件付き書式　→　新しいルール　→　数式を使用して・・・　→　数式欄に
=AND(A2<>"",C$2="A")
とし　→　書式　→　塗りつぶし　→　「赤」を選択しOK

同じようにA2セルに条件付き書式を三つ設定します。
新しいルール　→　・・・中略・・・　→　数式欄に
=AND(A2<>"",C$2="B")
とし　→　書式　→　塗りつぶし　→　「青」を選択しOK

同様に
=AND(A2<>"",C$2="C")
とし　→　・・・　→　「黄色」を選択しOK

これでA2セルに三つの条件付き書式が設定されましたので、
そのままフィルハンドルで下へコピー！

これで画像のような感じになります。m(_ _)m

この回答へのお礼

分かりました。分かりやすい説明ありがとうございました！

お礼日時：2017/09/25 17:52