Excel2010の棒グラフに数値以外のセルを表示

Question

お世話になります。
Excel2010の棒グラフです。記号のグラフを追加できないでしょうか。

A列　B列
10
20　　△
10
40　　△
30

20と40を示す棒グラフのどこかに△記号を表示させることはできないでしょうか。
データとして△記号になっているので、数字等に置き換えることはできません。

データラベルに数値以外のセルを表示したい
http://ciao.aoten.jp/ciao/2012/02/post-fd1c.html

方法としてはこれなのですが、600行ほどあるため、なにか別の手段はないかと思い質問しました。

xls88 · Accepted Answer

DreamyCatさんの方法をアレンジしてみました。

作業列で別系列データを設ける
最初のセルに下記のような式を入れる
=IF(AND(C1="△",B1<=0,5),5,IF(C1="△",B1+5,NA()))
下方セルにコピー
上記データで系列を追加
グラフの種類を「折れ線グラフ」にする
データ系列の書式設定で
線の色を「なし」
マーカーのオプションから
マーカーの種類を「▲」
マーカーの塗りつぶしを「塗り潰しなし」
に設定する

IF関数式は今までのやり取りで明確にされた条件で作っています。

doc_somday · Answer

皆様エクセルの尻を叩いておられますが、
エクセルは本来表計算ソフトで、グラフ描画ソフトでは無い。
私は十年前に「趣味」以外のコーディングは止めました。
趣味なら楽しいが、それは「本儀」では無い。
ですのでエクセルのデータをコピペできるグラフ描画
ソフトに乗り換えました。ものすごく簡単で、時には「時空」
までデタラメでも描いちゃう。何でもやってくれるが、
計算は和と日数計算ぐらいしかしてくれない。

xls88 · Answer

＞追加の質問で誠に恐縮ですが・・・
追加質問はできるだけ別スレッドを立てるようにお願いします。

＞マクロが動いている関係だと思いますが、グラフの点滅が激しいです・・・
どんなマクロなのかコードを提示されないと判断ができません。

＞最前面のグラフエリアを選択状態にすると点滅が止まります。
＞選択したままでも、Excelの動作には支障は無いようでした。
マクロの中で選択させればどでしょうか。

＞点滅を軽減する方法があるでしょうか？ 
効き目があるかどうかわかりかねますが動いているマクロの中で
画面の更新を抑止する
再計算を停止する
などの方法を試してみてください。
＜参考＞
画面更新を制御する(ScreenUpdatingプロパティ)
http://www.moug.net/tech/exvba/0010005.html
シートの再計算を設定する(EnableCalculationプロパティ)
http://www.moug.net/tech/exvba/0040055.html
数式の再計算
http://www.excel-vba.net/excel-range-029.html

mitarashi · Answer

#1です。
△をY=0の箇所に表示するニーズについて、X軸の目盛りのラベルを下端に設定した場合（当方の好みですが）に対応できるコードです。ご参考まで。
Sub test()
 Dim myChart As Chart
 Dim mySeries As Series
 Dim yValueRange As Range
 Dim i As Long
 
'ActiveSheetにグラフが一個ある事が前提
 Set myChart = ActiveSheet.ChartObjects(1).Chart
 'データ系列も一つだけが前提
 Set mySeries = myChart.SeriesCollection(1)
 With mySeries
  'SeriesのFormulaからyvalueのセル範囲を取得
  '例： =SERIES(Sheet1!$B$1,Sheet1!$A$2:$A$100,Sheet1!$B$2:$B$100,1)　の$B$2:$B$100を取得
  Set yValueRange = ActiveSheet.Range(Split(Split(mySeries.Formula, ",")(2), "!")(1))
 For i = 1 To .Points.Count
 .Points(i).ApplyDataLabels
 '各Y値のセルの一つ右隣の値をデータラベルに設定
 .Points(i).DataLabel.Text = yValueRange.Cells(i).Offset(, 1).Value
'毎回計算する必要は無いのですが手抜きです。律速になる場合は、ループの外で計算して下さい...
 .Points(i).DataLabel.Top = convertToPlotareaPosY(myChart, 0) - .Points(i).DataLabel.Height / 2
 Next i
 End With
 End Sub

