if関数の複数条件について

A1セルに半角数字の点数が入っています
B1セルに、点数に応じて、以下のとおり、△、〇等の記号を表示したいです

ifの複数条件が出来たらと考えています
ご存じの方、教えて下さい


1～3⇒△
4～9⇒〇
10～20⇒◎
0⇒空白

No.4 ベストアンサー 回答者： zongai 回答日時： 2025/07/19 03:38

IF関数をご存知なら、

=IF(　条件　,　Trueのときの処理　,　Falseのときの処理　)
という書き方であることはご存知だと思います。
この　Falseのときの処理　にIF関数を入れ込みます。

=IF(　条件1　,　Trueのときの処理　,
　　　IF(　条件2　,　Trueのときの処理　,　Falseのときの処理　)
　)

この2行目が条件1がFalseのときの処理です。
最初の条件がFalseなら、次の条件で判定しろ
と、こんな感じですね。

質問に書かれている内容だと、
IF関数で解決するなら、これで対応可能かな。
=IF(A1=0,"",IF(A1<=3,"△",IF(A1<=9,"〇",IF(A1<=20,"◎","判定基準外"))))


複数条件という意味で考えるなら、IFS関数を使うほうが、書きやすくわかりやすいと思います。
IFS関数の詳しい使い方は検索を。
=IFS(A1=0,"",A1<=3,"△",A1<=9,"〇",A1<=20,"◎",TRUE,"判定基準外")

余談ですが、数式の途中で[Alt]+[Enter]すると改行できるので、セルの中で
こんなふうに数式を入れてやると、条件ごとの処理がわかりやすいです。
--------------------
=IFS(A1=0,"",
A1<=3,"△",
A1<=9,"〇",
A1<=20,"◎",
TRUE,"判定基準外")
--------------------

No.3 回答者： fujillin 回答日時： 2025/07/14 10:11

こんにちは

ご提示の条件は部分条件なので、それ以外の場合をどうするのか不明です。
例えば、Ａ1の値が
　・空白の場合や数値でない文字列の場合
　・指定範囲外の-1や23の場合
　・ご提示の区切りの間の値（例えば3.5や9.5など）の場合

これらを、例えば連続数値の範囲の区切りと考えて
　・1以上、4未満
　・4以上、10未満
　・10以上
　・上記以外の値
などのように区分を整理してもよければ、式は簡単にできます。
検索すれば、ifs関数やvlookup関数等を利用する方法が見つかるでしょう。


＞ifの複数条件が出来たらと考えています
if関数で実現したければ、ご質問文の条件をそのままif関数でネストして並べれば良いです。
例えば
=IF(A1="","条件外",IF(A1=0,"",IF(AND(1<=A1,A1<=3),"△",IF(AND(4<=A1,A1<=9),"○",IF(AND(10<=A1,A1<=20),"◎","条件外")))))

※ 式が長いですが、これはご質問文の条件をそのまま記述しているからで、前述のように条件を整理することができれば、もっと簡単な式できます。
（文字数イメージとして半分以下の式にできそう）
※ 上式では、ご提示の条件に示されていない場合は「条件外」として扱うようにしてあります。
※ 上式もifs関数で書き換えれば、多少は短くできるでしょう。

No.2 回答者： タマタマポチ 回答日時： 2025/07/14 09:30

https://kuroco.team/blog-data-if/
　
「if関数の複数条件」で検索すればヒットします。

No.1 回答者： akubi_m 回答日時： 2025/07/14 09:04

if で0なら空白、3以下なら△、9以下なら〇、20以下なら◎を上から順番に評価する

とするのが教科書通りでしょうか。
else ifを使わないというのがポイント
見読性のためにはcaseを使ってほしいところではありますが。