VBAの範囲印刷設定を修正したいのですが

VBAの初心者です。詳しく教えてください。
１.下記のVBAでシートを非表示にしたときに実行時エラー１００４が出るのですが　　どうしたらよいのですか。
ーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーー
Sub printappointedrange()

Worksheets("シート１").Activate
Range("A1:AB42").Select 'セル範囲の選択

With ActiveSheet
.PageSetup.PrintArea = Selection.Address '印刷範囲の指定
.PrintOut '印刷
.PageSetup.PrintArea = False '印刷範囲のクリア
End With

End sub
ーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーー

２.シートに印刷ボタン作成して、印刷はできるのですが、印刷する前にプリンターの設定を変更する方法は無いのですか。

No.3 ベストアンサー 回答者： nishi6 回答日時： 2002/01/17 23:41

シート２の表示、非表示にかかわらず、印刷を行います。

簡単にしてあります。

Sub printappointedrange()
　　Dim ws As Worksheet 'ワークシート
　　Set ws = Worksheets("シート２")

　　Dim ws2visible As Boolean 'シート２の表示条件

　　Application.ScreenUpdating = False '画面更新ストップ

　　ws2visible = ws.Visible
　　　　'シート2が非表示なら表示する
　　　　If ws2visible = False Then
　　　　　　ws.Visible = True
　　　　End If

　　ws.Activate
　　ws.PageSetup.PrintArea = "A1:AB42" '印刷範囲の指定

　　Application.Dialogs(xlDialogPrint).Show 'プリンタ設定

　　'シート2の表示を戻す
　　If ws2visible = False Then
　　　　ws.Visible = False
　　End If

　　Worksheets("シート１").Activate
　　Application.ScreenUpdating = True '画面更新

End Sub

この回答へのお礼

いろいろ、教えていただきありがとうございます。
本に記載されている、マクロの記述と回答を頂いた記述が違ったので、悩みましたが、本より回答を頂いたほうが、よく分かりました。

お礼日時：2002/01/18 12:38

No.2 回答者： nishi6 回答日時： 2002/01/12 12:07

質問の『印刷する前にプリンターの設定を変更する方法』の意味がよくわからなかったので、

xlDialogPrintとxlDialogPrinterSetupを回答したのですが、補足では、『xlDialogPrint』が使ってあり、
このままでは、

１．『xlDialogPrint』のダイアログでOKボタンを押したためにボタンがあるシート１を印刷

２．マクロの『.PrintOut』でシート２の印刷

となって、シート１、シート２が印刷されるはずです。

Ａ．『プリンターの設定』が印刷書式の設定なら『xlDialogPageSetup』を
Ｂ．『プリンターの設定』がプリンタの切替等なら『xlDialogPrinterSetup』を使用します。

Ｃ．『印刷』のダイアログをだすのなら『xlDialogPrint』ですが、このままだとシート１も印刷してしまいます。

『印刷する前にプリンターの設定を変更する方法』がＣの場合は補足してください。

この回答への補足

申し訳ありませが、『印刷する前にプリンターの設定を変更する方法』Ｃの場合を教えてもらえますか。
よろしくお願いします。

補足日時：2002/01/13 22:53

No.1 回答者： nishi6 回答日時： 2002/01/11 01:10

中に書き込んでみました。

非表示なら表示して印刷後非表示に戻しています。
非表示でも印刷しています。(質問でここが一番分からない。非表示なら印刷する？しない？)

プリンタの設定は『'』をはずして確認して下さい。

Sub printappointedrange()
　　Dim Sheet1Visible As Boolean 'Sheet1のマクロ実行時のVisibleの設定

　　'プリンタの設定→どちらのことでしょうか。『'』をはずして試して下さい。
　　'Application.Dialogs(xlDialogPrint).Show
　　'Application.Dialogs(xlDialogPrinterSetup).Show

　　Sheet1Visible = Worksheets("シート１").Visible

　　Application.ScreenUpdating = False '画面更新をストップ
　　If Sheet1Visible = False Then
　　　　'非表示ならSheet1を表示する
　　　　'非表示の場合印刷しないなら　Exit Sub を書く
　　　　Worksheets("シート１").Visible = True
　　End If
　　'/// ここまで追記 ///

　　Worksheets("シート１").Activate
　　'/// このマクロがどのコードウインドウにあるか分からないので ActiveSheet. を追加 ///
　　ActiveSheet.Range("A1:AB42").Select 'セル範囲の選択

　　With ActiveSheet
　　　　.PageSetup.PrintArea = Selection.Address '印刷範囲の指定
　　　　.PrintPreview '印刷
　　　　.PageSetup.PrintArea = False '印刷範囲のクリア
　　End With

　　'/// 以下を追記 ///
　　'元に戻す
　　Worksheets("シート１").Visible = Sheet1Visible
　　Application.ScreenUpdating = True '画面更新を戻す

End Sub

この回答への補足

質問の仕方が悪かったので、すみませんが、もう少し教えてください。
○状況
・現在シート２を非表示にしてあります。
・シート１に印刷ボタンがあります。（ボタンをマクロ登録しています・・・下記　VBAです。）
・下記のVBAで「プリンタ設定、画面更新ストップ」を追加したときに、シート１及　びシート２（選択範囲のみ）が印刷されます。
○質問
・シート１及びシート２が印刷されるので、シート１を印刷しないようにし、シート２を印刷したいのです。
・プリンタの種類によっては、プリンタ設定を２回聞いてきます。（シート１とシ　ート２が印刷されるからですか）
○その他
・下記のVBAは回答を頂いたのを、私なりに修正しました。
・下記のVBAで「プリンタ設定、画面更新ストップ」を記述しない場合はシート２し　か印刷されませんでした。
---------------------------------------------------------------------
Sub printappointedrange()

Dim ws As Worksheet 'ワークシート
Dim PrintFlg As Boolean '印刷するかの判定

On Error GoTo ErrorHandler 'エラー対応(非表示シート対応)

Application.Dialogs(xlDialogPrint).Show 'プリンタ設定
Application.ScreenUpdating = False '画面更新ストップ

For Each ws In Worksheets '全てのシートを調べる
With ws
Select Case .Name
Case "シート２"
.PageSetup.PrintArea = "A1:AB42" '印刷範囲の指定
.PrintOut '印刷
.PageSetup.PrintArea = "" '印刷範囲クリア
End Select
End With
Next
Exit Sub '終わり

ErrorHandler:
'シートが非表示の場合
If Err = 1004 Then
ws.Visible = True '表示する
ws.PrintOut
ws.Visible = False '非表示に戻す
End If
Resume Next '次の処理
End Sub

---------------------------------------------------------------------

補足日時：2002/01/11 18:56