EXCELで複数シートの各A列を集計シートに横並びに表示したい。

EXCELの複数シートのA列を集計シートに並べて表示したいのですが簡単に設定できる方法はありますか？

例)
集計シートのA列にシート1のA列
集計シートのB列にシート2のA列
集計シートのC列にシート3のA列...
といった感じです。

集計シートに設定する式もしくは何か機能があれば教えてください。

No.4 ベストアンサー 回答者： noname#9284 回答日時： 2004/03/05 14:59

挿入→名前→定義で

名前　　　　　name と入力
参照範囲　　　=GET.WORKBOOK(1)　　と入力

集計シートのA1に
=MID(INDEX(name,COLUMN()),FIND("]",INDEX(name,COLUMN()))+1,31)
と入力してこれを右にコピーしますと自動的にシート名が並びます。
お試し下さい。

この回答へのお礼

何度もありがとうございます。
おかげさまで解決できそうです。
かなり手間が省けそうです。
ありがとうございました。

お礼日時：2004/03/05 16:16

No.3 回答者： noname#9284 回答日時： 2004/03/05 13:08

> シート数が多いのでこの方法でリンク先をコピーなどで設定することはできますか？

シート名をA1から右に東京、大阪・・・と入力しておきます。
A2に
=INDIRECT(A$1&"!A"&ROW()-1)　と入力し、
これをコピーしてはいかがでしょうか。

また、シート名ですが、あまりにも多ければ関数を使って全部表示させる事もできますが、
必要でしたら補足をお願いいたします。

No.2 回答者： maruru01 回答日時： 2004/03/05 10:50

こんにちは。

maruru01です。

シート名に一定の規則があれば、横へもコピーで出来ます。
例えば、シート名が「1月」「2月」「3月」・・・という風になっていれば、集計シートのA1に、

=INDIRECT("'" & COLUMN() & "月'!A" & ROW())

と入力して、右へ下へコピーします。
なお、各シートの参照するセルが未入力の場合は、「0」と表示されてしまいます。
これを回避するには、数式を、

=IF(LEN(INDIRECT("'" & COLUMN() & "月'!A" & ROW())),INDIRECT("'" & COLUMN() & "月'!A" & ROW()),"")

にして、右へ下へコピーして下さい。

この回答への補足

回答ありがとうございます。
残念ながらシート名はばらばらです。
(東京、大阪などの店舗名が入っています)
この方法は別の機会とかに使えそうですね。
参考になりました。
今回については地道にやったほうが良いでしょうか？

補足日時：2004/03/05 12:46

No.1 回答者： noname#9284 回答日時： 2004/03/05 10:27

簡単に、とのことですから、にシート1のA列を選択してコピー、

集計シートのA列を右クリックして「形式を選択して貼り付け」で「リンク貼り付け」をします。
この手順で次々リンク貼り付けしていきます。

違う事をイメージされていましたら補足をお願いいたします。

この回答への補足

回答ありがとうございます。
この方法ですと1シートずつコピーするのとあまり手間が変わらないですよね？
シート数が多いのでこの方法でリンク先をコピーなどで設定することはできますか？
今回は特にシート1以降のデータの変更はないので値コピーでもOKです。
宜しくお願いいたします。

補足日時：2004/03/05 12:41