エクセルのセルに時計表示するには？

Question

パソコンのシステム時計を使って、エクセルの1つのセルにリアルタイムに時刻を表示させる方法を教えてください。
システム時計でなくても、インターネットから標準時を取り込む方法でも良いと思います。
リアルタイムの時刻をエクセルのデータのひとつとして使いたいのです。
よろしくお願いします。

Wendy02 · Accepted Answer

追伸です。

# VRAMメモリのバッファの関係や仮想メモリの問題で、表示の問題は、PCの環境の問題ではないかと思います。

もう少し説明すると、Excelのワークシートに毎秒書き込むという作業そのものが負担なのです。こちらでは、その違いが分りませんが、ユーザーフォームではなく、例えば、ラベルやExcelのApplication.Caption を使うなどして、あまり、下位のRangeオブジェクトのプロパティにアクセスすることを避けるのがよいかもしれません。Rangeオブジェクトは、複合的な存在なのですね。

Wendy02 · Answer

こんばんは。Wendy02です。

＞（A,1)の表示が2秒ごとに進むという不具合が目立ちます。

残念ながら、VRAMメモリのバッファの関係や仮想メモリの問題で、表示の問題は、PCの環境の問題ではないかと思います。

おそらく、それ自体は、セル上ではどうしようもないことのような気がします。秒を表示するのは多少無理があります。しかし、私の環境のCRTでは、そういう現象は出てこないのです。おそらく、ユーザーフォーム上で処理すれば、解決するのではないかと思います。（保証はいたしません）コード自体は同じですから、後は、ユーザーフォームに移植すれば、表示自体は楽になると思います。ただし、記録自体は、ワークシートが良いかもしれません。

完全な正確性をお考えになるようでしたら、C++ など、直接 Windowsのシステムから取れるものにするか、Visual Basic .NET などのほうがよいと思います。とても、Excelなどの重装備のオブジェクトを持っているソフトウェアでは不可能だと思います。書き入れたときに、わずかですが、表示が阻害されます。

