エクセル シフト表 ６連続勤務は"fault"

Excel 2003です。
エクセルでシフト表を作ろうと思います。
A列２行目から１０行目迄に氏名を入力　１行目のB列からAF列までに日付（１日から３１日迄）が入力されています。
升目に休日の場合は空白、出勤の場合、２種類の出勤パターンで”早”または”遅”を入力していきます。
AG列の各行に確認の計算式で、
６以上の連続勤務がある場合は”fault”そうでない場合は”true”となるような
確認の式を作りたいのです。
また別の式で、”遅”の翌日に”早”がきた場合”fault”になるような式はできますでしょうか。
２点
教えてください。
どうぞ宜しくお願いします。

No.3 ベストアンサー 回答者： tom04 回答日時： 2011/03/01 18:34

こんばんは！

ご希望の方法とは違いますが・・・

一つの案として、条件付書式を使って質問の条件の場合は入力時にセルの色を赤くする方法はどうでしょうか？

C2～AF10を範囲指定　→　メニュー　→　書式　→　条件付書式　→　「数式が」を選択　→　数式欄に
=AND(B2="遅",C2="早")
として　書式　→　パターンで「赤」（←好みの色でOK）を選択し、OK

次にG6～AF10を範囲指定　→　条件付書式　→　条件を追加　→　「数式が」　→　数式欄に
=COUNTA(B2:G2)=6
として同様に好みの色を選択

これで入力した時点でそのセルに色がつくと思います。

以上、参考になれば良いのですが
的外れならごめんなさいね。m(__)m

この回答へのお礼

tom04さん

御回答有り難うございます。
お礼が大変遅くなり失礼しました。

これは目から鱗の解凍でした。
とても分かり易くて便利ですね。
全く予想していなかったご回答でしたが、
とても便利なのでこちらを採用させていただきました。

大変参考になりました。
有り難うございました。

お礼日時：2011/03/14 16:35

No.5 回答者： don9don9 回答日時： 2011/03/02 09:37

No.1の回答の、後者の方は逆ではないかと。

（"遅"の翌日に"早"が来た時にTRUEを返す式になっている）

=(SUMPRODUCT((B2:AE2="遅")*(C2:AF2="早"))=0)

とすべきでは。

この回答へのお礼

don9don9さん

ご丁寧に有り難うございます。

参考になりました。

有り難うございました。

お礼日時：2011/03/14 16:37

No.4 回答者： tom04 回答日時： 2011/03/01 22:14

No.3です！

たびたびごめんなさい。

前回の投稿で文章に誤りがありました。

＞次にG6～AF10を範囲指定・・・

の部分を

＞次にG2～AF10を範囲指定・・・

に訂正してくださ。

どうも失礼しました。m(__)m

この回答へのお礼

tom04さん

ご丁寧にありがとうございました。

お礼日時：2011/03/14 16:36

No.2 回答者： imogasi 回答日時： 2011/03/01 16:51

条件が前後関係にかかわる条件で（連続といった条件は）関数では難しいと思う。

例として、１行だけ、第２行目だけを考える。Ｂ列から右にデータがあり、第３２列までの各列のセルの値は
早
遅
空白
のどれかとする。
エクセルは、データのあるセルに（判定のために）関数式を入れることは出来ないのは当然のこと。。だから別の離れた行以下に関数式を入れることになる。
２０人未満の従業員がいる場合を考えて、例えば第２１行目を注目して、そこの行の列の各セルについて
６以上の連続を問題にするので、Ｆ列までは（Ｂ－Ｆで５列）は６連続は無いから、Ｇ２０セルに
=IF(COUNTIF(B2:G2,"早")+COUNTIF(B2:G2,"遅")=6,"x","")　　
（Ｆａｕｌｔは特殊な言葉なのでＸにした、ＯＫはＴｒｕｅより空白の方が、Ｘだけが目立つのでそうする。）
と入れて式を第３２列まで右方向に複写。
これを下方向にも従業員数の行分、全列式を複写。
月初の１日からこのチェックをするなら、前月５日前からのデータが必要だが、その点質問には何も書かず、不完全だろう。
そこはどうなるのか考えてみて。別表になっていたりすると面倒。
ーーーー
上記方法は、自信はないが、質問者の方でチェックし不都合な場合の例が起こることが判ったら、無視してください。
＝＝＝
本心はむしろこの程度の課題になると、ＶＢＡででもやらないと関数の組み合わせなどでは、難しいと思ったが、関数での思い付きの案を１つ挙げてみる。

この回答へのお礼

imogashi さん。

いつも丁寧な御回答有り難うございます。
お礼が遅くなり失礼しました。

思いの外難しかったので、自分の中で理解するのに
時間をかけてしまいました。

大変参考になりました。
有り難うございました。

お礼日時：2011/03/14 16:33

No.1 回答者： keithin 回答日時： 2011/03/01 16:31

＞A列…に氏名…B列からAF列までに日付（１日から３１日迄）

前者は
=MAX(COLUMN(A2:AF2)-LOOKUP(COLUMN(A2:AF2),(IF((COLUMN(A2:AF2)=1)+(A2:AF2=""),COLUMN(A2:AF2)))))<6
をコントロールキーとシフトキーを押しながらEnterで入力

後者は
=(SUMPRODUCT((B2:AE2="遅")*(C2:AF2="早"))>0)
をふつーにEnterで入力



＃言わずもがなですが今の表では「月またぎで連続勤務」を数える方法がありません。
　上述式は「１日から」及び「３１日まで」の範囲で連続日数を計算しています。
　先月末に遅で終え，今月アタマに早で始まったケースも同じです。

この回答へのお礼

keithinさん

御回答有り難うございます。
お礼が大変遅くなり失礼しました。
思いの外難しかったので、自分の中で納得するのに
時間をかけてしまいました。
columnやsumproductなど普段余り使わなかった
ので勉強になりました。
大変参考になりました。
有り難うございました。

お礼日時：2011/03/14 16:31