エクセルに詳しい方、助けてください・・・

奇数と偶数の数を数えるのに関数を使用したいのですがそのような関数はありますでしょうか？（数字ではなく記号で数えたいのですが）
（イメージです）↓
　A B C D E F
1 1 2 3 4 5 6　奇数 偶数
2 ○ ○　　 ○ 　　2 　 1
3 ○　　○ 　　　　 1 　 1

このように奇数 偶数のところにカウントした数を表示させたいのですが・・・

No.1 回答者： mike_g 回答日時： 2007/11/07 03:08

G2: =SUMPRODUCT((MOD($A$1:$F$1,2)=1)*($A2:$F2="○"))

H2: =SUMPRODUCT((MOD($A$1:$F$1,2)=0)*($A2:$F2="○"))

No.2 回答者： imogasi 回答日時： 2007/11/07 09:36

例データA2:F2

A　　　B　　　　　C　　　　D　　　　E　　　　F　　　G
○ー○ーー○1
偶数列を求める
G2に　=SUM(IF(A2:F2="○",IF(MOD(COLUMN(A2:F2),2)=0,1,0)))
と入れて、SHIFT,CTRL,ENTERキーを同時押しする（配列数式）
結果
１
奇数列は
=SUM(IF(A2:F2="○",IF(MOD(COLUMN(A2:F2),2)=1,1,0)))
と入れて、SHIFT,CTRL,ENTERキーを同時押しする。
結果
２
=COUNTIF(A2:F2,"○")の３から偶数分を引く方法もある。
ーー
SUMPRODUCT関数に品約翻訳すると
偶数の列
=SUMPRODUCT((A2:F2="○")*(MOD(COLUMN(A4:F4),2)=0))
ーー
どちらもやっていることは、A2:F2で値が○で、かつ（AND条件、式中の＊がそれを表す）列番号が偶数である場合は１として、その１の数を集計する。

No.3 ベストアンサー 回答者： Wendy02 回答日時： 2007/11/07 12:41

こんにちは。

このご質問自体は、Microsoft サポートに同じようなものがあります。

[XL2002] n 行おきの合計を算出する方法
http://support.microsoft.com/kb/402181/ja

上記でお分かりのように、基本形は、#2のimogasiさんの数式です。その発展系で、#1 さんの数式になります。

世界中のExcelの回答者さんは、この定石はずしをいろいろトライするのですが、年に1個も生まれないことも多いものです。世界のどこかで掲示板に書けば、だいたい、同様のテクニックは知れ渡ってしまっています。月並みですが、私も考えてみました。

G2
=SUM(INDEX(MOD(COLUMN($A2:$F2),2)*($A2:$F2="○"),,))

H2:
=SUM(INDEX(MOD(COLUMN($A2:$F2)+1,2)*($A2:$F2="○"),,))

または、

G2:
=SUMPRODUCT(COUNTIF(OFFSET($A2,,COLUMN($A$2:$C$2)*2-2),"○"))

H2:
=SUMPRODUCT(COUNTIF(OFFSET($A2,,COLUMN($A$2:$C$2)*2-1),"○"))

この回答へのお礼

質問への回答ありがとうございました。　
上記の関数を入力したところ正確に数をカウントできました。
今まではひとつひとつカウントしていたのでとても楽になりました。
本当にありがとうございました。

お礼日時：2007/11/07 15:19