範囲内で２番目、３番目に低い値を、別セルへの表示する方法を教えて下さい。 例、 15 15 15 1

範囲内で２番目、３番目に低い値を、別セルへの表示する方法を教えて下さい。
例、
15
15
15
18
18
20
この範囲で、２番は18、３番は20
となるような式を作りたいです。
(SMALL)だけですと、２番目も15と表示されました。
よろしくお願いいたします

No.2 ベストアンサー 回答者： ママチャリ 回答日時： 2017/10/31 15:06

こんな感じでしょうか。

ただし、応用が利かないやり方です。
1番目はMIX関数で求めることができます。2番目はその値を基に求めます、さらに3番目は2番目の値を基に求めます。なので、いきなり10番目を求めることはできません。

【C2セル】=SMALL($A:$A,COUNTIF($A:$A,"<="&MIN($A:$A))+1)
【D2セル】=SMALL($A:$A,COUNTIF($A:$A,"<="&C2)+1)

この回答へのお礼

ありがとうございました。
他のセルを使わず直接表示できる式でしたのでベストアンサーにさせて頂きました。

お礼日時：2017/11/01 07:43

No.4 回答者： mike_g 回答日時： 2017/10/31 16:43

添付図参照

B1: =IF(COUNTIF(A$1:A1,A1)=1,A1,"")
E1: =SMALL(B$1:B$6,D2)

この回答へのお礼

ありがとうございます！
参考になりました。

お礼日時：2017/11/01 07:51

No.3 回答者： enunokokoro 回答日時： 2017/10/31 15:37

No.1の回答者さんと似ていますが。

作業列を使うことで、SMALL関数で指定できます。
数値の範囲が決まっていることが前提です。

B列を作業列にしています。
=IF(ROW()=MATCH(A2,$A$2:$A$7,0)+1,A2,"")

SMALL関数の配列はB列の範囲を指定します。

この回答へのお礼

ありがとうございます。
参考になりました。

お礼日時：2017/11/01 07:50

No.1 回答者： tom04 回答日時： 2017/10/31 14:19

こんばんは！

具体的な配置が判らないので、やり方だけ・・・

↓の画像のようにA列にデータがあるとします。
安直な方法ですが、作業列を設けるのはどうでしょうか？

作業列B2セルに
=IF(COUNTIF(A$2:A2,A2)=1,RANK(A2,A:A,2),"")
という数式を入れフィルハンドルでこれ以上データはない！というくらいまで下へコピーしておきます。

そしてE2セルに
=INDEX(A:A,MATCH(SMALL(B:B,ROW(A2)),B:B,0))

という数式を入れ下へフィル＆コピーしています。
（エラー処理はしていません）

※　作業列が目障りであれば遠く離れた列にするか
非表示にしておきます。m(_ _)m

この回答へのお礼

ありがとうございます。
作業列を作る方法も有るのですね。参考になりました。

お礼日時：2017/11/01 07:47