エクセル・INDIRECT関数の中で、とある範囲の列をくりかえしながら行番号は増やしたい

エクセルについて教えてください。

いま下記のような作業をしています。F2には別シートの名前が入っています。
　　　A列
　｜＿＿＿＿＿＿＿＿＿＿＿＿
1｜=INDIRECT($F$2&"!H2")
2｜=INDIRECT($F$2&"!I2")
3｜=INDIRECT($F$2&"!J2")
4｜=INDIRECT($F$2&"!K2")
5｜=INDIRECT($F$2&"!H3")
6｜=INDIRECT($F$2&"!I3")
7｜=INDIRECT($F$2&"!J3")
8｜=INDIRECT($F$2&"!K3")
・・・
・・・
というような表を作っています。
H,I,J,Kの繰り返しの中で、末尾の2,3,・・・だけが4,5,6と増えるように変わっていってほしいのですが、
ドラッグしてもまたH2,I2,の繰り返しになってしまい、できません。

エクセルの説明サイトなど調べてみましたが、はっきりしませんでした。
膨大な量があるので、できれば手打ちでなくドラッグでやりたいのですが、どうしたらいいのかわかりません。
無知で申し訳ありませんが、ご教授のほどよろしくお願いします。

No.1 ベストアンサー 回答者： tom04 回答日時： 2016/06/07 11:22

こんにちは！

INDIRECT関数を使用するというコトは、F2セルは変化するのでしょうか？
一例です。表示したいセルに
=INDIRECT(F$2&"!"&ADDRESS(INT(ROW(A8)/4),MOD(ROW(A1),4)+IF(MOD(ROW(A1),4)=0,4)+7))

という数式を入れフィルハンドルで下へコピーしてみてください。

※　F2セルが変化しないSheet名（仮に「Sheet2」と決まっている）ならば
=INDEX(Sheet2!H:K,INT(ROW(A8)/4),MOD(ROW(A1),4)+IF(MOD(ROW(A1),4)=0,4))

でも大丈夫だと思います。m(_ _)m

この回答へのお礼

迷いましたが、一番最初にくださったyom04さんにベストアンサーを。皆さんのご意見参考にしたいと思います。ありがとうございました！

お礼日時：2016/06/07 14:10

No.6 回答者： picopico_7 回答日時： 2016/06/07 13:30

No.3です。

「=INDIRECT($F$2&"!H)2")」だとHと2の間に不要なカッコがあるのでそのエラーかな？
念のため数式が入ってる部分の画像を引きのばしてみますね。

この回答へのお礼

できました！ありがとうございます！段階もわかりやすくて非常に
勉強になりました。画像までありがとうございました。感謝です。

お礼日時：2016/06/07 14:06

No.5 回答者： fujillin 回答日時： 2016/06/07 12:56

こんにちは

ANo1様と同様の発想ですが・・・

A1に
　=INDIRECT($F$2&"!"&MID("HIJK", MOD(ROW(F8),4)+1,1)&INT(ROW(F8)/4))
として、下方にフィルコピーではどうでしょうか？

この回答へのお礼

こちらでもできました！ありがとうございました。非常に勉強になります。がんばります！

お礼日時：2016/06/07 14:06

No.4 回答者： picopico_7 回答日時： 2016/06/07 11:48

No.3です

ごめんなさい。
ちょっと修正させて下さい。

⑥⇒コピペの際は「値のみ貼り付け」です
⑧⇒置換は「'=」を「=」にします

No.3 回答者： picopico_7 回答日時： 2016/06/07 11:38

こんにちは。

４行ごとに数字をアップさせて数式を作りたいのならばこんな手も。

---------------------------------------------------------------------
①A列に「'=INDIRECT($F$2&"!H」(I,J,K)まで入力

②B１～B4⇒「2」と入力
　B5⇒「B4+1」と入力
　B6～B8⇒「3」と入力

③B5～B8を範囲選択してドラッグ

④C列に「")」と入力

⑤D１に「=A1&B1&C1」と入力してドラッグ

⑥D列をE列にコピペ

⑦E列の式がそのまま表示されるので数式が入っているセルを範囲選択して置換処理

⑧⇒「=」を同じく「=」に置換

⑨E列の数式を本番シートに貼り付ける
---------------------------------------------------------------------

この回答へのお礼

ありがとうございます！
いま、試してみました。
しかし置換がうまくいってないのか、
最終的な数式である=INDIRECT($F$2&"!H)2")を入力するとエラーが出てしまいます。
添付画像が細かいところまでよく見えないのですが、数式が間違ってますでしょうか？
お聞かせください。

お礼日時：2016/06/07 13:16

No.2 回答者： tom04 回答日時： 2016/06/07 11:29

No.1です。

投稿後気づきました。
INDIRECT関数を使うのであれば
=INDEX(INDIRECT(F$2&"!H:K"),INT(ROW(A8)/4),MOD(ROW(A1),4)+IF(MOD(ROW(A1),4)=0,4))
でも大丈夫だと思います。

どうも失礼しました。m(_ _)m

この回答へのお礼

ありがとうございます！今試してみましたらうまく機能しました！本当にありがとうございます！

お礼日時：2016/06/07 12:46