エクセル ＩＦ関数とＡＮＤ関数とＯＲ関数の組み合わせ

こんにちは　エクセルの関数について、解らない事があるので教えて頂けませんか？

画像のように、Ｎ２～Ｑ２に文字が入っていて、賛成か反対かを記入するようになっています。

やりたい事は、Ｎ２～Ｑ２が全て賛成の場合には賛成、全て反対の文字が入っている場合は反対とＫ２セルに表示させたいと思っています。

Ｋ２には、=IF(AND(N2="賛成", O2="賛成",P2="賛成",Q2="賛成"), "賛成", "")　の関数を入れたのですが、これでは賛成だけしか判定してくれませんので、反対も判定表示して欲しいのです。

自分ではちょっと出来なかったのでよろしくお願いします。

No.2 ベストアンサー 回答者： zongai 回答日時： 2019/09/06 14:20

全て賛成の場合には賛成

=IF(AND(N2="賛成", O2="賛成",P2="賛成",Q2="賛成"), "賛成", "")

同じように考えて、
全て反対の場合には反対
=IF(AND(N2="反対", O2="反対",P2="反対",Q2="反対"), "反対", "")

IF関数って、
=IF(条件,合っているときの処理,合っていないときの処理)
ですよね。

最初のこの式、
=IF(AND(N2="賛成", O2="賛成",P2="賛成",Q2="賛成"), "賛成", "")
合っていないときは "" になってるので、ここに、
合っていないとき、全部が反対の場合のIFの式をそのまま入れてやればいいんです。

=IF(AND(N2="賛成", O2="賛成",P2="賛成",Q2="賛成"), "賛成", IF(AND(N2="反対", O2="反対",P2="反対",Q2="反対"), "反対", ""))

これで望んだ結果になると思います。


参照する件数が4固定であるなら、No1で回答されているように、COUNTIFを使うのが簡単にできて良いですね。

=IF(COUNTIF(N2:Q2,"賛成")=4, "賛成", IF(COUNTIF(N2:Q2,"反対")=4,"反対",""))


賛成か反対しか無いのであれば、

=IF(COUNTIF(N2:Q2,N2)=4,N2,"")

ここまで短縮できるかと。

この回答へのお礼

ご丁寧に教えて頂きありがとうございます。
なるほど、色んな形で実現出来るんですね、今後は頭の体操と思って色々考えてみます。
ありがとうございました！

お礼日時：2019/09/06 17:34

No.3 回答者： angkor_h 回答日時： 2019/09/06 14:20

記入文字の全てが揃っていればそれを表示する、という事であれば、

K2=IF(AND(N2=O2, O2=P2,P2=Q2), N2, "")　

記入文字を指定したければ、先頭にその判断を置けばよいでしょう。
K2=IF(N2=OR("賛成", "反対"),IF　…

この回答へのお礼

回答ありがとうございます。

お礼日時：2019/09/09 15:01

No.1 回答者： GOMΛFU 回答日時： 2019/09/06 14:01

countif で”賛成”が4つあればよいんでしょ。