Excelのワークシート上に配置したActiveXコントロールのテキストボックスの数値範囲入力制限

Excel2013vbaで、ワークシート上にActiveXコントロールのテキストボックスを配置しています。
それに、入力制限をかけて、半角数字の3~200までを入力範囲とし、それ以外は入力不可としたいのですが、うまくできません。
とりあえず、現状数値のみの入力制限をかけることと、0入力不可(2文字目以降は可能)、200以上の入力不可という所まではできていますが、1と２の入力制限がかかりません。
１と２に入力制限をかけると、11や21などの2桁以上の入力も制限されてしまいます。
なにか方法は、あるでしょうか？

Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
If Chr(KeyAscii) < "0" Or Chr(KeyAscii) > "9" Then
KeyAscii = 0
End If
End Sub

Private Sub TextBox1_Change()
If TextBox1.Value > 200 Or TextBox1.Value = 0 Then
TextBox1.Value = ""
End If
End Sub

また、ワークシート上のテキストボックスのプロパティのIME MODEで3-fmIMEModeDisableを選択してもIMEモードが無効になりません。これは、仕方ないのでしょうか？できなかったので、IME -fmIMEModeOffに設定しています。

No.1 ベストアンサー 回答者： WindFaller 回答日時： 2019/03/31 14:18

このActiveX コントロールをシート上には、UserForm上の AterUpdate イベントがありません。

Changeイベントだと、Change のたびにチェックしてしまうので、うまくいきません。
今のところ、私の案ではこのぐらいです。もっと良い方法があるかもしれません。

'//シートモジュール
Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
　Select Case KeyAscii.Value
　Case 48 To 57
　Case Else
　　KeyAscii.Value = 0
　End Select
End Sub

Private Sub TextBox1_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
'AfterUpdate の代わり
Dim n As Variant
　Select Case KeyCode.Value
　Case 8 To 13　'Tab, Enter を入れたとき
　 n = Val(TextBox1.Value)
　 If (n < 3 Or n > 200) Then TextBox1.Value = ""
　End Select
End Sub

Private Sub TextBox1_LostFocus()
'貼り付け防止
Dim n As Variant
n = Val(TextBox1.Text)
If (n < 3 Or n > 200) Then TextBox1.Value = ""
End Sub

この回答へのお礼

テキストボックスを離れないとダメですが、やりたいことは実現できました。
シート上ではAterUpdate イベントがない以上、これが限界ですかね。
どうもありがとうございました。

お礼日時：2019/03/31 17:53

No.2 回答者： WindFaller 回答日時： 2019/03/31 19:32

>テキストボックスを離れないとダメですが、やりたいことは実現できました。

>シート上ではAterUpdate イベントがない以上、これが限界ですかね。

自力で考えたものですから、もう少し他の回答があるかもしれません。私は、ワークシート上のActiveX コントロールは、Windows 10になったときに、こちらでは、もう見限ってしまっているので、あまり研究していません。

TextBoxを離れなくてもできたと思いますが、
Private Sub TextBox1_LostFocus()
これは、テキストボックスに貼り付けされると、そのまま残るから付け加えました。

この回答へのお礼

ありがとうございます。
LostFocusがあることで、貼り付け時にも対応できることを確認しています。

お礼日時：2019/03/31 19:58