マクロ（Excel）で上下のセルの値が同じ場合、特定の列のセルを統合する方法

Question

マクロで処理を自動化したいのですが、作ることができません。
技術のある方、お助け下さい。

D列で上下のセルの値が同じ場合、A列、B列、C列のセルを統合する。
A2、A3を統合しますが、データは残す。A2、A3のデータは改行する
B2、B3を統合しますが、データは残す。B2、B3のデータは改行する。
C2、C3を統合します。データも統合する。
以降は同じ要領です。画像をご参照下さい。

※画像は1ファイルしか添付できないため、A-D列の実行結果をF-I列に表示していますが、
A-D列に表示（統合）させたいです。

ママチャリ · Accepted Answer

もしかして、こういうこと？
 tom04さんのマクロの方が、遥かに高機能ですが・・・。

Sub sample()
    Dim i As Long
    For i = Cells(Rows.Count, "D").End(xlUp).Row - 1 To 2 Step -1
        If Cells(i, "D") = Cells(i + 1, "D") Then
            Cells(i, "A").Value = Cells(i, "A").Value & vbLf & Cells(i + 1, "A").Value
            Cells(i, "B").Value = Cells(i, "B").Value & vbLf & Cells(i + 1, "B").Value
            Rows(i + 1).Delete
        End If
    Next i
End Sub

tatsu99 · Answer

No3です。
＞A列が同じであれば、C列、D列も同じ(１つ)になります。
ということなので、No2の方のマクロで問題ないかと思います。

No2の方の返信で、
＞提示して頂いたコードを実行したところ、一見セルが統合されているのですが、
＞例としてA2-3をコピーして別セルに張り付けると、１行不要なセルがコピーされます。
＞A4-6については２行不要なセルがコピーされます。
とありますが、どのようなことでしょうか。

こちらで確認した範囲では正常です。
A2-3をコピーして、G2-3に張り付け
A4-6をコピーして、G6-8に張り付けました。（添付図参照）

どのようにくずれるのか、画像を提示していただけると、わかりやすいかと。

tatsu99 · Answer

C列統合とのことですが、異なる場合は、改行を付加して連結ですか。
例えば、図で、C4＝”大”ですが、C4＝”中”の場合は、
結合セルは
中
大
のようになりますか？

D列も同様です。
例えば、D3＝"果実類"ですが、D3＝"果実類特別"の場合は
結合セルは
果実類
果実類特別
のようになりますか？

tom04 · Answer

こんばんは！

＞統合する。
は「セル結合」ですね。

画像ではC・D列（サイズと分類列）は必ず同じデータになっていますので、
C・D列はそのまま結合します。

一例です。

Sub Sample1()
　Dim i As Long, cnt As Long
　Dim myStr1 As String, myStr2 As String
　　For i = 2 To Cells(Rows.Count, "A").End(xlUp).Row
　　　If Cells(i, "D") = Cells(i + 1, "D") Then
　　　　myStr1 = Cells(i, "A")
　　　　myStr2 = Cells(i, "B")
　　　　　cnt = 1
　　　　　Do While Cells(i, "D") = Cells(i + cnt, "D")
　　　　　　myStr1 = myStr1 & vbCrLf & Cells(i + cnt, "A")
　　　　　　myStr2 = myStr2 & vbCrLf & Cells(i + cnt, "B")
　　　　　　cnt = cnt + 1
　　　　　Loop
　　　　　　Application.DisplayAlerts = False
　　　　　　　With Cells(i, "A").Resize(cnt)
　　　　　　　　.ClearContents
　　　　　　　　.Merge
　　　　　　　　.Value = myStr1
　　　　　　　End With
　　　　　　　With Cells(i, "B").Resize(cnt)
　　　　　　　　.ClearContents
　　　　　　　　.Merge
　　　　　　　　.Value = myStr2
　　　　　　　End With
　　　　　　　Cells(i, "C").Resize(cnt).Merge
　　　　　　　Cells(i, "D").Resize(cnt).Merge
　　　　　　Application.DisplayAlerts = True
　　　　　　　i = i + cnt - 1
　　　End If
　　Next i
End Sub

こんな感じではどうでしょうか？

※　細かい検証はしていませんので
不具合が出たらごめんなさい。m(_ _)m

くんこば · Answer

具体的にどこがわからないの？
処理フローくらいは書ける？
セルの結合？文字の結合？繰り返し文？
今、どこまで出来てるの？

マクロ（Excel）で上下のセルの値が同じ場合、特定の列のセルを統合する方法

もしかして、こういうこと？

No3です。

C列統合とのことですが、異なる場合は、改行を付加して連結ですか。

こんばんは！

具体的にどこがわからないの？

似たような質問が見つかりました

このQ&Aを見た人はこんなQ&Aも見ています

関連するカテゴリからQ&Aを探す

このQ&Aを見た人がよく見るQ&A

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング