セルサイズに自動で合わせて画像を貼るマクロとカレンダーマクロでエラー表示・変数宣言とは。

Question

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Excel.Range, Cancel As Boolean) 



    Cancel = True



    '===============画像選択
    myF = Application.GetOpenFilename _
           ("jpg bmp tif png gif,*.jpg;*.bmp;*.tif;*.png;*.gif", , "画像の選択", , False)
    If myF = False Then
        MsgBox "画像を選択してください(終了)"
        Exit Sub
    End If



    '===============画像の掃除
    For Each mySP In ActiveSheet.Shapes
        myAD1 = mySP.TopLeftCell.MergeArea.Address　　　←この行が黄色くなっちゃいます。
        myAD2 = Target.Address
        If myAD1 = myAD2 Then mySP.Delete
    Next



    '===============画像の貼り付け
    Set mySP = ActiveSheet.Pictures.Insert(myF)



    '===============タテヨコの縮尺を保持
    myHH = Target.Height / mySP.Height
    myWW = Target.Width / mySP.Width
    If myHH > myWW Then
        mySP.Height = mySP.Height * myWW
        mySP.Width = Target.Width
    Else
        mySP.Height = Target.Height
        mySP.Width = mySP.Width * myHH
    End If



    '===============中央へ調整
    myHH2 = (Target.Height / 2) - (mySP.Height / 2)
    myWW2 = (Target.Width / 2) - (mySP.Width / 2)
    mySP.Top = Target.Top + myHH2
    mySP.Left = Target.Left + myWW2



    Set mySP = Nothing


End Sub 


ーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーー 

 Private Sub Calendar1_Click()
ActiveCell.Value = Calendar1.Value
End Sub

※黄色くなってエラー表示、変数宣言がされていないとご指示いただきましたが、どうして良いのか分かりません。どのように書き加えればを教えてください。よろしくお願いいたします。

WindFaller · Accepted Answer

こんにちは。

変数の使い方は、なかなか覚えられませんね。
中級までは、あってもなくてもよいと思います。
回答者でも、長くやっていても、よく分かっていない人もいるようです。
VBAというのは、あまりエラーが出ないし、予約語も少ないから、何でもありでしょうけれども、VBA関数やプロパティ名を変数に使ったりする人がいますが、それはまずいなって、分かりそうだと思うのですが。それと、私の場合は　2Byte 文字を変数には使いません。Excel等がバージョン違いが存在していたり、海外のユーティリティを使うと、文字化けが起きてしまうからです。

ただ、あえて自分なりにガンバってみたいのでしたら、例えば、myHH, myWW というのは、Double 型なのですが、こういうのの決め方というのは、ローカルモジュールで推奨型が出てきますから、それをフィードバックしてつけてあげるようにすると良いかもしれません。

>myAD1 = mySP.TopLeftCell.MergeArea.Address　　　←この行が黄色くなっちゃいます。

ところで、今回のエラーって別に、変数の問題ではないのではありませんか？

>For Each mySP In ActiveSheet.Shapes
問題は、この後だと思います。Shapes というのは、オブジェクトの統合したもので、何でも入ってしまいます。プロパティがあれば、mySP.TopLeftCell　でRange オブジェクトが取れるでしょうけれども、これは、オブジェクトのタイプを限定させた方が安心できます。

コードを見る限りは、Active X コントロール(Calendar)があるようです。

最近、似たような質問で、私の回答はボツになりましたが、画像の重なりの問題ですよね。画像を重ねてはならないのでしょうから、左上端のアドレス合わせだけでよいのか、工夫が必要ではないかと思います。

以下は、まだ、不具合は残っているかもしれません。

