エクセルで西暦→和歴→数字のピックアップ（関数？）

エクセルで西暦→和歴→数字のピックアップができますか？

例えば
1974/04/03（または1974/4/3)
↓
昭和49年４月３日
↓
一文字づつ分けて、それぞれ一つのセルに１文字
「４」「９」「０（またはスペース）」「４」「０（またはスペース」「３」

と変換することはできますか？

それらの数字を、別のシートにリンクさせて使いたいのです・・。

かなり困っています。
教えていただけると助かりますいｍ（＿＿）ｍ

No.7 ベストアンサー 回答者： tom04 回答日時： 2011/04/01 21:36

No.6です！

たびたびごめんなさい。

投稿した後で気づいたのですが、前回の方法はNo.2の　mu2011さんとほとんど同様の方法でした。
確認せずに投稿してごめんなさいね。

余計なお世話かもしれませんが、
前回のSheet1のB列は必要なくて、
Sheet2のA2セルに
=IF(Sheet1!$A2="","",MID(TEXT(Sheet1!$A2,"emmdd"),COLUMN(A1),1))
として列・行方向にオートフィルで大丈夫だと思います。

何度も失礼しました。m(__)m

この回答へのお礼

お礼が大変遅くなり申しわけありませんｍ（＿＿）ｍ
何度もご回答ありがとうございました。
大変わかりやすく、参考になりましたｍ（＿＿）ｍ

お礼日時：2011/09/23 21:13

No.6 回答者： tom04 回答日時： 2011/04/01 21:27

こんばんは！

一例です。
↓の画像のようにSheet1に1列作業用の列を設けています。

Sheet1のB2セルに
=IF(A2="","",TEXT(A2,"emmdd"))
という数式を入れ、オートフィルでずぃ～～～！っと下へコピーしておきます。

そして、Sheet2のA2セルに
=MID(Sheet1!$B2,COLUMN(A1),1)
という数式を入れ、列方向と行方向にオートフィルでコピーすると
画像のような感じになります。

参考になれば良いのですが・・・m(__)m

No.5 回答者： kagakusuki 回答日時： 2011/04/01 18:34

　今仮に、元の（西暦の）日付がSheet1のA1セルに入力されているものとします。

　和暦に関しては、リンク先のセルに、

=Sheet1!A1

と入力した上で、そのセルの書式設定を[日付]の

平成13年3月14日

とするだけで良いと思います。

●和暦の10の位を表示する関数

=LEFT(TEXT(A1,"ee"),1)*1


●和暦の1の位を表示する関数

=RIGHT(TEXT(A1,"ee"),1)*1


●月の10の位を表示する関数

=INT(MONTH(A1)/10)


●月の1の位を表示する関数

=MOD(MONTH(A1),10)


●日の10の位を表示する関数

=INT(DAY(A1)/10)


●日の1の位を表示する関数

=MOD(DAY(A1),10)

この回答へのお礼

お礼が遅くなり申し訳ございませんｍ（＿＿）ｍ
とてもわかりやすい説明ありがとうございました。
たくさん方法があるのですね。
とても参考になりましたｍ（＿＿）ｍ

お礼日時：2011/09/23 21:12

No.4 回答者： imogasi 回答日時： 2011/04/01 10:09

>1974/04/03　日付シリアル値＋日付表示形式でそうなっているとする（文字列でないとするということ。

本当は質問にはっきり注釈しておくべき。日付シリアル値のことは知ってるでしょうね）
これは和暦で昭和なのだが年号文字は省くのだね。それを明記しておくべき。
Ｂ１セルに
=TEXT(A1,"eemmdd")で490403
あえて桁数をそろえて扱いやすいようにmmやddにする。
Ｃ１セルに=MID($B1,COLUMN()-2,1)　と入れてＨ列まで式を複写
Ｃ１：Ｈ１に　490403
これで良いのかな。
数字化するなら＊１（１をかける）
=MID($B1,COLUMN()-2,1)*1
０を空白にするなら
=IF(MID($B1,COLUMN()-2,1)="0","",MID($B1,COLUMN()-2,1))
他シートから参照は=Sheet1!番地

この回答へのお礼

お礼が遅くなり申しわけございませんｍ（＿＿）ｍ
エクセル超初心者なので（＞＜；）
いろいろな方法があるのですね・・。
ご回答、ありがとうございましたｍ（＿＿）ｍ

お礼日時：2011/09/23 21:09

No.3 回答者： mike_g 回答日時： 2011/04/01 09:57

添付図参照

D1: =MID(TEXT(A1,"geemmdd"),2,2)+0
F1: =MID(TEXT(A1,"geemmdd"),4,2)+0
H1: =MID(TEXT(A1,"geemmdd"),6,2)+0

この回答へのお礼

お礼が遅くなり申し訳ありませんｍ（＿＿）ｍ
いろいろな方法があるのですね・・。
エクセルは難しいです（＞＜）
ご回答ありがとうございましたｍ（＿＿）ｍ

お礼日時：2011/09/23 21:07

No.2 回答者： mu2011 回答日時： 2011/04/01 09:55

一例です。

■和暦変換　仮に日付入力セルがSheet1のA1、任意セルに=Sheet1!A1を入力、セルの書式設定で表示形式をユーザ定義でggge"年"m"月"d"日"

■一文字抽出　任意セルに=MID(TEXT(Sheet1!$A$1,"emmdd"),COLUMN(A1),1)に設定、右方向にコピー

No.1 回答者： edomin7777 回答日時： 2011/04/01 06:58

西暦が入っているセルをA1とすると、

A1
1974/04/03
和暦
=TEXT(A1,"gggee年mm月dd日")
年号の10の位
=LEFT(TEXT(A1,"ee"),1)
年号の1の位
=RIGHT(TEXT(A1,"ee"),1)
月数の10の位
=LEFT(TEXT(A1,"mm"),1)
月数の1の位
=RIGHT(TEXT(A1,"mm"),1)
日数の10の位
=LEFT(TEXT(A1,"dd"),1)
日数の1の位
=RIGHT(TEXT(A1,"dd"),1)

で取り出せます。
後は、「A1」を別のシートから参照したセルに置き換えるだけです。