ちょっと変わったマニアな作品が集結

エクセルの初歩的な質問になってしまうかもしれませんが
A列の値からB列の値で重複する値を削除して
C列を作る方法を教えてください。

A列
a
b
c
d

B列
c
d
から
結果
C列
a
b
のような結果が得られる処理方法を
お願い致します。

A 回答 (5件)

こんばんは!


すでに数種の回答が出ていますので
かぶっているものがあるかもしれませんが・・・

↓の画像のように作業列を使った方法になります。

C2セルに
=IF(COUNTIF($B$2:$B$5,A2)>0,"",ROW(A1))
としてオートフィルで下へコピー

この作業列を参照し、D列に表示させます。

D2セルに
=IF(COUNT($C$2:$C$5)>=ROW(A1),INDEX($A$2:$A$5,SMALL($C$2:$C$5,ROW(A1))),"")
という数式をいれて下へオートフィルでコピーしてみてください。
希望に近い形になると思います。

尚、データはA2~A5までの数式ですので
データ量によって範囲指定を広げてみてくださいね。

そして、作業列が目障りであれば
B列すべてを範囲指定して「非表示」にしても良いと思います。

以上、参考になれば幸いですが、
的外れの回答なら軽く読み流してくださいね。m(__)m
「エクセルでA列-B列=C列 の抽出方法に」の回答画像5
    • good
    • 0

Googleで「imogasi方式」で照会すれば、私の回答した抜き出しの問題がたくさん出ます。


その」亜種です。B列を条件としてB列に無い行を抜き出す。

A列   B列   C列(関数で算出)
ac1
bd2
c
d
C2の式は
=IF(COUNTIF($B$2:B$100,A2)=0,MAX($C$1:C1)+1,"")
下方向に式を複写。
D列にD2に
=INDEX($A$1:$A$100,MATCH(ROW()-1,$C$1:$C$100,0),1)
下方向に式を複写する。
結果
a
b
#N/A
#N/Aを出さないようには、ROW()-1がC列の最高値を超えると空白というIF関数をかぶせてください。
詳細は上記WEBの中の該当を探してください。
こういう風に抜き出しは関数では面倒なのだ。
    • good
    • 0

こんな感じ


=INDEX($A$1:$A$4,SMALL(INDEX(COUNTIF($B$1:$B$2,$A$1:$A$4)*100+ROW($A$1:$A$4),),ROW()))
    • good
    • 0

一例です。



1.A列のデータで、B列に重複したデータのないものだけをC列に抽出(2行目以降にデータがあるものとします)

C2に=IF(COUNTIF(B:B,A2)=0,A2,"")と入力し下へ必要数ドラッグ

これで目的のデータがC列に表示されます。ただし、空白行がそのまま含まれます。

2.空白行を上に詰める

関数では私の手に負えないので、フィルタ機能で「□空白」のチェックを外せば上に詰めて表示されます。
    • good
    • 0

C1に


=IF(COUNTIF(B:B,A1)>0,"",A1)
と入力して、C2以下にコピペ。
    • good
    • 0

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!

このQ&Aを見た人が検索しているワード

このQ&Aと関連する良く見られている質問

QエクセルでA列B列C列の重複するレコードのみを表示

エクセルのA列とB列とC列で重複するレコードのみを抽出して別の列に表示させたい。

エクセルのA列とB列とC列にそれぞれ1000行くらいのデータがあります。
それぞれの列内には重複レコードがあります。

この条件の中で

「A列とB列とC列に重複するデータすべて」

を抽出したいのですが、どんな方法がありますか。
抽出されたデータで重複レコードの場合は1件のみで表示したいです。

よろしくお願いします。


  A   B   C   抽出 
1-001-002--002--002
2-002-002--005--007
3-003-007--007--008
4-007-008--008--011
5-008-008--010
6-008-010--011
7-011-011--012
8-013-014--013

Aベストアンサー

式が複雑になるということはそれだけ分かりにくく、計算が重くなるということです。出来るだけ作業列を使ってわかりやすく処理することが肝要と考えます。
例えばA,B,C列の2行目からお示しのようなデータがあるとします。
D2セルには次の式を入力して下方にオートフィルドラッグします。

