エクセル関数で千の位とかの数値を取得するには？

算用数字を、セルに入力して、
その金額の、一の位、十の位
百の位…のそれぞれの数値を個別に取得することが出来る関数はありますか？

No.6 回答者： MarcoRossiItaly 回答日時： 2013/03/31 21:55

LEFT、MID、RIGHT 関数で取り出した数は文字列となります。

文字列ですが、「*1」などと四則演算などの計算をすれば、すぐに数値に変化します。

始めから数値として求めるためには、上の関数を使った数式に「*1」などを混ぜるか、次のような別の関数を用います。

=mod(int(a1/10^3),10)
あるいは
=int(mod(a1/10^3,10))
あるいは
=int(mod(a1,10^4)/10^3)

※いずれも 1000 の位を抜き出す場合

この回答への補足

ご回答頂いた皆様にお尋ねしますが、
伝票の最後に「￥」をつけないとならないのですが、
自動的に、最上桁の次のセルが「自分」だと判断して、
自動的に、次のセルだけが、「￥」を表示させるようにする式を作成することは可能でしょうか？

これが大変難しいと思うのですが・・・不可能かも？？？

補足日時：2013/04/10 23:01

この回答へのお礼

まったく新しい関数が出てきて驚いております。
エクセルで作成した銀行用伝票に１桁ずつ入れたいので、
どれが一番適しているか試してみます。
どうも早々に感謝です。
お礼が遅くなって済みません。
有難うございました。
参考にさせて頂きます。

お礼日時：2013/04/10 22:49

No.5 回答者： KURUMITO 回答日時： 2013/03/31 16:33

A2セルに数値が入力されているとしてB２セルには1の位、C２セルには10の位、D２セルには100の位・・・・と横に表示させるとしたらB2セルには次の式を入力して右横方向にドラッグコピーします。

=IF(COLUMN(A2)>LEN($A2),"",INT(MOD($A2/10^(COLUMN(A2)-1),10)))

勿論、例えば100の位の数値を求めるのでしたら次の式で良いでしょう。

=INT(MOD($A2/100,10))

この回答へのお礼

なるほど。
とにかく、式を入れて一度試してみます。

お礼が遅くなって済みません。
有難うございました。
参考にさせて頂きます。

お礼日時：2013/04/10 22:48

No.4 回答者： mike_g 回答日時： 2013/03/30 20:43

添付図参照

B2: =LEN(A2)
C2: =IF(COLUMN(A2)<MAX($B:$B)-$B2+1,"",MID($A2,COLUMN(A2)-MAX($B:$B)+$B2,1))

この回答へのお礼

難しそうですが、かなり図式もあり、
理解できています。
取り敢えず、自分でやってみますね。

お礼が遅くなって済みません。
有難うございました。

お礼日時：2013/04/10 22:46

No.3 回答者： JazzCorp 回答日時： 2013/03/30 14:22

Ａ列：問題の数値データ

１行目：B1～に位を表す数値（10のべき乗：例えば、10000、1000、100、10、1）
２行目：お答え
Ｂ２：
=RIGHT(INT($A$2/B$1),1)
Ｂ２は右方向にコピー
Ａ列のデータの数に合わせて、まとめて下右方向にもコピー

この回答へのお礼

どうも早々に感謝です。
お礼が遅くなって済みません。
有難うございました。
参考にさせて頂きます。

お礼日時：2013/04/10 22:44

No.2 回答者： shintaro-2 回答日時： 2013/03/30 14:11

＃１さんの方法が素直ですが、

いろいろなやり方があって、

A1に数値があるとしたら、
　1の桁は、right(a1,1)
　10の桁は、right(int(a1/10),1)
　100の桁は、right(int(a1/100),1)
　としても可能です。

この回答へのお礼

どうも早々に感謝です。
お礼が遅くなって済みません。
有難うございました。
参考にさせて頂きます。

取り敢えず、いろいろご回答者様の方法を
試してみます。

お礼日時：2013/04/10 22:44

No.1 回答者： keithin 回答日時： 2013/03/30 12:58

Ａ１セルにとりあえず最大１０ケタの整数（小数点以下が無い数字）を記入することにして

＞数値を個別に取得することが出来る関数

どういう具合に表示したいのか不明なので、とりあえずＢ１セルから右に１０ケタ分「右詰」で数字を並べることにして

Ｂ１に
=MID(TEXT(A$1,"0000000000"),COLUMN(A1),1)*1
と記入して右にコピー

または
=MID(TEXT(A$1,"??????????"),COLUMN(A1),1)
と記入して右にコピー

この回答へのお礼

どうも早々に感謝です。
お礼が遅くなって済みません。
有難うございました。
参考にさせて頂きます。

お礼日時：2013/04/10 22:43