'//シートモジュール
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Excel.Range, Cancel As Boolean)
　Dim mySP As Object
　Dim myAD1 As Range, myAD2 As Range
　Dim myF As Variant
　Dim myHH As Double, myWW As Double
　Cancel = True
　'===============画像選択
　myF = Application.GetOpenFilename _
　　　("jpg bmp tif png gif,*.jpg;*.bmp;*.tif;*.png;*.gif", , "画像の選択", , False)
　If myF = False Then
　　MsgBox "画像を選択してください(終了)"
　　Exit Sub
　End If
　'===============画像の掃除
　For Each mySP In ActiveSheet.Shapes
　　If TypeName(mySP.DrawingObject) = "Picture" Then　'画像限定
　　　Set myAD1 = mySP.TopLeftCell　　 '左端上
　　　Set myAD2 = mySP.BottomRightCell　'右端下
　　　If Not Intersect(Range(myAD1, myAD2), Target) Is Nothing Then mySP.Delete
　　End If
　Next
　'===============画像の貼り付け
　Set mySP = ActiveSheet.Pictures.Insert(myF)

'===============タテヨコの縮尺を保持
　myHH = Target.Height / mySP.Height
　myWW = Target.Width / mySP.Width
　If myHH > myWW Then
　　mySP.Height = mySP.Height * myWW
　　mySP.Width = Target.Width
　Else
　　mySP.Height = Target.Height
　　mySP.Width = mySP.Width * myHH
　End If
　'===============中央へ調整
　myHH2 = (Target.Height / 2) - (mySP.Height / 2)
　myWW2 = (Target.Width / 2) - (mySP.Width / 2)
　mySP.Top = Target.Top + myHH2
　mySP.Left = Target.Left + myWW2
　Set mySP = Nothing
End Sub

Private Sub Calendar1_Click()
If ActiveCell.Value = "" Then
　ActiveCell.Value = Me.Calendar1.Value
End If
End Sub

WindFaller · Answer

>シートの保護をしてから貼り付けようとするとエラーが出てしまいます。
Protect の中の、UserInterfaceOnly というプロパティをTrue にすれば、マクロはプロテクトとは関係なしに動くようになります。

'//ThisWorkbook モジュールに以下のようなプログラムを足して、再起動(または、実行）すれば、おっしゃるようになります。

Private Sub Workbook_Open()
Const PSW As String = "xyz"  'パスワード
With Worksheets("Sheet1")　'保護するシート
　.Unprotect Password:=PSW
　.Protect Password:=PSW, UserInterFaceOnly:=True, DrawingObjects:=True, Contents:=True
End With
End Sub

めぐみん_ · Answer

No.3です。

＞Dim 変数名をどのように、どこに書くのかも知らないでエクセルを使おうとしています。

まず基本は変数を使う前に宣言してあれば良いのですが、
特別な条件でない限り（今回の場合）なら、

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Excel.Range, Cancel As Boolean) 
Dim 変数名１
Dim 変数名２

と、最初に書くのが一般的ですかね。

めぐみん_ · Answer

No.1です。

既存のBookはわかりませんが、チェックを外した後Excelを一旦閉じて
開いた際の新規BookにはNo.2の項目は出ず、
エラーにはならないでしょうね。

と言うより変数の宣言は最初のうちに覚える物ですから、
それを飛ばすのもどうでしょうね？

面倒でなければ

Dim 変数名

を最初に書いてしまえば良いのではないかと。
型の明確な指定は省くことになりますが、エラー表示対策にはなるのでは？

tatsu99 · Answer

先頭に
Option Explicit
がありませんか。
その行を削除すれば、変数宣言がなくてもエラーになりません。
本来は、きちんと変数を宣言してマクロを作成したほうが良いのですが、とりあえず、
Option Explicit　の行を削除すれば動きます。

めぐみん_ · Answer

変数の宣言をしたくなければ
http://officetanaka.net/excel/vba/variable/02.htm
『変数の宣言を強制する』のチェックを外す。

今後変数の宣言をキチンとしたいなら
https://www.vba-ie.net/programing/variable-statement.html
こう言った所を勉強する。

セルサイズに自動で合わせて画像を貼るマクロとカレンダーマクロでエラー表示・変数宣言とは。

こんにちは。

>シートの保護をしてから貼り付けようとするとエラーが出てしまいます。

No.3です。

No.1です。

先頭に

変数の宣言をしたくなければ

似たような質問が見つかりました

このQ&Aを見た人はこんなQ&Aも見ています

関連するカテゴリからQ&Aを探す

このQ&Aを見た人がよく見るQ&A

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング