Excelで月間予定表を作成する方法

Excelで月間予定表を作成したいのですが、初心者でも分かるように詳しく作成の仕方を示してあるサイトをご存知ないでしょうか？

テンプレートとして配布してあるサイトもいろいろ探しては見たのですが、
なかなか自分好みのものが見つかりません。

縦型ではなく、横型カレンダーの形で年月を入力すると日付が自動で入るようなもの。
祝日等、自動で色付けが出来る。

更に予定が記入できるような余白部分があるものを作りたいのですが…

どなたかご存知でしたらお教え頂けないでしょうか？
よろしくお願い致します。

No.7 ベストアンサー 回答者： tom04 回答日時： 2013/08/15 21:50

No.5・6です。

＞土日、祝祭日のセルの塗りつぶしは書式設定で行ってますが
＞これも駆使すると自動で色が付いたりするものなのでしょうか？

の件に関してですが、
No.5で書いたように「条件付き書式」の設定で可能です。
前回のNo.6の場合ではオートフィルでコピーする前に
A5・A6セルの条件付き書式を設定しておきます。
Excel2007以降をお使いだとして・・・

A5セルを選択　→　条件付き書式　→　新しいルール　→　数式を使用して・・・　→　「次の数式を満たす場合に・・・」の数式欄に
=A6<>""
という数式を入れ　→　書式　→　フォントのスタイルで「赤」を選択しOK
同様にA6セルを選択　→　・・・中略・・・　→　数式欄に同じ数式
=A6<>""
を入れ　→　書式　→　フォントのスタイルで「赤」を選択しOK

以上の設定を行い、数式を入れた後にA5～A8セルを選択　→　A8セルのフィルハンドルでG列までコピー！
そのまま下へ4行ずつコピー！
これで祝日の日付と祝日名は「赤」が表示されます。

日・土の色は条件付き書式でも可能ですが、A列・G列と決まっているので
セルを選択　→　フォント色を指定！

こちらの方が簡単だと思います。

※　注意点　※　
日・土のフォント色の設定は必ず最後に行います。
日曜日のセルを右方向にオートフィルでコピーするようにしていますので、
最初に日のフォント色の「赤」を設定してしまうと、書式もコピーされてしまい、
すべての日付が「赤」となってしまいます。m（_ _）m

この回答へのお礼

追加の質問にも丁寧に、詳しく教えていただきありがとうございます。
満足のいくものが作れて大変感謝しております。
本当にありがとうございました。

お礼日時：2013/08/15 23:43

No.6 回答者： tom04 回答日時： 2013/08/15 17:57

No.5です。

（1）Excel2010はまた少し方法が違うのでしょうか？　について
この数式はExcelのバージョンは関係なくどのバージョンでもちゃんと表示されるはずです。
条件付き書式の操作方法が若干異なる程度で条件付き書式の数式欄はそのまま利用できます。

（2）『値の更新：sheet2』というBOXが出てきます。　について
この件に関しては同一Book内の別Sheetを参照している場合は通常表示されることはないと思うのですが、
前回「名前定義」したコトによるものかもしれませんので、今回は名前定義せずに数式を載せてみます。

（3）キャンセルをするとE5、F5、G5に何やら分からない数字が入力されています。
おそらくシリアル値が表示されているのだと思います。5桁数値で4万台の数値が表示されていないでしょうか？
前回書き忘れたのですが、
A5セル上で右クリック　→　セルの書式設定　→　表示形式　→　ユーザー定義　→　「G/標準」を消して
d　だけにしてください。

そうしたうえで前回の数式を入れますが、ご希望としては予定欄を2行・もしくは3行にしたい！というコトですので
↓の画像のような2行にした場合の数式です。
Sheet2の祝日の表は前回同様の配置だとします。
（今回は名前定義せずにそのままセルを範囲指定するようにしてみました）

A5セル（条件好き書式の方法は前回同様）に
=IF(MONTH($C$1-WEEKDAY($C$1)+COLUMN(A1)+7*(ROW(A4)/4-1))=$A$2,$C$1-WEEKDAY($C$1)+COLUMN(A1)+7*(ROW(A4)/4-1),"")

A6セル（条件付き書式は前回同様）に
=IF(OR(A5="",COUNTIF(Sheet2!$B$1:$E$21,A5)=0),"",INDEX(Sheet2!$A$1:$A$21,SUMPRODUCT((Sheet2!$B$1:$E$21=A5)*ROW($A$1:$A$21))))

という数式を入れA5～A8セルを範囲指定　→　A8セルのフィルハンドルでG列までコピー　→　そのまま4行ずつ下へコピー！

これで画像のような感じになります。

