EXCEL VBAで教えてください。データ変換:replace

こんばんは。
excel VBAでおしえてください。
シート１（data),シート２（名簿）があります。
シート２（名簿）に列Bに社員番号、列Cに氏名があります。
シート１のB列に社員番号のみが入っています。
シート１のB列の社員番号をシート２の名簿のB列の横にある氏名に変換したいのですがreplaceがいいかselect case がいいかわかりません。ご教示よろしくお願い致します。

No.3 ベストアンサー 回答者： tatsu99 回答日時： 2017/10/12 09:50

No2です。

先ほどのマクロに誤りがありました。前回のは破棄してください。
--------------------------------
Option Explicit
Public Sub 社員番号変換()
Dim sh1 As Worksheet
Dim sh2 As Worksheet
Dim dicT As Object
Dim maxrow1 As Long
Dim maxrow2 As Long
Dim okctr As Long
Dim ngctr As Long
Dim row As Long
Dim key As String
Set sh1 = Worksheets("data")
Set sh2 = Worksheets("名簿")
Set dicT = CreateObject("Scripting.Dictionary")
maxrow1 = sh1.Cells(Rows.Count, "B").End(xlUp).row
maxrow2 = sh2.Cells(Rows.Count, "B").End(xlUp).row
Application.ScreenUpdating = False

For row = 2 To maxrow2
key = sh2.Cells(row, "B").Value
dicT(key) = sh2.Cells(row, "C").Value
Next
okctr = 0
ngctr = 0
For row = 2 To maxrow1
key = sh1.Cells(row, "B").Value
If dicT.exists(key) = True Then
sh1.Cells(row, "B").Value = dicT(key)
okctr = okctr + 1
Else
ngctr = ngctr + 1
End If
Next
Application.ScreenUpdating = True
MsgBox ("処理件数=" & okctr & " 未処理件数=" & ngctr)
End Sub
----------------------------------

No.4 回答者： WindFaller 回答日時： 2017/10/12 12:16

Match関数を使ってみました。

'//標準モジュール
Sub FindNames()
　Dim sh1 As Worksheet: Set sh1 = Worksheets("名簿")
　Dim sh2 As Worksheet: Set sh2 = Worksheets("Data")
　Dim i As Variant
　Dim c As Variant
　Dim rngNumList As Range
　With sh1
　　'必ず、頭出しは、B1にしてください。
　　Set rngNumList = .Range("B1", .Cells(Rows.Count, 2).End(xlUp))
　End With
　Application.ScreenUpdating = False
　With sh2
　　'データがB2から始まっているなら、B2から
　　For Each c In .Range("B2", .Cells(Rows.Count, 2).End(xlUp))
　　　If c.Value <> "" Then
　　　　i = Application.Match(c.Value, rngNumList, False)
　　　　If IsNumeric(i) Then
　　　　　c.Value = sh1.Cells(i, 3).Value
　　　　End If
　　　End If
　　Next
　End With
　Application.ScreenUpdating = True
End Sub

この回答へのお礼

WindFallerさん、返信ありがとうございました。自分のPCでは少し時間がかかるみたいです。勉強になりました。感謝致します。

お礼日時：2017/10/12 21:00

No.2 回答者： tatsu99 回答日時： 2017/10/12 09:35

No1です。

以下のマクロを標準モジュールへ登録してください。
---------------------------------------
Option Explicit
Public Sub 社員番号変換()
Dim sh1 As Worksheet
Dim sh2 As Worksheet
Dim dicT As Object
Dim maxrow1 As Long
Dim maxrow2 As Long
Dim okctr As Long
Dim ngctr As Long
Dim row As Long
Dim key As String
Set sh1 = Worksheets("data")
Set sh2 = Worksheets("名簿")
Set dicT = CreateObject("Scripting.Dictionary")
maxrow1 = sh1.Cells(Rows.Count, "B").End(xlUp).row
maxrow2 = sh2.Cells(Rows.Count, "B").End(xlUp).row
Application.ScreenUpdating = False

For row = 2 To maxrow2
key = sh2.Cells(row, "B").Value
dicT(key) = sh2.Cells(row, "C").Value
Next
okctr = 0
ngctr = 0
For row = 2 To maxrow1
key = sh1.Cells(row, "B").Value
If dicT.exists(key) = True Then
sh1.Cells(row, "B").Value = dicT(key)
okctr = okctr + 1
Else
ngctr = ngctr + 1
End If
dicT(key) = sh2.Cells(row, "C").Value
Next
Application.ScreenUpdating = True
MsgBox ("処理件数=" & okctr & " 未処理件数=" & ngctr)
End Sub
-----------------------------------------

この回答へのお礼

tatsu99さん、コードありがとうございました。無事作成することができました。感謝致します。

お礼日時：2017/10/12 21:02

No.1 回答者： tatsu99 回答日時： 2017/10/11 23:52

補足要求です。

１）シート１、シート２共に１行目は見出しでしょうか。
２）replaceもselect caseも使用しませんが、それでも良いですか。
３）シート１の社員番号を直接変換してしまうと、リラン（マクロの再実行）ができなくなります。
その為、他の列（例えばC列）に、名前を出力したほうが良いと、考えますが、いかがでしょうか。
どうしても、B列を直接変換したい場合は、事前シート１のバックアップをとることをお勧めします。

この回答へのお礼

tatsu99さん、返信ありがとうございます。
（１）シート1、シート2とも1行目は見出しです。
（２）方法は特にこだわりはありません。できれば高速処理できると助かり
　　　ます。
（３）元ファイルはバックアップしているので、直接変換できたほうがいい
　　　です。
申し訳ありませんがご教示よろしくお願い致します。

お礼日時：2017/10/12 07:02