重複及び隔週土曜日の条件下での祝日土日別の日数の求め

いつもお世話になります。

OS WIN10 エクセル2013　です。

ご指導を仰ぎたいのは、
祝日　土　日のお休みの日数を下記の条件で自動でカウントしたいです。


1　第二及び第四土曜日は休み
2　土日と祝日が重なる場合は祝日にカウント

例
2016年/1月の場合

祝日　AA2=5　
土　　AA3=2
日　　AA4=4
平日　AA5=20
の各セルに求めたい。
ご協力をよろしくお願いいたします。

質問者からの補足コメント

• 振り替え休日は平日扱いですか？
  
  振替休日は平日にしています。
  
  なぜなら
  例えば今年の３月の場合、
  D列()内には　20/日(春分)　21/月(振替)　と表示します。
  祝日のカウントは　春分　で　振替をカウントして後で引算と考えています。
  
  =COUNTIF(D6:D36,"振替")　=1
  
  よろしくお願いいたします。

  No.5の回答に寄せられた補足コメントです。 補足日時：2016/02/12 20:18

No.1 ベストアンサー 回答者： jmuiny 回答日時： 2016/02/12 13:44

作業列を使う方法ですが。

例ではE列とF列にしますが、空いた列で構いません。
E6
=WEEKDAY(B6)
F6
=WEEKNUM(B6)
下へコピー

祝日AA2
=COUNTA(D6:D36)　
土AA3
=COUNTIFS(D6:D36,"",E6:E36,7,F6:F36,2)+COUNTIFS(D6:D36,"",E6:E36,7,F6:F36,4)
日AA4
=COUNTIFS(E6:E36,1,D6:D36,"")
平日AA5
=DAY(EOMONTH(B6,0))-SUM(I2:I4)

この回答へのお礼

早速のご指導誠にありがとうございます。
上手くできました。
なかでもEOMONTHの使い方が非常に勉強になりました。

今後ともご指導のほどよろしくお願いします。

お礼日時：2016/02/13 06:49

No.5 回答者： mike_g 回答日時： 2016/02/12 14:59

後になって「やっぱりヤ～メタ」とならぬための確認です。

》 土日と祝日が重なる場合は祝日にカウント
ご承知のとおり、振り替え休日てのはホントは日が祝日。
「日と祝日が重なる場合は祝日にカウント」するなら、振り替え休日は平日扱いですか？それとも両方とも祝日？！

No.4 回答者： jmuiny 回答日時： 2016/02/12 14:22

No.1です。

B列の日付の入力について補足致します。
中身は2016/1/1という日付です。表示形式をユーザー定義で d としています。

No.3 回答者： tom04 回答日時： 2016/02/12 14:09

No.2です。

投稿後間違いに気づきました。
B6セルに入れる数式を
=IF(MONTH(DATE(C$1,B$1,ROW(A1)))=B$1,DATE(C$1,B$1,ROW(A1)),"")
にしてください。

絶対参照になっていませんでした。m(_ _)m

No.2 回答者： tom04 回答日時： 2016/02/12 14:06

こんにちは！

一案です。
↓の画像のようにB1セル（セルの表示形式はユーザー定義から　0月　としておく）には
月の数値だけを入力し、C1セルに西暦年を入力するとします。
（年が変わっても対応できるようにするため）
そしてF1セルに
=DATE(C1,B1,0)-WEEKDAY(DATE(C1,B1,0)-6,2)
としておきます。
これは前月の最終土曜のシリアル値を表示させておくためです。
実際は遠く離れた目立たないセルにしても大丈夫です。

そして前提条件としてB列はシリアル値で表示させます。
B6セル（セルの表示形式はユーザー定義から　 d　としておく）に
=IF(MONTH(DATE(C1,B$1,ROW(A1)))=B$1,DATE(C1,B$1,ROW(A1)),"")
C6セルに
=IF(B6="","",TEXT(B6,"aaa"))
という数式をいれ、B6・C6セルを範囲指定　→　C6セルのフィルハンドルで31日までのC36セルまでフィル＆コピー！

これでとりあえずはカレンダーの作成は完了です。
D列は数式が入っていても、手入力でも構いません。

G5セルに
=COUNTIF(D6:D36,"?*")
G6セルに
=2-COUNTIFS(B6:B36,F1+14,D6:D36,"?*")-COUNTIFS(B6:B36,F1+28,D6:D36,"?*")
G7セルに
=COUNTIF(C6:C36,"日")-COUNTIFS(C6:C36,"日",D6:D36,"?*")
G8セルに
=COUNT(B6:B36)-SUM(G5:G7)
という数式を入れると
画像のような感じになります。

※　もっと簡単にできるかもしれませんが、
とりあえずはこの程度で・・・m(_ _)m

この回答へのお礼

早速のご指導誠にありがとうございます。
上手くできました。
今後ともご指導のほどよろしくお願いします。

お礼日時：2016/02/13 06:50