エクセル 2番目 3番目など 大きい数字 の順

こんばんは、エクセル2010を使っています。

画像のようなデータがあり、Bセルに数字が並んでいます。

そのBセルの数字の一番大きい数は、MAX関数　LARGE関数などで求められますが、D3、D4、D5セルのように、８の次に大きい値を調べるにはどうしたら良いでしょうか？

ちなみに、Bセルの数値は参照により毎回変わりますので、それに対応できる方法が希望です。

詳しい方、よろしくお願いいたします。

質問者からの補足コメント

• 

  いえ、そうではありません。

  No.1の回答に寄せられた補足コメントです。 補足日時：2015/12/16 20:16

No.6 ベストアンサー 回答者： CoalTar 回答日時： 2015/12/17 14:51

EXCELの前に戻ってきたので、再度

D2セルに=MAX(B:B)
D3セルに
=IF(OR(D2="",MIN(B:B)=D2),"",LARGE(B:B,COUNTIF(B:B,">="&D2)+1))
下へオートフィル

この回答へのお礼

回答ありがとうございます。

関数の組み合わせでいろいろ出来るんですね、助かりました。

ありがとうございました。

お礼日時：2015/12/19 15:49

No.5 回答者： CoalTar 回答日時： 2015/12/17 06:48

最大値は関数でmax

large(対象範囲,countif(対象範囲,">="&ひとつ上のセル)+1)
ひとつ上のセルの数値以上の個数+1番目に大きな数値
未検証

No.4 回答者： mmmma 回答日時： 2015/12/16 21:51

＃１です。

先の回答だと、=LARGE(B:B,2)も、=LARGE(B:B,3)も「８」になっちゃうんですね。
すいません。

ということで、1列挿入して表示のために重複を削除するのはいかがですか？

C列に1列挿入して、C2のセルには、
=IF(COUNTIF(B$2:B2,B2)>1,0,B2)
を入力して、下へオートフィルでコピーしちゃいます。

とすると、C11のセルは=IF(COUNTIF(B$2:B11,B11)>1,0,B11)
になります。

意味は、B2のセルからB11のセルまでの間で、B11のセルと同じ値のセルの数を数えて、それが1を超えれば、C11のセルは0、1であればC11はB11と同じ、ということです。
これで、上から順番に見ていって重複する数字があれば0になりますので、=LARGE(C:C,2)は6、=LARGE(C:C,3)は4と表示されます。

この回答へのお礼

再度の回答ありがとうございます。

お陰様で出来ました、ありがとうございます！

お礼日時：2015/12/19 15:48

No.3 回答者： googoo900 回答日時： 2015/12/16 21:47

＜手順＞

１．A列を作業用にします。（A列でなくてもよいですが、データ列の隣の列が便利です⇒カーソルをセル右下角にあわせてダブルクリックで最下行までコピペできます）
２．A2セルに　=SMALL(B:B,ROW()-1)　を入力して、データ最下行までコピペします。
３．D2セルに　=LARGE(B:B,1)　を入力します。
４．D3セルに　=VLOOKUP(D2-(1e-15),A:A,1,TRUE)　を入力して、D4～D5セルにコピペします。(必要に応じてさらに下まで)

この回答へのお礼

回答ありがとうございます。

お陰様で、ばっちり出来ました。

お礼日時：2015/12/19 15:47

No.2 回答者： tom04 回答日時： 2015/12/16 20:39

こんばんは！

安直な方法ですが、

まずD2セルに
=IF(COUNT(B:B),MAX(B:B),"")
という数式を入れておきます。

そしてD3セルに
=IF(COUNTIF(B:B,"<"&D2),MAX(IF(B$1:B$1000<D2,B$1:B$1000)),"")
これは配列数式ですので
Ctrl＋Shift＋Enterで確定！
D3セルのフィルハンドルで下へコピー！

こんな感じではどうでしょうか？m(_ _)m

この回答へのお礼

回答ありがとうございます。

お陰様で、ばっちり出来ました。

お礼日時：2015/12/19 15:47

No.1 回答者： mmmma 回答日時： 2015/12/16 19:51

=LARGE(B:B,2)

これでB列の2番目に大きい数字が表示されます。

3番目に大きいのなら
=LARGE(B:B,3)
です。