=IF(AND(COUNTIF(A$2:A2,A2)=1,COUNTIF(B:B,A2)>0,COUNTIF(C:C,A2)>0),MAX(D$1:D1)+1,"")

D列にはA,B,C列に共通して含まれるデータがあれば上から順に番号が付けられます。その際にもしもA列でダブったデータがある場合には最初に出てきたデータに番号が振られます。

お求めのデータはE列に並べるとしてE2セルには次の式を入力して下方にオートフィルドラッグします。

=IF(ROW(A1)>MAX(D:D),"",INDEX(A:A,MATCH(ROW(A1),D:D,0)))

D列が目障りでしたら列を非表示にすればよいでしょう。

QB列の値がA列にあるかを調べる関数

excel2010を使っています。
題名の通りなのですが、B列にある値がA列にあるかを関数を使って求めたいと思います。

B列に290個、A列に259個の値が入力されていて、

・B列にあってA列にないもの
・A列にあってB列にないもの

の両方を見つけ出したいのですが、よい関数を教えてください。exact関数ではダメでした。

Aベストアンサー

C1セルに
=IF(COUNTIF(B:B,A1),"","このAはAにあってBに無い")
以下コピー
D1セルに
=IF(COUNTIF(A:A,B1),"","このBはBにあってAに無い")
以下コピー

とそれぞれ埋めて検査します。

Qエクセル 同名の場合はB列にC列の数値を入れたい!

 A列  B列   C列     D列
りんご        50    みかん
みかん        30    ぶどう
いちご        20    ばなな
ぶどう        40    りんご
ばなな        60    いちご

↑上記のような表があります。
もしA列とD列が同名であればC列の金額をB列に表示したいのですがよい関数はありますでしょうか??
おわかりの方教えてくださーい!

Aベストアンサー

>このような場合は空欄にしたいのですが・・・
B1=IF(COUNT(MATCH($A1,$D:$D,0)),INDEX($C:$C,MATCH($A1,$D:$D,0),0),"")
または
B1=IF(ESERROR(MATCH($A1,$D:$D,0)),"",INDEX($C:$C,MATCH($A1,$D:$D,0),0))

Qエクセル【A列とB列の不一致を知りたいです】

初めまして。
お忙しい中、大変申し訳ございませんが、下記に関して、ご指導のほど、宜しくお願い致します。

***************
【例】
A列    B列

あめ    チョコ
ガム    ポテトチップス
チョコ   あめ
       ガム


という列があり、A列はA1000まで続き、B列はB3000まで続きます。
必ずしも、A列の横に同じお菓子名があるわけではありません。

そこで、A列とB列を比較し、B列にしかないもの(上記「例」ではポテトチップス)のセルに色づけ、もしくはC列に、不一致するものだけ「NG」等が記載される数式を教えてください。

お忙しい中、大変申し訳ございませんが、
何卒宜しくお願い申し上げます。

Aベストアンサー

条件付書式で、B列のセルに
「数式が」
=ISERROR(VLOOKUP(B1,A:A,1,FALSE))
で書式を設定し下にコピーすると、無いものだけが書式変更されます。

同じように、B列の隣のC列に
=IF(ISERROR(VLOOKUP(B1,A:A,1,FALSE)),"NG","")
として下にコピーしても隣にNGと表示できます。

QA列の文字列からB列の文字列を

A列の文字列からB列の文字列を
引く(マイナス)することはできないでしょうか?

例)

A列 - B列 - C列
ABCD - CD - AB
ABCD - BCD - A
ABCD - GH - ABCD

という風にC列に関数で結果を表示したいのです。
方法はないでしょうか?

よろしくお願いします。

Aベストアンサー

2行目以降に文字列が入っていると仮定しますと、C2に

=SUBSTITUTE(A2,B2,"")

という式を入力して下へコピーしてみてください。

ご参考までに、SUBSTITUTE(文字列1,文字列2,文字列3)は文字列1に含まれている文字列2の部分だけを文字列3に置き換える関数です。

Qエクセルで、条件に一致した行を別のセルに抜き出す方法

エクセルで、指定した条件に一致するセルを含む行をすべて抜き出す方法が知りたいです。

たとえば、

<A列> <B列> <C列>
7/1 りんご 100円
7/2 ぶどう 200円
7/2 すいか 300円
7/3 みかん 100円

