【エクセル 顧客管理】 顧客の2回目の購入月の抽出

エクセルで顧客管理を行なっております。
各顧客の初回購入月、2回目の購入月、最終購入月を抽出できないか、質問させて頂きました。

以下のような表の中から、初回購入月をI欄に、2回目をＪ欄に、最終購入月をＫ欄に抽出したいと思います。

　A　　　　B　　　C　　　D　　　E　　　F　　　G　　　H　　　I　　　　J　　　　K
顧客NO　（1月)　(2月)　(3月)　(4月)　(5月)　(6月)　　合計　初回　　2回目　　　最終
a001　　　1000　2000　3000　　　　　　　　　　　　6000
a002　　　5000　　　　6000　7000　　　　　　　　　18000
a003　　　7500　　　　8500　9500　10000　　　　　35500


できれば関数だけを使って管理できればと思っております。どうぞ宜しくお願い致します。

No.1 ベストアンサー 回答者： tom04 回答日時： 2017/08/25 21:54

こんばんは！

お示しの配置通りだとするとI2セルに
=IFERROR(INDEX($B$1:$G$1,SMALL(IF($B2:$G2<>"",COLUMN($B$1:$G$1)-1),COLUMN(A1))),"")

配列数式なのでCtrl＋Shift＋Enterで確定！　→　I2セルのフィルハンドルで隣りのJ2セルまでフィル＆コピー！

K2セルの数式は別の数式になります。
=IF(COUNT(B2:G2),INDEX(B$1:G$1,MAX(IF(B2:G2<>"",COLUMN(B$1:G$1)-1))),"")

こちらも配列数式なので、同様にCtrl＋Shift＋Enterで確定！

最後にI2～K2セルを範囲指定　→　K2セルのフィルハンドルで下へコピーしてみてください。m(_ _)m

この回答へのお礼

おおーー！できました、ありがとうございました！

早速にご回答ありがとうございます！！

お礼日時：2017/08/25 23:34

No.3 回答者： mike_g 回答日時： 2017/08/26 01:01

[No.2]で、「式を簡単化するため」と言いながら、式を簡単にすることを失念していました。

ステップ３の式を次のように修正しておきます。
=SMALL(IF($B2:$G2>0,$B$1:$F$1,""),I$1)

この回答へのお礼

ありがとうございます！
式が簡単でびっくりしました！

お礼日時：2017/08/26 17:35

No.2 回答者： mike_g 回答日時： 2017/08/26 00:47

添付図参照

１．範囲 B1:G1 および I1:K4 の書式を G/標準"月" に
￣￣範囲 I1、J1 の書式を G/標準"回目" に、それぞれ設定
２．セル B1 から右に数値 1、2、3、…、6 を、
￣￣セル I1、J1 に数値 1、2 を、それぞれ入力
以上は次に入力する式を簡単化するための下準備です。
３．式 =SMALL(IF($B2:$G2>0,$B$1:$F$1,""),COLUMN(A1)) を
￣￣入力したセル I1 を右隣にオートフィル
４．セル K1 に式 =MAX(IF($B2:$G2>0,$B$1:$F$1,"")) を入力
５．範囲 I1:K1 を下方にオートフィル
【お断り】上式は何れも、必ず、配列数式として入力のこと