データの整合性のエクセル関数教えてください！

例えばシート１が
Ａ列　　　　　Ｂ列　　　Ｃ列
123さん　12番　　1番
345さん　13番　　2番
678さん　14番　　3番

シート２は

Ａ列　　　　Ｂ列　　　　Ｃ列　　　　Ｄ列　　
345さん　　Ａ　　　13番　　　3番　　　
123さん　　Ｂ　　　12番　　　1番　　　
678さん　　Ｃ　　　14番　　　3番　　　

という表があった場合にシート１の123さんのＢ列とＣ列が
シート２の123のＣ列とＤ列の番号と一致しているかどうか
をＥ列に●×で表示させたい時はどのような関数を使え
ばいいのでしょうか？ちなみにシート１とシート２は順番も
項目も違う内容になっています。
ＶＬＯＯＫとＩＦを組み合わせたりしたのですが、どうしも
うまくいかず困っています。
どなたかおわかりでしたら教えてください。

No.2 ベストアンサー 回答者： MackyNo1 回答日時： 2011/11/12 21:53

たとえばSheet2のE2セルに以下の数式を入力します。

=IF(AND(VLOOKUP(A2,Sheet1!$A:$C,2,0)=C2,VLOOKUP(A2,Sheet1!$A:$C,3,0)=D2),"○","×")

この回答へのお礼

ご回答ありがとうございました。
できました！

お礼日時：2011/11/14 21:17

No.5 回答者： imogasi 回答日時： 2011/11/13 10:37

こんなのは、VLOOKUP関数を使うしかない。

VLOOKUP関数など、多少エクセル関数をやったものにはエクセルの常識。
Googleで「エクセル　関数　VLOOKUP」で照会して読んで見たら。第４引数はFALSE型だ。膨大な記事があり、このコーナーでも、２シート比較も含めて、FAQだ。
ただしVLOOKUPはデータの存在する行のデータは取れるが、行そのものは捉えない・使わないので、MATCH関数を使う手もある。
そして123さんが２度出てくる場合は、使えない。これを書いてないのは経験不足の人。
他シートのセル範囲を指定するのでSheet2!$A$1:$D$100のような書き方が出て来るだけ。
ーー
但し、
（１）AにあってBにもある
（２）AにあってBにはない
（３）Aに無くてBには在る
の（３）がA側では検出しようがない。
だからB側からのVLOOKUP関数の検索も行い併用する必要があると思う。
＞ＶＬＯＯＫとＩＦを組み合わせたりしたのですが、どうしも
うまくいかず困っています。
うまく行かないのはどの点か、書いて、質問の論点を絞ること。
ここを文章ででも書けるようになってこそ勉強した人。
比較は、一方はB列セル、一方はVLOOKUPの第３引数で指定する列（例C列）になるだけ。
ーー
関数以外でVBAでやるのが良い課題だが。

この回答へのお礼

勉強不足で申し訳ありません。
回答ありがとうございました。

お礼日時：2011/11/14 21:08

No.4 回答者： KURUMITO 回答日時： 2011/11/13 06:52

データが多くなっても計算が重くならずに分かり易い方法は作業列を作って対応する方法です。

シート1のD1セルには次の式を入力して下方にオートフィルドラッグします。

=IF(A1="","",A1&"/"&B1&"/"C1

シート2のE1セルには次の式を入力して下方にオートフィルドラッグします。

=IF(A1="","",IF(COUNTIF(Sheet1!D:D,A1&"/"&C1&"/"&D1),"●","×"))

この回答へのお礼

ご回答ありがとうございました。

お礼日時：2011/11/14 21:19

No.3 回答者： keithin 回答日時： 2011/11/12 22:02

簡易版で

Ｅ１に
=IF(SUMPRODUCT(VLOOKUP(A1,Sheet1!A:C,{2,3},FALSE)-C1:D1),"×","○")
とします。

この回答へのお礼

ご回答ありがとうございました。

お礼日時：2011/11/14 21:13

No.1 回答者： CoalTar 回答日時： 2011/11/12 21:51

半分遊びで(というか酔っぱらいなので)

Sheet2!E1セルに
=AND(INDEX(Sheet1!B:C,MATCH(Sheet2!A1,Sheet1!A:A,0),)=C1:D1)
[Ctrl]+[Shift] ＋[Enter] で確定、配列数式です({}で囲まれる)

この回答へのお礼

ご回答ありがとうございます。

お礼日時：2011/11/14 21:14