文字の切り出しのことで教えてください

お願いします。
エクセル2003です。下記のようなデータが入ったセルがあります。　
　Ａ列
21-1080無鉛タンク　　　　　　
03-0054ムエンN-9.5ホワイト　　
03-649ムエンパントーン2C
3-133チャコールグレー
　　↓
　Ｂ列
無鉛タンク
ムエンN-9.5ホワイト　
ムエンパントーン2C 　 　　　　　
チャコールグレー
このようにＡ列の数字の後からＢ列に切り出したいのですが数字の
数がランダムでうまい関数が浮かびません、どなたか教えていただ
けますか？
よろしくお願いしたします。

No.1 ベストアンサー 回答者： maron--5 回答日時： 2009/11/30 15:02

B1=REPLACE(A1,1,MIN(INDEX((CODE(MID(A1&REPT(" ",20),ROW($1:$20),1))<100)*1000+ROW($1:$20),))-1,)

★下にコピー

この回答へのお礼

早速のご回答有難うございました。
希望通りにいきました。
”REPLACE”関数使った事が無かったので参考になりました。

お礼日時：2009/11/30 17:24

No.4 回答者： KURUMITO 回答日時： 2009/11/30 16:29

ーの後の数字が2個から5個までのデータでしたら次のような式をＢ1セルに入力して下方にオートフィルドラッグします。

=IF(ISNUMBER(MID(A1,FIND("-",A1)+5,1)*1),MID(A1,FIND("-",A1)+6,20),IF(ISNUMBER(MID(A1,FIND("-",A1)+4,1)*1),MID(A1,FIND("-",A1)+5,20),IF(ISNUMBER(MID(A1,FIND("-",A1)+3,1)*1),MID(A1,FIND("-",A1)+4,20),IF(ISNUMBER(MID(A1,FIND("-",A1)+2,1)*1),MID(A1,FIND("-",A1)+3,20),""))))

この回答へのお礼

ご回答ありがとうございました。
長い関数式を造っていただきありがとうございました。
ハイフンがポイントで造っていただき今後の参考にさせていただきます。

お礼日時：2009/11/30 17:44

No.3 回答者： mike_g 回答日時： 2009/11/30 16:17

[回答番号：No.2]の４行目を次のとおりに訂正します。

　　　　　　　 A　　　　　　　　　　　　 B　　　　　　 C
4　03-649ムエンパントーン2C　　ムエンパントーン2C　 03-649

No.2 回答者： mike_g 回答日時： 2009/11/30 16:03

　　　　　　　 A　　　　　　　　　　　　 B　　　　　　 C

1　Original_Strings　　　　　　Strings　　　　　　　Numerals
2　21-1080無鉛タンク　　　　　 無鉛タンク　　　　　 21-1080
3　03-0054ムエンN-9.5ホワイト　ムエンN-9.5ホワイト　03-0054
4　03-649ムエンパントーン2C　　ムエンパントーン　　 2C03-649
5　3-133チャコールグレー　　　 チャコールグレー　　 3-133

C2: {=LEFT(A2,MATCH(TRUE,(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1))>="A",0)-1)}
　　(配列数式)

B2: =SUBSTITUTE(A2,C2,"")

この回答へのお礼

ご回答ありがとうございました。
う～ん自分には難しかったですが、勉強させていただきます。

お礼日時：2009/11/30 17:40