このような表があって、100円を含む行をそのままの形で、
別のセル(同じシート内)に抜き出したいのですが。

7/1 りんご 100円
7/3 みかん 100円

抽出するだけならオートフィルターでもできますが、
抽出結果を自動的に、別の場所に、常に表示させておきたいのです。

初歩的な質問だと思いますが、検索しても分からなかったので、よろしくお願いします。

Aベストアンサー

同じ質問が結構よく出てますが、そんなに初歩的でもありません
別シートのA1セルに「100円」と入力し、そのシートの任意のセルに以下の式を貼り付けて下さい。後は、下方向、右方向にコピー。
日付のセル書式は「日付」形式に再設定してください

=IF(COUNTIF(Sheet1!$C:$C,$A$1)>=ROW(A1),INDEX(Sheet1!A:A,LARGE(INDEX((Sheet1!$C$1:$C$500=$A$1)*ROW(Sheet1!$C$1:$C$500),),COUNTIF(Sheet1!$C:$C,$A$1)-ROW(A1)+1)),"")

データ範囲は500行までとしていますが、必要に応じて変更して下さい

QEXCELでA列とB列の文字が合わせてC列に入るやり方を教えて欲しいで

EXCELでA列とB列の文字が合わせてC列に入るやり方を教えて欲しいです。

A1セルは04+  B1セルは2000 C列に04+ 2000のように作りたいです(真ん中に1個スペース)。
セルが多すぎて、一個ずつやるのは大変時間かかりますので、関数のやり方をご教示ください。
よろしくお願いします。

Aベストアンサー

C1に
=A1&" "&B1

QExcelの結合でA列とB列の内容を結合したいのですが

A列とB列を結合しますと、B列のデータがなくなってしまい、A列のデータのみとなってしまいますが
具合の良い方法ありますでしょうか。
行数が沢山あるものですから。

例:
A列に東京都中央区銀座
B列に8-5-6 ××ビル5階
これを結合して
東京都中央区銀座8-5-6 ××ビル5階
にしたいのです。

初心者です宜しくお願い致します。

Aベストアンサー

こんにちは。

表示させたいセルの数式バーに、結合させたいセルを"&"でつなげて入力すると、内容も結合されます。

例: =A1&B1

補足ですが、A1とB1を選択して、「セル結合」ボタンを使ったり、「書式」→「セル」→「配置」の「セルを結合する」にチェックを入れた場合は、A1の内容のみ保持されます。

Qエクセルで重複しているデータの抽出のしかたを教えてください。

エクセルで重複しているデータを抽出したいのですが・・。なにぶん初心者なもので簡単な方法があればよいのですが・・。
A列に日付 B列に企業名このデータが300件ほどあります。

 Å列      B列
1月 1日    AAAA社
1月 4日   BBBB社
1月 8日   CCCC社
2月 1日   BBBB社
2月20日    DDDD社
3月 2日   AAAA社

と、あるとしてB列の企業名が重複しているものを抽出したいのですが・・・。この場合 AAAA社とBBBB社ですが。
これを簡単に抽出する方法はないでしょうか?
教えてください お願いいたします。

Aベストアンサー

企業名がセルB2からセルB300まで入力されていると仮定します。
セルC2に IF(COUNTIF($B$2:B2,B2)>1,"*","") を入力し、セルC300までコピーして下さい。すると重複したデータの二番目以降に "*" のマークが付きます。
(注) 数式を下のセルまでコピーするため、COUNTIF($B$2 は絶対参照にして下さい。

QエクセルでA列とB列の差分を抽出

エクセルでA列にはあるがB列にはない項目を抽出するにはどうしたらよいでしょうか。
下の例だと、C列あたりに、山本、川田を抽出したいのですが……
A列にはB列のデータがすべて含まれています。
A列は10月と11月のデータで、B列は10月のデータです。

A列   B列
山田  山田
山本  川上
川田
川上

Aベストアンサー

色々な方法がありますが、COUNTIF関数とIF関数で、一致するものしないものが選択できそうですね。
データがA1:A4、B1:B2にあるとします。
C列に
=IF(COUNTIF($B$1:$B$2,A1)=0,A1,"")
と入力すれば、A1の値がB列の範囲内になければ、A1を表示、ない場合には何も表示しません。
ご確認下さい。


このカテゴリの人気Q&Aランキング