エクセルのマクロを2つご指南ください

１つ目：
・最終行はL列で判断
・開始行は12行目から
・T列が　0（若しくは0.000）　があった時
　同行のH列のセルを薄い灰色にして
　下揃え、右揃え　で　赤く kg と表示したいです。

2つ目：
・最終行はL列で判断
・開始行は12行目から
・上記H列の色を塗りつぶしなし、
　kgの表示を無くすマクロをご指南ください。

宜しくお願いいたします。

No.2 ベストアンサー 回答者： tatsumaru77 回答日時： 2023/01/02 17:30

添付画像の上のセルがマクロ実行前の状態です。

下のセルがマクロ実行後の状態です。
実行前、実行後の状態はこれであってますか。
赤いKgの付加は書式設定で行っています。

上記で良いなら、実行前の状態は既に右詰めになっているので、
右詰めにする必要はないかと思います。

この回答へのお礼

実行前、後。それぞれ合っています。
今、出先なので詳しくは分かりませんが
一度、お願い出来ますでしょうか？
宜しくお願いします。

お礼日時：2023/01/02 20:11

No.3 回答者： tatsumaru77 回答日時： 2023/01/02 21:25

以下のマクロを標準モジュールに設定してください。

Option Explicit

Public Sub KG設定()
Dim ws As Worksheet
Dim maxrow As Long
Dim wrow As Long
Set ws = ActiveSheet
maxrow = ws.Cells(Rows.Count, "L").End(xlUp).Row
If maxrow < 12 Then Exit Sub
For wrow = 12 To maxrow
If ws.Cells(wrow, "T").Value = 0 Then
ws.Cells(wrow, "H").NumberFormatLocal = "[赤]G/標準""Kg"""
ws.Cells(wrow, "H").VerticalAlignment = xlBottom
ws.Cells(wrow, "H").Interior.ThemeColor = xlThemeColorDark1
ws.Cells(wrow, "H").Interior.TintAndShade = -0.249977111117893
End If
Next
End Sub

Public Sub KG解除()
Dim ws As Worksheet
Dim maxrow As Long
Dim wrow As Long
Set ws = ActiveSheet
maxrow = ws.Cells(Rows.Count, "L").End(xlUp).Row
If maxrow < 12 Then Exit Sub
For wrow = 12 To maxrow
ws.Cells(wrow, "H").NumberFormatLocal = "G/標準"
ws.Cells(wrow, "H").VerticalAlignment = xlCenter
ws.Cells(wrow, "H").Interior.Pattern = xlNone
Next
End Sub

この回答へのお礼

思い通りの結果が得られました。
ありがとうございました。

お礼日時：2023/01/03 10:33

No.1 回答者： taglet 回答日時： 2023/01/02 12:25

条件付き書式でできるのではないかと思います。

https://www.crie.co.jp/chokotech/detail/269/

この回答へのお礼

ありがとうございます。
条件付き書式で出来るのは分かりますが
今回はマクロでの回答とさせていただきます。

お礼日時：2023/01/02 13:05