エクセルの計算式がわからない。。

添付ファイルより
年間の達成率「O9」の現在「68%」になっている部分なのですが、
契約済欄が入力されているところまでを反映させる形で、数値を表示させたいのです。

添付ファイルで言うと
現在3月まで契約済欄が入力されています。
つまり「O9」には　（C7:I7）/（C8:I8）　を反映させたい

契約済欄が6月まで入力されれば
「O9」には　（C7:L7）/（C8:L8）　を反映させたい

そんな計算式があれば教えてください！

No.2 ベストアンサー 回答者： chie65535 回答日時： 2011/04/13 14:22

C9セルに

=IF(ISBLANK(C$8),"",SUM($C$8:C$8)/SUM($C$7:C$7))
と入力する。

D9セルに
=IF(ISBLANK(D$8),C$9,SUM($C$8:D$8)/SUM($C$7:D$7))
と入力する。

入力してから、D9セルを「セルのコピー」で「E9～N9」までにコピーする。

すると、E9～O9に
=IF(ISBLANK(E$8),C$9,SUM($C$8:E$8)/SUM($C$7:E$7))
=IF(ISBLANK(F$8),D$9,SUM($C$8:F$8)/SUM($C$7:F$7))
=IF(ISBLANK(G$8),E$9,SUM($C$8:G$8)/SUM($C$7:G$7))
=IF(ISBLANK(H$8),F$9,SUM($C$8:H$8)/SUM($C$7:H$7))
=IF(ISBLANK(I$8),G$9,SUM($C$8:I$8)/SUM($C$7:I$7))
=IF(ISBLANK(J$8),H$9,SUM($C$8:J$8)/SUM($C$7:J$7))
(以下略)
と言う式がコピーされる。

O9セルに
=N9
と入力する。

あとは、一緒にコピーされて変わってしまった、セルの罫線を引き直しする。

8行目の契約済数の部分が「空白セル」になっている月以降の達成率は、空白じゃない最後の月の達成率がスライドしてきて表示される。

年間の達成率を「常に最終月の達成率と同じ」にしておけば、自動的に「空白じゃない最後の月の達成率」になる筈。

新しい期の表を作る時は、表ファイルをコピー後、C8～N8の契約済数をブランクにしてしまえばOK。

No.5 回答者： imogasi 回答日時： 2011/04/13 20:16

質問のデータ実例で、画像貼り付けは、やめてほしい。

字が小さかったり、画像がぼやけてたりして読めない場合が多い。質問者自信でも質問を挙げた後に見てみるぐらいのことはすること。
＝＝
質問文章の中でシートデータを工夫して、記述のこと。

No.4 回答者： mu2011 回答日時： 2011/04/13 18:02

一例です。

年間の達成率のＯ９は、年間用として今のままでよいと思う。
Ｃ９～Ｎ９に達成率の行があるのだからその月度までの達成率を表示するとしては如何がでしょうか。
一例です。
=IF(C$8<>"",SUM($C$8:C8)/SUM($C$7:C7),"")

No.3 回答者： KURUMITO 回答日時： 2011/04/13 14:48

図で見るところ7行目が目標値で8行目が契約済みの値であるように見えますね。

したがって達成率は8行目の合計を7行目の合計で割った値ではないでしょうか？
こちらの仮定のとおりだとすればO9セルに入力する式は次のようにします。

=SUM(C8:INDEX(C8:N8,COUNT(C8:N8)+2))/SUM(C7:INDEX(C7:N7,COUNT(C8:N8)+2))

これで8行目に入力されたデータまでの達成率が表示されます。

なお、O9セルの表示形式は％表示にすればよいでしょう。

No.1 回答者： keithin 回答日時： 2011/04/13 13:37

添付図は小さくなってしまって詳細が判読できませんが，O8にはデータが記入されている範囲での合計が計算できていますね。

今まだ数字が入っていない４月以降の「空白セル」が，
　・これから手打ちで数字を入れていくので今は全くの空っぽセルである
　・実は数式が記入してあって""が計算されて出ている
などの具体的な姿によっても，適切な数式が変わってきます。

あと，あなたは
達成率 =（C7:I7）/（C8:I8）
などとてきとー書いていますが，達成率というと
=８行の合計÷７行の合計
じゃありませんか？


そういうのをひっくるめて，たとえば
O9:
=SUM(C8:N8)/SUMIF(C8:N8,">=0",C7:N7)
などで。


＃参考
COUNT関数とOFFSET関数やINDIRECT関数を組み合わせる手などもありますが，ブックを開いて何もせずに閉じるだけでも「保存しますか」とイチイチ聞いてくる原因になります。