※　予定欄を3行にしたい場合はA5セルの数式を
=IF(MONTH($C$1-WEEKDAY($C$1)+COLUMN(A1)+7*(ROW(A5)/5-1))=$A$2,$C$1-WEEKDAY($C$1)+COLUMN(A1)+7*(ROW(A5)/5-1),"")

として5行ずつのコピーとします。m（_ _）m

この回答へのお礼

出来ました！！！＼(^o^)／
感動です！！
自分好みのものが出来ました。
tom04さん本当にありがとうございます。

出来上がった画像を貼りたかったのですが
貼り方が分かりませんでした(-_-;)

土日、祝祭日のセルの塗りつぶしは書式設定で行ってますが
これも駆使すると自動で色が付いたりするものなのでしょうか？

大した作業ではないので毎月ちょっと手を入れれば良いことなのですが
お暇な時に教えていただければ幸いです。

お礼日時：2013/08/15 19:46

No.5 回答者： tom04 回答日時： 2013/08/14 22:46

こんばんは！

色々なパターンのカレンダーが作成可能ですが、
オーソドックスな7列カレンダーを作成する方法の一例です。

↓の画像で説明します。Excel2007以降のバージョンだとします。
（画像がかなり小さいと思いますので、画面を拡大して確認してください）

左側がSheet2で祝日データを作成しておきます。
画像の配置でSheet2のB2～E21セルを範囲指定　→　名前ボックスに仮に　祝日　と入力しEnter
これでSheet2のB2～E21セルが「祝日」と名前定義されました。
以上の下準備ができた上で

Sheet1のA1セルに西暦年
A2セルに　月　の数値を
C1セルには
=DATE(A1,A2,1)
という数式を入れ、表示したい月の1日のシリアル値を表示しておきます。
（C1セルの表示形式やユーザー定義から　mmm　としています）

A5セルに
=IF(MONTH($C$1-WEEKDAY($C$1)+COLUMN(A1)+7*(ROW(A3)/3-1))=$A$2,$C$1-WEEKDAY($C$1)+COLUMN(A1)+7*(ROW(A3)/3-1),"")
という数式を入れ、A5セルの条件付き書式　→　新しルール　→　数式を使用して・・・　→　数式欄に
=A6<>""
という数式を入れ　→　書式　→　フォントの色を「赤」に設定しOK

A6セルに
=IF(OR(A5="",COUNTIF(祝日,A5)=0),"",INDEX(Sheet2!$A$1:$A$21,SUMPRODUCT((祝日=A5)*ROW($A$1:$A$21))))
という数式を入れ　→　条件付き書式　→　新しいルール　→　数式を使用して・・・　→　数式欄に
=A6<>""
としてこれもフォントの色を「赤」に設定しOK

A7（予定を入力するセル）はなにもしません。

最後にA5～A7セル（3行）を範囲指定　→　A7セルのフィルハンドルで土曜のG列までオートフィルでコピー
そのまま下へ3行ずつオートフィルでコピー！

最後に「日」の列のフォントの色を「赤」・「土」の列のフォントの色を「青」に設定し、
予定を入力する行を好みの高さに設定すると画像のような感じになります。

これでA1の西暦年やA2の月の数値を入れ替えるだけで1か月分のカレンダーが表示されます

※　Excel2003までのバージョンでもやり方は全く一緒ですが、
条件付き書式の進み方ら若干異なります。（条件付き書式の数式はそのまま）

参考になりますかね？m（_ _）m

この回答へのお礼

tom04さんありがとうございます。
私が作りたかったBOX型予定表です。
画像も付けてくださったのでとても分かりやすくて早速作成してみました。

名前の定義…初めて知り勉強になりました。

A6セルに数式を入れるところまでは出来ました。
A5～A7セルを範囲指定してG列までオートフィルコピーすると
『値の更新：sheet2』というBOXが出てきます。
キャンセルをするとE5、F5、G5に何やら分からない数字が入力されています。
どこをどう間違ったのか分かりません。
数式はコピペしたので大丈夫だと思うのですが…
Excel2010はまた少し方法が違うのでしょうか？
そこから先に進めず…です。

ちなみに予定を書き込む行は2行（A7・A8）、3行に出来るのでしょうか？
質問ばかりで申し訳ございません。

お礼日時：2013/08/15 17:01

No.4 回答者： hallo-2007 回答日時： 2013/08/14 21:06

一例です。

B2に　年（2007）
C２に　月（8）と入っているとします。
D1セルに
=IF(MONTH(DATE($B2,$C2,COLUMN()))=$C2,COLUMN(),"")
右へコピー
或いは
=IF(MONTH(DATE($B2,$C2,COLUMN()))=$C2,DATE($B2,$C2,COLUMN()),"")
表示形式を　d にして、右へコピー
してみてください。
C2（月）を変えると、その月に応じた日付が出ます。

次に、どこへ予定を表示させるかですが、
日付を全画面で表示させても、セル幅（横幅）がだいぶ狭くないですか？

No.3 回答者： maron--5 回答日時： 2013/08/14 18:28

◆参考にしてください

「EXCEL カレンダー（縦・横型）作成 いろいろ」
↓
http://note.chiebukuro.yahoo.co.jp/detail/n152074

No.2 回答者： tsubuyuki 回答日時： 2013/08/14 16:54

あなたの「好み」を忠実に再現するなら、

あなた自身で「作成する」のが一番手っ取り早い方法です。
回答する側は「一般的な作成方法」あるいは「回答者好みの作成方法」は解りますが、
「あなたの好み」はさっぱりわかりません。
唐突に
> 横型カレンダー
と言われても、お好みのレイアウトなどわかるはずもなく、
> 予定が記入できるような余白部分がある
と言われても、お好みの記述方法に沿う形もわかるはずもありません。
そんな中で
> なかなか自分好みのものが見つかりません。
と言われると、回答のしようがありません。
なので、「あなた自身のお好みのレイアウト」で作成するしかないのです。


「そんなこと言われても、初心者だから作れるはずねーだろ」
と居直られれて終わりでしょうが、とりあえず知っておくと便利なところだけいくつか。

> 年月を入力すると日付が自動で入る
ＤＡＴＥ関数が便利です。
「=DATE(年,月,日)」の形で、日付を返してくれますので、
例えば「年」をＡ１セル、「月」をＣ１セルに置き、
適当なセルに「=DATE(A1,C1,1)」と打ち込んでやると、指定の年月の１日を返してくれます。

このうち、「日」を判断させようと思ったら、ＲＯＷ関数、ＣＯＬＵＭＮ関数が便利に使えます。
例えば「=ROW(A1)」としてやると、Ａ１セルの「行番号」である「１」を返してくれます。
「=ROW(A2)」だと「２（行目）」を返してくれます。
ＤＡＴＥ関数と組み合わせて、例えばＡ１セルに「２０１３」、Ｃ１セルに「８」を置き、
適当なセルに「=DATE(A1,C1,ROW(A14)」と打ち込むと「2013/8/14」が返ってきます。

曜日を表示するには表示形式を「aaa」とします。
コレで、曜日の頭一文字（日～土）を表示してくれます。
ちなみに表示形式を「aaaa」とすると、「曜日」を付けて「日曜日～土曜日」で表示します。

曜日を色分けするには、条件付き書式を使います。
曜日を番号で返すＷＥＥＫＤＡＹ関数を併用して、
例えば日曜日を赤くしたいなら、条件に「=WEEKDAY(該当セル)=1」、書式を「文字色：赤」。
同様に土曜日を青くしたいなら、条件に「=WEEKDAY(該当セル)=7」、書式を「文字色：青」。
これを併記することで、曜日の色分けが可能です。

祝日を判断するには、別途「祝日一覧」を作成する必要があります。
これと条件付き書式・ＣＯＵＮＴＩＦ関数を併用して、祝日かどうかの判断をします。


コレだけ覚えておけば「万年カレンダー」は作成できます。
「初心者」だからこそ、わからない言葉は調べる癖をつけましょう。
「聞くな」とは言いませんが、聞いて回答を待つより調べた方が早いです。

http://www.eurus.dti.ne.jp/~yoneyama/Excel/jituy …
おそらく、この辺りがわかりやすいとは思います。

思いついたキーワードで検索をかけるとそれなりに見つかりますので、参考までに。
http://www.google.com/?hl=ja#bav=on.2,or.r_qf.&f …

この回答へのお礼

自分好み…分かりませんよね！
すみません。

なので自分好みを自分で作成しようと思い
レイアウトまでは作成したのですが
どこのセルにどの関数を入れれば良いのかさっぱり分からず
相談させていただきました。

いろいろサイトも見て少しは作成したのですが
要らないところまで日付が入ったり、分かりづらくて…

tsubuyukiさんが書いてくださっているものを
参考に少し勉強してみます。
ありがとうございます。

お礼日時：2013/08/14 18:19

No.1 回答者： hallo-2007 回答日時： 2013/08/14 15:03

＞縦型ではなく、横型カレンダーの形で年月を入力すると日付が自動で入るようなもの。

祝日等、自動で色付けが出来る。

どうしても横型でないといけない理由があるのでしょうか？
一般的には、縦方向に、万年カレンダー準備して、必要に応じて
その月分の表示にできるようにします。
これで、過去の予定も記録として残りますし、来月以降の予定も入力できます。

一案ですが
縦型で、日付の隣に予定を入力しておき
年月を入力するとその月の予定が表示されるようなもの。
祝日等、自動で色付けが出来る。

これで、基本となるシートを準備して、できない部分を再質問してみてください。
方法は、幾通りもあります。