'軸目盛りの値→グラフ上の座標に変換
'xlCategory対応を改造したので名残があります...
Private Function convertToPlotareaPosY(targetGraph As Chart, SetScale As Single) As Single
  Dim PIH As Single, PIW As Single, PIT As Single, PIL As Single
  Dim MaxScale As Single, MinScale As Single
  Dim x As Single
  
  On Error GoTo ErrorHandler
  If targetGraph Is Nothing Then Exit Function
  With targetGraph
    With .Axes(xlValue)
      MinScale = .MinimumScale
      MaxScale = .MaximumScale
    End With
    With .PlotArea
      PIH = .InsideHeight
      PIW = .InsideWidth
      PIT = .InsideTop - 0.25
      PIL = .InsideLeft - 0.25
    End With
  End With
  convertToPlotareaPosY = (MaxScale - SetScale) / (MaxScale - MinScale) * PIH + PIT
ErrorHandler:
  Exit Function
End Function

xls88 · Answer

＞マイナス側の△はどこに表示されるでしょうか？できれば０の線上に表示・・・

Dim v As Variant
    Dim t As Variant
    Dim ftxt As String
    Dim ws As String
    Dim yadr As String
    Dim i As Long

With ActiveChart
        t = .Axes(xlCategory).top
        With .SeriesCollection(1)
            v = .values
            ftxt = .Formula
            ws = Split(Split(ftxt, ",")(2), "!")(0)
            yadr = Split(ftxt, ",")(2)
            .HasDataLabels = True
            For i = 1 To .Points.Count
                With .Points(i).DataLabel
                    .text = "=" & ws & "!" & Range(yadr)(i).Offset(, 1).Address
                    If v(i) <= 0 Then
                        .top = t - .Height
                    End If
                End With
            Next
        End With
    End With

データの書き換えはないのですか？
表示位置に関して変更時の追随ができなくなるとおもいます。
追随が必要ならシートイベントプロシージャを利用することになると思います。

xls88 · Answer

提示されたデータに不可解な部分がありますが
数値データの隣に記号データがあるとして
系列1のデータラベルにセル参照式を入れる例を挙げてみます。

Dim ftxt As String
Dim ws As String
Dim yadr As String
Dim i As Long

With ActiveChart.SeriesCollection(1)
    ftxt = .Formula
    ws = Split(Split(ftxt, ",")(2), "!")(0)
    yadr = Split(ftxt, ",")(2)
    .HasDataLabels = True
    For i = 1 To .Points.Count
        With .Points(i).DataLabel
            .text = "=" & ws & "!" & Range(yadr)(i).Offset(, 1).Address
        End With
    Next
End With

DreamyCat · Answer

AB列の間に作業列を追加して
△があれば適当な値（ここでは仮に５としてあります）を表示するようにしておきます。
=IF(C2="△",5,"")　の式を下へドラッグ。
A列とこの数式の範囲を選択して積み上げ棒グラフを作成
積み上げ部分（系列２）の「塗りつぶし」に
あらかじめ作成して保存しておいた△の図を指定します。

mitarashi · Answer

地道にやるのがお嫌なら、VBAしか無いと思います。
Collectionから引っ張り出してちょっとアレンジしてみました。
コード中のコメント以上の解説はご容赦いただきます。関心をお持ちになったら自習いただくか、他の回答をお待ち下さい。
Sub test()
 Dim myChart As Chart
 Dim mySeries As Series
 Dim yValueRange As Range
 Dim i As Long

'ActiveSheetにグラフが一個ある事が前提
 Set myChart = ActiveSheet.ChartObjects(1).Chart
 'データ系列も一つだけが前提
 Set mySeries = myChart.SeriesCollection(1)
 With mySeries
  'SeriesのFormulaからyvalueのセル範囲を取得
  '例： =SERIES(Sheet1!$B$1,Sheet1!$A$2:$A$100,Sheet1!$B$2:$B$100,1)　の$B$2:$B$100を取得
  Set yValueRange = ActiveSheet.Range(Split(Split(mySeries.Formula, ",")(2), "!")(1))
 For i = 1 To .Points.Count
 .Points(i).ApplyDataLabels
 '各Y値のセルの一つ右隣の値をデータラベルに設定（手抜きで空白でも設定）
 .Points(i).DataLabel.Text = yValueRange.Cells(i).Offset(, 1).Value
 Next i
 End With
 End Sub

Excel2010の棒グラフに数値以外のセルを表示

DreamyCatさんの方法をアレンジしてみました。

皆様エクセルの尻を叩いておられますが、

この回答への補足

＞追加の質問で誠に恐縮ですが・・・

この回答への補足

#1です。

＞マイナス側の△はどこに表示されるでしょうか？できれば０の線上に表示・・・

提示されたデータに不可解な部分がありますが

この回答への補足

AB列の間に作業列を追加して

この回答への補足

地道にやるのがお嫌なら、VBAしか無いと思います。

この回答への補足

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング