Excel別行の条件を用いた集計について

今まで
名前　出身　　預金　　借金
Ａ　　東京　　１００　１００
Ｂ　　愛知　　２００　０
Ｃ　　大阪　　１００　５０
Ｄ　　沖縄　　１５０　５０

このような表で、「預金が100以上でかつ、借金が50以下」
の人数を集計する場合は、もう一つ列を作り、そこに
IF関数を用いて、該当する人間のみ「１」を表示させるように
して、そのセルを集計していました。
この手間をワンテンポ省略する手段はあるのでしょうか？
今までSUMIFやCOUNTIFを利用してもなかなかうまくいかず、この中で検索しても思ったものが出てこなかったのですが、よろしくお願いします。

No.1 回答者： merlionXX 回答日時： 2007/01/31 16:15

B列が預金、C列が借金（万単位）なら、表が100行まであるとして

=SUMPRODUCT((B1:B100>=100)*(C1:C100<=50))

です。

もし、「東京」出身という条件もつけるなら
=SUMPRODUCT((A1:A100="東京")*(B1:B100>=100)*(C1:C100<=50))

この回答へのお礼

ありがとうございます。その関数は初めて知りました・・・。

お礼日時：2007/02/01 00:19

No.2 回答者： mshr1962 回答日時： 2007/01/31 16:20

人数=SUMPRODUCT((預金の範囲>=100)*(借金の範囲<=50))

預金=SUMPRODUCT((預金の範囲>=100)*(借金の範囲<=50)*(預金の範囲))
借金=SUMPRODUCT((預金の範囲>=100)*(借金の範囲<=50)*(借金の範囲))

都道府県を追加するなら
人数=SUMPRODUCT((預金の範囲>=100)*(借金の範囲<=50)*(都道府県の範囲="東京"))

この回答へのお礼

３つも条件をつけることが出来るのですか？やってみます。ありがとうございました。

お礼日時：2007/02/01 14:35

No.3 回答者： mu2011 回答日時： 2007/01/31 16:35

次の方法は如何でしょうか。

配列数式ですので、入力完了時にshift＋ctrl+enterキーを同時押下して下さい。
検索範囲はご質問のサイズとしていますので、調整して下さい。
=SUM(IF((C2:C5>=100)*(D2:D5<=50),1))

この回答へのお礼

配列数式ですか？初めて聴く言葉なのでいろいろネットで調べてみようと思います。ありがとうございました。

お礼日時：2007/02/24 22:35

No.4 ベストアンサー 回答者： 3mioya 回答日時： 2007/01/31 22:16

(1)まず、ツールバーの　データ＞フィルタ＞オートフィルター　をONにします。

(2)預金の▼をクリックしオプションで「100以上」を選択し、
(3)借金の▼をクリックして同じくオプションで「50以下」を選びます。
(4)預金もしくは借金の一番下のセルをクリックして、Σボタン（オートSUM）をクリックすると「SUBTOTAL(9,C2:C***)」が数式バーに表示されましたか？　この数字の9は集計方法を表していて、この9を2に置き換えると（数値の入った）個数がでます。参考までに、他の集計方法もどうぞ
実際にやってみると簡単です。お試しください。

集計方法 関数
1 AVERAGE 関数
2 COUNT 関数
3 COUNTA 関数
4 MAX 関数
5 MIN 関数
6 PRODUCT 関数
7 STDEV 関数
8 STDEVP 関数
9 SUM 関数
10 VAR 関数
11 VARP 関数

この回答へのお礼

いろいろ知らない関数があって勉強になりました。ありがとうございます、やってみます。

お礼日時：2007/02/24 22:34

No.5 回答者： imogasi 回答日時： 2007/01/31 23:01

DCOUNTがあります

例データ
名前出身預金借金
A東京100100
B愛知2000
C大阪10050
D沖縄15050
F岡山10249
G広島10049
G1:H2に条件（クライテリア）
預金借金
>=100<=50
式（上記以外のセルに）
=DCOUNT(A1:D7,C1,G1:H2)
結果
上例で５
ーー
なぜか回答で人気がない。式の中でなく、別セルにクライテリアがいるためか。
しかし明示性に優れ、条件を変えることも容易。