エクセル：特定のブックのみ、ツールバーの設定をしたい

　タイトルの通りですが、エクセルで特定のブックだけにツールバーの表示・非表示の設定をすることはできるでしょうか？
　現在は、表示メニューからツールバーの設定をしています。しかし、この場合、すべてのブックに対して同じツールバーの設定になってしまいます。
　ツールバーと同様に、特定のブックのみ数式バーの表示・非表示の設定をしたいと思っています。

どちらかで結構ですのでご存知の方教えていただけませんか。
使用しているのはエクセル２００２です。

No.2 ベストアンサー 回答者： ham_kamo 回答日時： 2007/03/23 11:15

「ツールバーの表示・非表示の設定」というのが、特定のブックのときだけ、特定のツールバーを表示する、というなのか、特定のブックを開いたときだけ全てのツールバーを非表示にしたい、ということなのか、よくわからなかったので後者だと思って回答します。

違ったら補足してください。

特定のブックを開き、Alt+F11でVBAの画面を開きます。
左のThisWorkbookというところをダブルクリックして、右の白い部分に以下のマクロをコピーして貼り付けてください。

Dim CmdBarStatus() As Boolean

Private Sub Workbook_Open()
　On Error Resume Next
　Dim i As Integer
　With Application
　　ReDim CmdBarStatus(.CommandBars.Count)
　　For i = 1 To .CommandBars.Count
　　　CmdBarStatus(i) = .CommandBars(i).Visible
　　　.CommandBars(i).Visible = False
　　Next
　End With
　Application.DisplayFormulaBar = False
　
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
　On Error Resume Next
　Dim i As Integer
　With Application
　　For i = 1 To .CommandBars.Count
　　　.CommandBars(i).Visible = CmdBarStatus(i)
　　Next
　End With
　Application.DisplayFormulaBar = True
End Sub

貼り付けた後、いったんブックを閉じて開き直すと、ツールバーと数式バーが表示されなくなります。ブックを閉じると、ツールバーと数式バーは元の状態に戻ります。

このブックを開いている間は、同時に開いている他のブックも同じようにツールバーや数式バーは非表示になってしますが、このブックを閉じると元に戻ります。

この回答へのお礼

わざわざご丁寧にありがとうございました。

お礼日時：2007/03/24 01:03

No.1 回答者： hana-hana3 回答日時： 2007/03/23 10:04

ブック毎にＶＢＡで制御するしか方法はありません。

この回答へのお礼

回答ありがとうございました。

お礼日時：2007/03/24 01:02