Ｅｘｃｅｌ 縦のデータを横に展開

Excelで(1)から(2)のような状態にするにはどうしたらいいでしょうか？ご教示願います。

(1)
Ａ　●　１
Ａ　△　３
Ａ　■　４
Ｂ　×　１
Ｂ　●　４
Ｃ　△　２
Ｃ　□　３
Ｃ　☆　４


(2)
　　１　２　３　４
Ａ　●　　　△　■　
Ｂ　×　　　　　●
Ｃ　　　△　□　☆

ピボットテーブルを使用すればいいのでしょうか？

No.2 ベストアンサー 回答者： CoalTar 回答日時： 2009/03/06 17:33

A列 昇順として

B12セルに
=IF(ISNA(MATCH(B$11,INDEX($C$1:$C$8,MATCH($A12,$A$1:$A$8,0)):INDEX($C$1:$C$8,MATCH($A12,$A$1:$A$8)),0)),"",
INDEX(INDEX($B$1:$B$8,MATCH($A12,$A$1:$A$8,0)):$B$8,MATCH(B$11,INDEX($C$1:$C$8,MATCH($A12,$A$1:$A$8,0)):INDEX($C$1:$C$8,MATCH($A12,$A$1:$A$8)),0)))
右へ下へオートフィル

A列昇順の必要なしの作業列を使って E1セルに
=A1&C1
B12セルに
=INDEX($B$1:$B$8,MATCH($A12&B$11,$E$1:$E$8,0))
右へ下へオートフィル、エラー処理なし
参考まで

ちなみにピボットテーブルにはタイトル行が必要で、集計のために使うのでB列は数値である必要があります

この回答へのお礼

ありがとうございます。今日試してみます。

お礼日時：2009/03/09 08:24

No.4 回答者： mike_g 回答日時： 2009/03/06 20:35

Sheet1　　　　　　　　　Sheet2

　 A　 B　 C　　　　　　　 A　 B　 C　 D　 E
1　Ａ　●　１　　　　　 1　　　１　２　３　４
2　Ａ　△　３　　　　　 2　Ａ　●　　　△　■
3　Ａ　■　４　　　　　 3　Ｂ　×　　　　　●
4　Ｂ　×　１　　　　　 4　Ｃ　　　△　□　☆
5　Ｂ　●　４
6　Ｃ　△　２
7　Ｃ　□　３
8　Ｃ　☆　４

Sheet2!B2: =IF(SUMPRODUCT((Sheet1!$A$1:$A$20=$A2)*(Sheet1!$C$1:$C$20=B$1)),INDEX(Sheet1!$B$1:$B$20,SUMPRODUCT((Sheet1!$A$1:$A$20=$A2)*(Sheet1!$C$1:$C$20=B$1),ROW(A$1:A$20))),"")

この回答へのお礼

ありがとうございます。今日試してみます。

お礼日時：2009/03/09 08:25

No.3 回答者： mu2011 回答日時： 2009/03/06 17:34

次の方法は如何でしょうか。

縦データをSheet1として、Sheet2に横データを作成する
（１）Sheet2のA1を選択→データ→フィルタオプションの設定→指定した範囲を選択、リスト範囲欄にsheet1!$A$A,抽出範囲欄に$A$1、重複レコードは無視するをチェック→ＯＫ
（２）sheet2のA1はクリア、Ｂ１に１を入力し右方向に連続データを作成
（３）sheet2のB1に=IF(SUMPRODUCT((Sheet1!$A$1:$A$8=$A2)*(Sheet1!$C$1:$C$8=B$1)),INDEX(Sheet1!$B$1:$B$8,SUMPRODUCT((Sheet1!$A$1:$A$8=$A2)*(Sheet1!$C$1:$C$8=B$1)*ROW(Sheet1!$A$1:$A$8))),"")を設定、縦横にコピー

この回答へのお礼

ありがとうございます。今日試してみます。

お礼日時：2009/03/09 08:25

No.1 回答者： tomo8047 回答日時： 2009/03/06 17:00

はい。

ピボットテーブルで出来ます。

この回答へのお礼

ありがとうございます。

お礼日時：2009/03/09 08:22