エクセル 一番右側にあるデータを知りたい

エクセルにて
一番右側にあるデータや一番下側にあるデータの位置を
知りたいのですが、良い方法があれば教えてください。

No.4 ベストアンサー 回答者： mu2011 回答日時： 2008/05/08 18:38

NO3です。

行・列番号を抽出する一例です。
■最下行番号（仮にＡ列）
=IF(COUNTA(A:A),MAX(IF(COUNT(A:A),MATCH(MAX(A:A)+1,A:A)),IF(COUNTIF(A:A,"*"),MATCH("",A:A,-1))),"")
■最右列番号（仮に１行目）
=IF(COUNTA(1:1),MAX(IF(COUNT(1:1),MATCH(MAX(1:1)+1,1:1)),IF(COUNTIF(1:1,"*"),MATCH("",1:1,-1))),"")
因みにMAX関数も前にADDRESS関数を設定すればセル表示になります。

この回答へのお礼

回答ありがとうございます。

お礼日時：2008/12/01 09:43

No.5 回答者： sige1701 回答日時： 2008/05/09 09:53

こんな感じかな

一番下側にあるデータの位置を
=MAX(INDEX((A1:G10<>"")*ROW(A1:G10),))

一番右側にあるデータの位置を
=MAX(INDEX((A1:G10<>"")*COLUMN(A1:G10),))

この回答へのお礼

回答ありがとうございます。

お礼日時：2008/12/01 09:43

No.3 回答者： mu2011 回答日時： 2008/05/08 15:09

補足をお願いします。

・データの書式は何ですか？（数値のみ、文字列のみ、数値又は文字列）
・行／列範囲に未入力セルは存在しますか？　
・データの位置とはなんですか？（行番号、列番号、セル名）

この回答への補足

回答ありがとうございます。
補足いたします。

・データの書式は数値又は文字列です。
・行／列範囲に未入力セルは存在します。
・データの位置とは、
　　どこのセルにデータが入力されているか分かれば、
　　行番号、列番号あるいはセル名のいずれでもＯＫです。

補足日時：2008/05/08 18:03

No.2 回答者： sige1701 回答日時： 2008/05/08 14:21

こんな感じかな

=LOOKUP(1,0/(範囲<>""),範囲)

この回答へのお礼

回答ありがとうございます。

お礼日時：2008/12/01 09:42

No.1 回答者： tomname 回答日時： 2008/05/08 13:57

こういうことですか？

一行目の右端　=LOOKUP(10^16,1:1)
Ａ列の最下行　=LOOKUP(10^16,A3:A299)

この回答へのお礼

回答ありがとうございます。

一行目とかA列とか限定せずに、
一番右や一番下にあるデータの行、列番号などセルの位置を
特定できる情報を得たいのですが。

お礼日時：2008/05/08 18:10