＞左辺　StartCell.Offset(, lngCount).Value のOffset中に左記のように ( , ）を加え＞ました。
＞それでも3回目の表示データ以後は、差分の差分が加算されて表示されているようです。

横型でしたら、

StartCell.Offset(, lngCount).Value = Range("A2").Value - WorksheetFunction.Sum(Range(StartCell, StartCell.Offset(, lngCount)))

例:

A2の表示は　「12 」

時系列→
10　　0　　1　　1　　0

＞Option Explicit など 他にも分からないことがまだまだいっぱいあります。　
Explicit の意味は、明示的という意味です。つまり、明示的に型の宣言をしています、ということです。

＞例えば Call TimerRefresh を始めとする特殊な時間関数の意味や使い方など、インターネット上のどこかで参考にできるようなページがあるのでしょうか？

もう、ここらのレベルでは、たまたま誰かが掲示したということでないと、Webで参考になるページはないはずです。少し掘り下げたものは、ほとんどインターネットではヒットしません。地道に本で勉強するしかないと思います。

＞1台のパソコンで4方向の交通量が同時に自動測定記録できれば、大幅に効率向上できます。

これは、保留です。
今でも、表示系で重いようですから、なかなか、問題が多いような気がします。

ただ、繰り返しますが、多少、無理が見えてきました。
もう一度、大幅な変更をすべきか、迷うところです、API関数を使用して、システムから時間を取るべきか、なんとも言えませんが、ワークシート上から、ユーザーフォームに変えたほうがよいかもしれません。

Wendy02 · Answer

kinseiさん、こんにちは。Wendy02です。

作り直しました。
一気に作らないので、自分のコードが見えなくなって、遅くなってしまいました。

最初に、
＞2番目のストップウオッチでは、最初は20秒間隔でカウントされ、その後1分間隔でカウ＞ントされるようです。
＞なぜ20秒間隔なのかは分かりませんが。

テストでは、20秒間隔で行っていたからですが、その辺りも見直しました。
以下のコードの中で、秒で指定してください。

ただし、注意点があります。例えば、300秒でしたら、記録は　301 秒後になります。記録は、1秒のズレがあります。気になるようでしたら、TIMEVALUE("00:00:01")

PresentTime = Now -TIMEVALUE("00:00:01")　　'現在の時刻
としてください。

現在は、STARTCELLNAME に記録した場所から、横に表示するようになっています。

'========================================
'シートモジュール
Private Sub CommandButton1_Click()
　'スタートボタン
　Range("A1").NumberFormatLocal = "h:mm:ss"
　Range("A1").Value = 0
　On Error GoTo ErrHandler
　If Range(STARTCELLNAME).Value > 0 Then
　　 If MsgBox("上書きされますがよろしいですか？", vbOKCancel) = vbCancel Then
　　　　Exit Sub
　　 End If
　End If
　If (Columns.Count - Range(STARTCELLNAME).Column) < LASTCOUNT Then
　　 MsgBox "回数は、列数に依存します。" & LASTCOUNT & "を減らしてください。"
　　 Exit Sub
　End If
　myStartTime = TimeValue(Now)
　lngCount = 0
　CommandButton1.Enabled = False
　Call TimerRefresh
　Exit Sub
ErrHandler:
　MsgBox Err.Number & " : " & Err.Description
End Sub

Private Sub CommandButton2_Click()
　'終了ボタン
　lngCount = 0
　Call TimerRefreshStop
　CommandButton1.Enabled = True
End Sub

'========================================
'標準モジュール
Option Explicit
Private myOnTime As Date
Public lngCount As Long
Public myStartTime As Date
'====================
'*******設定値*******
Public Const STARTCELLNAME = "D7"　　 'スタートセル
Public Const LASTCOUNT = 100　　　　 'カウント数(データ数）
Private Const MY_INTERVAL As Long = 300 '秒数 (5分 = 300）
'====================
Sub TimerRefresh()
　Dim TimeDifference As Date
　Dim TimeCount As Long
　Dim StartCell As Range
　Dim PresentTime As Date
　
　If StartCell Is Nothing Then
　　 Set StartCell = Range(STARTCELLNAME)
　End If
　TimeDifference = Time() - myStartTime
　TimeCount = TimeDifference * 60& * 60 * 24
　''Cells(10, 1).Value = TimeCount 'Count検査用
　Cells(1, 1).Value = Format$(Now + TimeDifference, "h:nn:ss")
　myOnTime = Now + TimeSerial(0, 0, 1)　　'秒単位
　DoEvents
　Application.OnTime myOnTime, "TimerRefresh"
　PresentTime = Now　　'現在の時刻
　If TimeCount > MY_INTERVAL Then
　　　 '累計方式
　　　　'StartCell.Offset(lngCount).Value = Range("A2").Value - WorksheetFunction.Sum(Range(StartCell, StartCell.Offset(lngCount)))
　　　　 
　　　　 StartCell.Offset(-1, lngCount).Value = Format$(PresentTime, "h:nn:ss")
　　　　 StartCell.Offset(, lngCount).Value = Range("A2").Value
　　　　 lngCount = lngCount + 1
　　　 
　　　　If lngCount > LASTCOUNT Then
　　　　　 Set StartCell = Nothing
　　　　　 Call TimerRefreshStop
　　　　End If
　　　　Beep
　　　　TimeCount = 0
　　　　myStartTime = TimeValue(Now)
　End If
End Sub

Sub TimerRefreshStop()
　 '終了用
　 On Error Resume Next
　 Application.OnTime myOnTime, "TimerRefresh", , False
　 myStartTime = 0
End Sub

'----------------------------------------

Wendy02 · Answer

kinsei様、もう少し、お待ちください。

どうも、不手際申し訳ありません。お話は了解しましたし、変更もさほどむつかしくはありません。私は、前々からこのテーマをどうしてもしたかったので、両天秤を掛けたことがいけなかったようです。公開するものは、最初のものに、的を絞って進めていきます。今回書いた内容が、越えそうで越えないテーマの1つなのですね。

みなさんが、出来ないと思ったのも当然でしたし、前の私も同じでした。Excelでこんなことまでできるというのは、留まるところがありませんね。しかし、書籍購入費も留まるところがありません。

＞「超図解Excel　マクロ＆VBA　プログラミング」
なかなか、分りやすい本だと思います。最初に、こういう本を買っておけば、私は失敗しなかっただろうなって思います。

＞私も自分でマクロやVBAを使えるようになりたいと思っています。
私自身は、2年までは調子良く進んだのですが、その後が、長い長いトンネルをまだ抜け出せません。今は、我慢して、諦めないようにするだけです。

なお、
＞2番目のストップウオッチのボタン動作が正しくないようです。
やっぱりそうでしたか。なぜか良く分りませんが、特に、二度打ちしたりすると良くないようです。

＞2番目のストップウオッチでは、最初は20秒間隔でカウントされ、
作成中は、20秒で行っていたからで、それは簡単に直せますが、その流れ自体を換えることにしました。ただ、1番目側を進めていくようにします。

今、直しているのは、時間表示に戻しますが、クリックの開始時刻は、その始めた時からの時間にしています。

それでは、もう少し、お待ち願います。

Wendy02 · Answer

こんばんは。Wendy02です。
やっと、出来ました。二つのものを考えてみました。どうしても、気が乗らないと作れない種類のものです。

最初に紹介したものと同じパターンのものと、二重線から下のコードは、APIを使ったもので、私には、多少不安定要素が含まれるような気がします。ただ、時間の書き込み中に占有されません。

なお、時間表示は、ストップウォッチになっています。


表示レイアウト
　A　　　　B　　 C　　　　　ボタン1
0:01:24　　　　 30
45　　　　　　　 5
　　　　　　　　10　　　　　ボタン2
　　　　　　　　 0


'シートモジュール
'-------------------------------------
Private Sub CommandButton1_Click()
　Range("A1").NumberFormatLocal = "h:mm:ss"
　Range("A1").Value = 0
　myStartTime = TimeValue(Now)
　CommandButton1.Enabled = False
　Call TimerRefresh
End Sub

Private Sub CommandButton2_Click()
　Call TimerRefrshStop
　CommandButton1.Enabled = True
End Sub

'標準モジュール
'------------------------------------------------------
Private myOnTime As Date
Private lngCount As Long
Public myStartTime As Date
Sub TimerRefresh()
　Dim TimeDifference As Date
　'掲示板に出したもの
　'A1に表示が出ます。
　TimeDifference = Format$(Time() - myStartTime, "h:nn:ss")
　Cells(1, 1).Value = TimeDifference
　myOnTime = Now + TimeSerial(0, 0, 1) '1秒単位
　DoEvents
　Application.OnTime myOnTime, "TimerRefresh"
　If　 Second(TimeDifference) = 0 Then
　　　 If Range("C65536").End(xlUp) = 0 Then
　　　 Range("C65536").End(xlUp) = Range("A2").Value - lngCount
　　　 Else
　　　 Range("C65536").End(xlUp).Offset(1).Value = Range("A2").Value - lngCount
　　　 End If
　　　 lngCount = Range("A2").Value
　End If
End Sub

Sub TimerRefrshStop()
　 On Error Resume Next
　 Application.OnTime myOnTime, "TimerRefresh", , False
　 lngCount = 0
　 myStartTime = 0
End Sub

'------------------------------------------------------

'==========================================================
'以下は、同じモジュールには登録はしてはいけません。
'単独のモジュールです。なるべく、他のブックといっしょには用いないでください。

'シートモジュール
'---------------------------------------------------------
Private Sub CommandButton1_Click()
　'スタートボタン
　 Call StartTimer
　 CommandButton1.Enabled = False
End Sub

Private Sub CommandButton2_Click()
　'終了ボタン
　 Call TimerStop
　 CommandButton1.Enabled = True
End Sub

'標準モジュール
'-------------------------------------------------------
Private Declare Function GetTickCount Lib "kernel32" () As Long
Private Declare Function SetTimer Lib "user32" (ByVal Hwnd As Long, ByVal nIDEvent As Long _
　　, ByVal uElapse As Long, ByVal lpTimerFunc As Long) As Long
Private Declare Sub KillTimer Lib "user32" (ByVal Hwnd As Long, ByVal nIDEvent As Long)

Private lngTimerID As Long
Private myCell As Range
Private lngStartTime As Long
Private lngStock As Long
Sub StartTimer()
　　Dim lngInterval As Long
　　lngInterval = 1000
　　Set myCell = Range("A1")
　　myCell.NumberFormatLocal = "h:mm:ss"
　　Range("A1").Value = 0
　　lngStartTime = GetTickCount()
　　lngTimerID = SetTimer(0&, 0&, lngInterval, AddressOf s_Timer)
End Sub

Sub s_Timer(ByVal Hwnd As Long, ByVal uMsg As Long, ByVal idEvent As Long, ByVal dwTime As Long)
　　Dim dblTime As Double
　　dblTime = (GetTickCount() - lngStartTime) / (60& * 60 * 24 * 1000)
　　On Error Resume Next
　　myCell.Value2 = dblTime
　　If Second(dblTime) Mod 20 = 0 Or Second(dblTime) = 0 Then
　　　 If Range("C65536").End(xlUp) = 0 Then
　　　 Range("C65536").End(xlUp) = Range("A2").Value - lngStock
　　　 Else
　　　 Range("C65536").End(xlUp).Offset(1).Value = Range("A2").Value - lngStock
　　　 End If
　　　 lngStock = Range("A2").Value
　　End If
End Sub

Sub TimerStop()
　　KillTimer 0&, lngTimerID
　　Set myCell = Nothing
　　lngStock = 0
End Sub

Wendy02 · Answer

こんばんは。Wendy02です。

＞ついでにお聞きしたいのですが、最終的には、
＞この時計をA1のセルに表示させ、通過車両台数の計数値をA2のセルに表示させながら、
＞これができるまでの道のりはまだまだ遠いのでしょうか？ 

ちょっと考えさせてください。（今日は、ちょっと無理ですが、より良いものを考えます。もともと、私が、この問題は、ずっと前から手がけていた内容なのです。このご質問が、もし私の考えたものと合えばと思って、それで様子をみていたのです。Visual Basic　カテゴリでは、回答の反応自体がありませんでした。久々の名作？（迷作）だと思ったのですが。

http://oshiete1.goo.ne.jp/kotaeru.php3?q=1721584
コンセプトは同じですが、こちらよりも、はるかにむつかしい内容です。）

＞私が初心者でかつ十分には時間が取れていないので、レスポンスが遅くなってし
＞まうと思います。

それは構いません。やりながら、学べばよいです。入門編ぐらいは、1ヶ月ぐらいで卒業できますから。それから、私は、VBAを使って、自分の発言を画面から取得しリスト化して、気になるものは、すぐに開けられるようにしてあります。どんなに、時が経っても、こちらが、もうダメと判断しなければ、リストには残ります。（言葉よりもずっとすごいです。（^^;）

それから、お礼側に返事をつけたものに関しては、メールが届きますので分ります。時間的なものは気にしなくてよいです。また、つけなくても、1ヶ月先でも、2ヶ月先でも、今は、十分にチェックできます。

＞ネット上のどこを見れば参考にできるのか、そのページを教えていただけるとあ
＞りがたいと思っています。

このご質問の件に関しては、たぶん、どこにも出てこないかもしれません。私の勧めるところは、今は、Microsoft のMSDNぐらいしかありません。

Wendy02 · Answer

こんばんは。Wendy02です。

ボタンの取り付け方:

メニューの何もないところで、右クリック－コントロールツールボックス
　とすると、
コントロールツールバーが出てきます。

次に、□（長方形）のボタンをクリック

ワークシートにマウスを移すと、マウスカーソルが、＋　になります。

それで、斜めにドラッグすれば、ボタンが出来上がります。

それをもう一度行ってください。

そうしたら、そのボタンを右クリック－[コードの表示]

で、そのまま、

　Private Sub CommandButton1_Click()
　'ココ
　End Sub

というのが、出来上がりますので、そこに、Call TimerRefresh を入れ、

Private Sub CommandButton2_Click()
 'ココ
End Sub
 
に、 
Call TimerStop
Beep

を入れ、今度は、現在のVisual Basic Editor 画面のまま、メニューから　挿入－標準モジュールをクリック

今度は、標準モジュール側のコードを貼り付けます。

貼り付けたら、Alt キーを押しながら、Q （または、ファイル(F)-終了してExcelへ戻る）

まだ、コントロールツールバーが出ていたら、青い三角定規のコマンドボタンが凹んでいたら、クリックして、元に戻します。
（ただ、もし、シート上のコマンドボタンの名前などを変える場合は、右クリックして、コマンドボタンオブジェクトから、名前を変更してから、青い三角定規のコマンドボタンをクリックします。）

そして、メニューの何もないところで、右クリック－コントロールツールボックスをクリックして、ツールバーを消します。

＞多少時間がかかるかも知れませんが、

時間さえ掛ければ、これは何とかなりますし、より良いものが得られると思います。なお、時間表示中にも入力は可能であることを前提として考えています。

コードを取り付ける方法は、いくつかのサイトでは、スクリーン・キャプチャで取った画面の絵で説明出ているものがあるかと思います。

Wendy02 · Answer

kinseiさん、こんばんは。

お話の要点が見えないので、少し、様子を見させていただきました。

#6さんの
＞エクセルでは、デジタル時計のように、何もしなくても自動的に時間表示が変わるということはできないですね。

いくつか方法はあります。本来は、VBでは標準的なのに、VBAでは、どうやるのか、探してみましたが、出てきませんでしたし、私が出来ても、該当するActiveX コントロールを持っていない人には使えません。

（問題ある場合は、また、負担の少ない方法を考え直します。ただし、明日は、すぐにお答えできないですが、私でなくても、それが、できる方がここにはいらっしゃいます。）

また、「インターネットから標準時を取り込む方法でも良いと思います」というのは、一回、システム時計を修正するだけのマクロになってしまいます。サーバー経由ですので、若干、cmd.exe /c のコプロからExcelのワークシートに戻ってくるまでのタイムラグが生じて、繰り返しするにはロスが出てしまいます。やはり、システム時計を使わないと、うまくいきません。

シートにコントロールツールのボタンを二つ用意してください。
ここでは、シート1 にボタンを取り付けるとします。
'-------------------------------------------------
Private Sub CommandButton1_Click()
　'スタートボタン
　 Call TimerRefresh
End Sub

Private Sub CommandButton2_Click()
　'終了ボタン
　 Call TimerStop
　 Beep
End Sub

'-------------------------------------------------

標準モジュールには以下のようにしてください。
'------------------------------------------------
Private myOnTime As Date
Sub TimerRefresh()
　'シート1 のA1に表示が出ます。
　Sheet1.Cells(1, 1).Value = Format$(Time(), "h:nn:ss")
　myOnTime = Now + TimeSerial(0, 0, 1)　'1秒単位
　DoEvents
　Application.OnTime myOnTime, "TimerRefresh"
End Sub

Sub TimerStop()
　 Application.OnTime myOnTime, "TimerRefresh", , False
End Sub

若干、VBAメソッドですから、多少の、負荷・負担があります。他にも方法があります。

lilact · Answer

エクセルでは、デジタル時計のように、何もしなくても自動的に時間表示が変わるということはできないですね。
ただ、「=now()」を埋め込んだセルを参照した計算をする場合、表示が過去の時間になっていても計算を実行した時間を参照して計算しますから使えるとは思います。同時に時間表示も更新されます。
マクロに埋め込むこともできますし、どのような計算をするかを書かれると、回答しやすいかと思います。

imogasi · Answer

関数では
=TEXT(NOW(),"ggg.e年mm月.dd日hh時mm分ss秒")
というところでしょうか。
ただF9を押さないと現在時刻に更新されません。
即時（的）に（1分１秒単位で）更新させるには、エクセルVBAレベルで組むのは難しいのではないかと思います。
あとはフリーソフトやアドインを見つけるとか。
取得できる単位の問題
http://www.happy2-island.com/excelsmile/smile04/capter00304.shtml
ある時点からXX秒後に一回起動などならできる（Timerなど）が、永久にXX秒ごとに割り込みを掛けて何か（この場合は時刻表示）をするのは、一段高いスキルがいるように思う。

エクセルのセルに時計表示するには？

追伸です。

こんばんは。

この回答への補足

kinseiさん、こんにちは。

この回答への補足

kinsei様、もう少し、お待ちください。

こんばんは。

この回答への補足

こんばんは。

こんばんは。

kinseiさん、こんばんは。

エクセルでは、デジタル時計のように、何もしなくても自動的に時間表示が変わるということはできないですね。

この回答への補足

関数では

似たような質問が見つかりました

このQ&Aを見た人はこんなQ&Aも見ています

関連するカテゴリからQ&Aを探す

このQ&Aを見た人がよく見るQ&A

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング