excelで別シートにセルを参照する式の行番号の指定

エクセル初心者です。
まず、住所録のシートがあります。

A　　　　 B　　　　　　　　　 c
○山○子　北海道ほにゃらら町　090-0000-0000
△田◆雄　東京都ぴながわ区　　03-0000-0000

のように、各行にひとりずつ入っています。
それを別のシートに

○山○子
北海道ほにゃらら町
090-0000-0000

と表示させたいので、=で参照してみました。
そして、次の行に入っている△田◆雄を
セルのコピーで参照できる・・・のは虫が良すぎたようで、参照元（行番号1）の直下の行を参照せず、エクセルが数式の行番号を適当に計算して（行番号2ではなく4くらい）割り当ててしまいます。

これを、セルの指定をして、一挙にコピーした場合でも、参照元をそれぞれ直下の行にすることは可能でしょうか。

また、なにか良い方法があれば教えてくださいませんでしょうか。

何卒よろしくお願いいたします。

No.1 ベストアンサー 回答者： ASIMOV 回答日時： 2007/07/03 14:45

別シートにのA1から

A1=INDEX(Sheet1!A:A,(ROW()-1)/3+1,1)
A2=INDEX(Sheet1!B:B,(ROW()-2)/3+1,1)
A3=INDEX(Sheet1!C:C,(ROW()-3)/3+1,1)
として、A1-A3を選択して下にコピーしてみてください

この回答へのお礼

本当にありがとうございました！
できました♪

お礼日時：2007/07/04 12:40

No.4 回答者： imogasi 回答日時： 2007/07/03 21:03

例データ

Ｓｈｅｅｔ１
Ａ１：Ｃ３
abc
xyz
uvw
Ｓｈｅｅｔ２のＡ１に
=INDEX(Sheet1!$A$1:$C$100,INT((ROW()-1)/3)+1,MOD(ROW()-1,3)+1)
と入れて下方向に式を複写する。
結果
Ａ１：Ａ９
a
b
c
x
y
z
u
v
w

この回答へのお礼

お寄せいただいたものを全てやってみている最中で、
まだ試していませんがこれからチャレンジします！
ありがとうございました。

お礼日時：2007/07/04 12:46

No.3 回答者： mu2011 回答日時： 2007/07/03 15:09

住所録をシート１として、シート２のＡ列に抽出します。

シート２のA1セルに=OFFSET(Sheet1!$A$1,INT((ROW()-0.1)/3),MOD(ROW()-1,3))入力し、下方向にコピーして下さい。

この回答へのお礼

やってみました！できました！
ありがとうございました。
関数勉強します！

お礼日時：2007/07/04 12:44

No.2 回答者： may0430 回答日時： 2007/07/03 14:50

こんにちは。

＿＿＿＿＿＿＿＿＿＿＿＿＿＿
　A1　○山○子
　A2　北海道ほにゃらら町
　A3　090-0000-0000
　A4　△田◆雄
　A5　東京都ぴながわ区
　A6　03-0000-0000
　・・・

↑こういう並びということでよいですよね？
＿＿＿＿＿＿＿＿＿＿＿＿＿＿
　A1　=OFFSET(Sheet1!$A$1,(ROW()-1)/3,0)
　A2　=VLOOKUP(A1,Sheet1!$A$1:$C$10,2,FALSE)
　A3　=VLOOKUP(A1,Sheet1!$A$1:$C$10,3,FALSE)
（※　$A$1:$C$10 は もとの表の範囲）
　　
もしくは、
　A1　=OFFSET(Sheet1!$A$1,(ROW()-1)/3,0)
　A2　=OFFSET(Sheet1!$A$1,(ROW()-2)/3,1)
　A3　=OFFSET(Sheet1!$A$1,(ROW()-3)/3,2)
＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿
OFFSET(基準となるセル番地、そのセル番地から何行ずれるか、何列ずれるか)
ROW()＝この数式が入っているセルの行番号
　A1の　(ROW()-1)/3＝(1-1)/3＝0
　A2の　(ROW()-2)/3＝(2-2)/3＝0
　…
_＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿
これだと一気にコピーしてできるはずです^^
（のちのちちょっとレイアウトを変えたくなったときのことを考えると、
修正箇所が少なくて済むのは、最初の方の数式です。）

この回答へのお礼

できました♪
式が同じなのになぜ表示が違ってくるのか不思議でしょうがないのですが、これから勉強します！
ありがとうございました。

お礼日時：2007/07/04 12:43