ユーザマネージャーの一覧を出したい

解決済

質問者：zunda
質問日時：2002/08/24 01:42
回答数：3件

現在、WindowsNT Server のユーザマネージャには多くのユーザやグループが登録されているのですが、
そこに登録されているユーザやグループの一覧をテキストファイルなどに出力することは可能なのでしょうか？

通報する

この質問への回答は締め切られました。

質問の本文を隠す

回答 (3件)

ベストアンサー優先
最新から表示
回答順に表示

No.3ベストアンサー

回答者： you-m
回答日時：2002/08/25 03:15

単に一覧が欲しいだけであれば、標準のコマンドを使用する事でできます。

net user
net user /domain
net localgroup
net group

それぞれ、ローカルユーザ/ローカルグループ/ドメインユーザ/ドメイングループを表示します。
このままでは、コンソールに表示されるだけなので、ファイルに落としたい場合は、後ろに、"> ファイル名"と付け足します。

このコマンドは、ユーザの一覧をテキストで表示しますが、1行に3ユーザ表示するので、後の扱いが苦しいです。
とりあえず、1行に1人づつ表示するためのバッチファイルを載せておきますので、参考にしてみてください。
点線の下からすべてを～.batというファイル名で保存すれば、実行できるはずです。
グループに関しても、ちょっと修正すれば応用は可能です。

---------------------------
@echo off
REM ユーザ一覧を表示する。
REM オプションとして/domainを付けると、ドメインユーザを表示する。

if /i "%1"=="/domain" (
set SKIPCOUNT=6
) else if "%1"=="" (
set SKIPCOUNT=4
) else (
echo ---引数ちゃうで。---
echo ユーザ一覧の表示
echo %~n0 [/DOMAIN]
echo /DOMAIN --- ドメインユーザの表示
goto :EOF
)

for /f "tokens=1-3 skip=%SKIPCOUNT%" %%a in ('net user %1') do (
if not "%%a"=="コマンドは正常に終了しました。" echo %%a
if not "%%b"=="" echo %%b
if not "%%c"=="" echo %%c
)